basis/cpu/x86/64/64.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math namespaces make sequences
   4 system layouts alien alien.c-types alien.accessors alien.libraries
   5 slots splitting assocs combinators locals compiler.constants
   6 compiler.codegen compiler.codegen.fixup
   7 compiler.cfg.instructions compiler.cfg.builder
   8 compiler.cfg.intrinsics compiler.cfg.stack-frame
   9 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86
  10 cpu.architecture vm ;
  11 FROM: layouts => cell cells ;
  12 IN: cpu.x86.64
  13
  14 : param-reg-0 ( -- reg ) 0 int-regs cdecl param-reg ; inline
  15 : param-reg-1 ( -- reg ) 1 int-regs cdecl param-reg ; inline
  16 : param-reg-2 ( -- reg ) 2 int-regs cdecl param-reg ; inline
  17 : param-reg-3 ( -- reg ) 3 int-regs cdecl param-reg ; inline
  18
  19 M: x86.64 pic-tail-reg RBX ;
  20
  21 M: int-regs return-reg drop RAX ;
  22 M: float-regs return-reg drop XMM0 ;
  23
  24 M: x86.64 ds-reg R14 ;
  25 M: x86.64 rs-reg R15 ;
  26 M: x86.64 stack-reg RSP ;
  27 M: x86.64 frame-reg RBP ;
  28
  29 M: x86.64 extra-stack-space drop 0 ;
  30
  31 M: x86.64 machine-registers
  32     {
  33         { int-regs { RAX RCX RDX RBX RBP RSI RDI R8 R9 R10 R11 R12 } }
  34         { float-regs {
  35             XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7
  36             XMM8 XMM9 XMM10 XMM11 XMM12 XMM13 XMM14 XMM15
  37         } }
  38     } ;
  39
  40 : vm-reg ( -- reg ) R13 ; inline
  41 : nv-reg ( -- reg ) RBX ; inline
  42
  43 M: x86.64 %mov-vm-ptr ( reg -- )
  44     vm-reg MOV ;
  45
  46 M: x86.64 %vm-field ( dst field -- )
  47     [ vm-reg ] dip vm-field-offset [+] MOV ;
  48
  49 M: x86.64 %vm-field-ptr ( dst field -- )
  50     [ vm-reg ] dip vm-field-offset [+] LEA ;
  51
  52 M: x86.64 %prologue ( n -- )
  53     temp-reg -7 [] LEA
  54     dup PUSH
  55     temp-reg PUSH
  56     stack-reg swap 3 cells - SUB ;
  57
  58 M: x86.64 %prepare-jump
  59     pic-tail-reg xt-tail-pic-offset [] LEA ;
  60
  61 : load-cards-offset ( dst -- )
  62     0 MOV rc-absolute-cell rel-cards-offset ;
  63
  64 M: x86.64 %mark-card
  65     dup load-cards-offset
  66     [+] card-mark <byte> MOV ;
  67
  68 : load-decks-offset ( dst -- )
  69     0 MOV rc-absolute-cell rel-decks-offset ;
  70
  71 M: x86.64 %mark-deck
  72     dup load-decks-offset
  73     [+] card-mark <byte> MOV ;
  74
  75 M:: x86.64 %dispatch ( src temp -- )
  76     ! Load jump table base.
  77     temp HEX: ffffffff MOV
  78     building get length :> start
  79     0 rc-absolute-cell rel-here
  80     ! Add jump table base
  81     temp src ADD
  82     temp HEX: 7f [+] JMP
  83     building get length :> end
  84     ! Fix up the displacement above
  85     cell code-alignment
  86     [ end start - + building get dup pop* push ]
  87     [ align-code ]
  88     bi ;
  89
  90 M: stack-params copy-register*
  91     drop
  92     {
  93         { [ dup  integer? ] [ R11 swap next-stack@ MOV  R11 MOV ] }
  94         { [ over integer? ] [ R11 swap MOV              param@ R11 MOV ] }
  95     } cond ;
  96
  97 M: x86.64 %save-param-reg [ param@ ] 2dip %copy ;
  98
  99 M: x86.64 %load-param-reg [ swap param@ ] dip %copy ;
 100
 101 : with-return-regs ( quot -- )
 102     [
 103         V{ RDX RAX } clone int-regs set
 104         V{ XMM1 XMM0 } clone float-regs set
 105         call
 106     ] with-scope ; inline
 107
 108 M: x86.64 %pop-stack ( n -- )
 109     param-reg-0 swap ds-reg reg-stack MOV ;
 110
 111 M: x86.64 %pop-context-stack ( -- )
 112     temp-reg "ctx" %vm-field
 113     param-reg-0 temp-reg "datastack" context-field-offset [+] MOV
 114     param-reg-0 param-reg-0 [] MOV
 115     temp-reg "datastack" context-field-offset [+] bootstrap-cell SUB ;
 116
 117 M:: x86.64 %unbox ( n rep func -- )
 118     param-reg-1 %mov-vm-ptr
 119     ! Call the unboxer
 120     func f %alien-invoke
 121     ! Store the return value on the C stack if this is an
 122     ! alien-invoke, otherwise leave it the return register if
 123     ! this is the end of alien-callback
 124     n [ n rep reg-class-of return-reg rep %save-param-reg ] when ;
 125
 126 : %unbox-struct-field ( c-type i -- )
 127     ! Alien must be in param-reg-0.
 128     R11 swap cells [+] swap rep>> reg-class-of {
 129         { int-regs [ int-regs get pop swap MOV ] }
 130         { float-regs [ float-regs get pop swap MOVSD ] }
 131     } case ;
 132
 133 M: x86.64 %unbox-small-struct ( c-type -- )
 134     ! Alien must be in param-reg-0.
 135     param-reg-1 %mov-vm-ptr
 136     "alien_offset" f %alien-invoke
 137     ! Move alien_offset() return value to R11 so that we don't
 138     ! clobber it.
 139     R11 RAX MOV
 140     [
 141         flatten-value-type [ %unbox-struct-field ] each-index
 142     ] with-return-regs ;
 143
 144 M:: x86.64 %unbox-large-struct ( n c-type -- )
 145     ! Source is in param-reg-0
 146     ! Load destination address into param-reg-1
 147     param-reg-1 n param@ LEA
 148     ! Load structure size into param-reg-2
 149     param-reg-2 c-type heap-size MOV
 150     param-reg-3 %mov-vm-ptr
 151     ! Copy the struct to the C stack
 152     "to_value_struct" f %alien-invoke ;
 153
 154 : load-return-value ( rep -- )
 155     [ [ 0 ] dip reg-class-of cdecl param-reg ]
 156     [ reg-class-of return-reg ]
 157     [ ]
 158     tri %copy ;
 159
 160 M:: x86.64 %box ( n rep func -- )
 161     n [
 162         n
 163         0 rep reg-class-of cdecl param-reg
 164         rep %load-param-reg
 165     ] [
 166         rep load-return-value
 167     ] if
 168     rep int-rep?
 169     cpu x86.64? os windows? and or
 170     param-reg-1 param-reg-0 ? %mov-vm-ptr
 171     func f %alien-invoke ;
 172
 173 : box-struct-field@ ( i -- operand ) 1 + cells param@ ;
 174
 175 : %box-struct-field ( c-type i -- )
 176     box-struct-field@ swap c-type-rep reg-class-of {
 177         { int-regs [ int-regs get pop MOV ] }
 178         { float-regs [ float-regs get pop MOVSD ] }
 179     } case ;
 180
 181 M: x86.64 %box-small-struct ( c-type -- )
 182     #! Box a <= 16-byte struct.
 183     [
 184         [ flatten-value-type [ %box-struct-field ] each-index ]
 185         [ param-reg-2 swap heap-size MOV ] bi
 186         param-reg-0 0 box-struct-field@ MOV
 187         param-reg-1 1 box-struct-field@ MOV
 188         param-reg-3 %mov-vm-ptr
 189         "from_small_struct" f %alien-invoke
 190     ] with-return-regs ;
 191
 192 : struct-return@ ( n -- operand )
 193     [ stack-frame get params>> ] unless* param@ ;
 194
 195 M: x86.64 %box-large-struct ( n c-type -- )
 196     ! Struct size is parameter 2
 197     param-reg-1 swap heap-size MOV
 198     ! Compute destination address
 199     param-reg-0 swap struct-return@ LEA
 200     param-reg-2 %mov-vm-ptr
 201     ! Copy the struct from the C stack
 202     "from_value_struct" f %alien-invoke ;
 203
 204 M: x86.64 %prepare-box-struct ( -- )
 205     ! Compute target address for value struct return
 206     RAX f struct-return@ LEA
 207     ! Store it as the first parameter
 208     0 param@ RAX MOV ;
 209
 210 M: x86.64 %prepare-var-args RAX RAX XOR ;
 211
 212 M: x86.64 %alien-invoke
 213     R11 0 MOV
 214     rc-absolute-cell rel-dlsym
 215     R11 CALL ;
 216
 217 M: x86.64 %prepare-alien-indirect ( -- )
 218     param-reg-0 ds-reg [] MOV
 219     ds-reg 8 SUB
 220     param-reg-1 %mov-vm-ptr
 221     "pinned_alien_offset" f %alien-invoke
 222     nv-reg RAX MOV ;
 223
 224 M: x86.64 %alien-indirect ( -- )
 225     nv-reg CALL ;
 226
 227 M: x86.64 %begin-callback ( -- )
 228     param-reg-0 %mov-vm-ptr
 229     "begin_callback" f %alien-invoke ;
 230
 231 M: x86.64 %alien-callback ( quot -- )
 232     param-reg-0 param-reg-1 %restore-context
 233     param-reg-0 swap %load-reference
 234     param-reg-0 quot-entry-point-offset [+] CALL
 235     param-reg-0 param-reg-1 %save-context ;
 236
 237 M: x86.64 %end-callback ( -- )
 238     param-reg-0 %mov-vm-ptr
 239     "end_callback" f %alien-invoke ;
 240
 241 M: x86.64 %end-callback-value ( ctype -- )
 242     %pop-context-stack
 243     nv-reg param-reg-0 MOV
 244     %end-callback
 245     param-reg-0 nv-reg MOV
 246     ! Unbox former top of data stack to return registers
 247     unbox-return ;
 248
 249 : float-function-param ( i src -- )
 250     [ float-regs cdecl param-regs nth ] dip double-rep %copy ;
 251
 252 : float-function-return ( reg -- )
 253     float-regs return-reg double-rep %copy ;
 254
 255 M:: x86.64 %unary-float-function ( dst src func -- )
 256     0 src float-function-param
 257     func "libm" load-library %alien-invoke
 258     dst float-function-return ;
 259
 260 M:: x86.64 %binary-float-function ( dst src1 src2 func -- )
 261     ! src1 might equal dst; otherwise it will be a spill slot
 262     ! src2 is always a spill slot
 263     0 src1 float-function-param
 264     1 src2 float-function-param
 265     func "libm" load-library %alien-invoke
 266     dst float-function-return ;
 267
 268 M:: x86.64 %call-gc ( gc-root-count temp -- )
 269     ! Pass pointer to start of GC roots as first parameter
 270     param-reg-0 gc-root-base param@ LEA
 271     ! Pass number of roots as second parameter
 272     param-reg-1 gc-root-count MOV
 273     ! Pass VM ptr as third parameter
 274     param-reg-2 %mov-vm-ptr
 275     ! Call GC
 276     "inline_gc" f %alien-invoke ;
 277
 278 M: x86.64 struct-return-pointer-type void* ;
 279
 280 ! The result of reading 4 bytes from memory is a fixnum on
 281 ! x86-64.
 282 enable-alien-4-intrinsics
 283
 284 USE: vocabs.loader
 285
 286 {
 287     { [ os unix? ] [ "cpu.x86.64.unix" require ] }
 288     { [ os winnt? ] [ "cpu.x86.64.winnt" require ] }
 289 } cond
 290
 291 check-sse