basis/cpu/x86/64/64.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math namespaces make sequences system
   4 layouts alien alien.c-types alien.accessors slots
   5 splitting assocs combinators locals compiler.constants
   6 compiler.codegen compiler.codegen.fixup compiler.cfg.instructions
   7 compiler.cfg.builder compiler.cfg.intrinsics compiler.cfg.stack-frame
   8 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86 cpu.architecture ;
   9 IN: cpu.x86.64
  10
  11 M: x86.64 machine-registers
  12     {
  13         { int-regs { RAX RCX RDX RBX RBP RSI RDI R8 R9 R10 R11 R12 R13 } }
  14         { float-regs {
  15             XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7
  16             XMM8 XMM9 XMM10 XMM11 XMM12 XMM13 XMM14 XMM15
  17         } }
  18     } ;
  19
  20 M: x86.64 ds-reg R14 ;
  21 M: x86.64 rs-reg R15 ;
  22 M: x86.64 stack-reg RSP ;
  23
  24 M:: x86.64 %dispatch ( src temp -- )
  25     building get length :> start
  26     ! Load jump table base.
  27     temp HEX: ffffffff MOV
  28     0 rc-absolute-cell rel-here
  29     ! Add jump table base
  30     temp src ADD
  31     temp HEX: 7f [+] JMP
  32     building get length :> end
  33     ! Fix up the displacement above
  34     cell code-alignment
  35     [ end start - 2 - + building get dup pop* push ]
  36     [ align-code ]
  37     bi ;
  38
  39 M: x86.64 param-reg-1 int-regs param-regs first ;
  40 M: x86.64 param-reg-2 int-regs param-regs second ;
  41 : param-reg-3 ( -- reg ) int-regs param-regs third ; inline
  42
  43 M: x86.64 pic-tail-reg RBX ;
  44
  45 M: int-regs return-reg drop RAX ;
  46 M: float-regs return-reg drop XMM0 ;
  47
  48 M: x86.64 %prologue ( n -- )
  49     temp-reg 0 MOV rc-absolute-cell rel-this
  50     dup PUSH
  51     temp-reg PUSH
  52     stack-reg swap 3 cells - SUB ;
  53
  54 M: stack-params copy-register*
  55     drop
  56     {
  57         { [ dup  integer? ] [ R11 swap next-stack@ MOV  R11 MOV ] }
  58         { [ over integer? ] [ R11 swap MOV              param@ R11 MOV ] }
  59     } cond ;
  60
  61 M: x86 %save-param-reg [ param@ ] 2dip copy-register ;
  62
  63 M: x86 %load-param-reg [ swap param@ ] dip copy-register ;
  64
  65 : with-return-regs ( quot -- )
  66     [
  67         V{ RDX RAX } clone int-regs set
  68         V{ XMM1 XMM0 } clone float-regs set
  69         call
  70     ] with-scope ; inline
  71
  72 M: x86.64 %prepare-unbox ( -- )
  73     ! First parameter is top of stack
  74     param-reg-1 R14 [] MOV
  75     R14 cell SUB ;
  76
  77 : %vm-invoke-2nd-arg ( function -- )
  78     param-reg-2 0 MOV rc-absolute-cell rt-vm rel-fixup
  79     f %alien-invoke ;
  80
  81
  82 M:: x86.64 %unbox ( n rep func -- )
  83     ! Call the unboxer
  84     func %vm-invoke-2nd-arg
  85     ! Store the return value on the C stack if this is an
  86     ! alien-invoke, otherwise leave it the return register if
  87     ! this is the end of alien-callback
  88     n [ n rep reg-class-of return-reg rep %save-param-reg ] when ;
  89
  90 M: x86.64 %unbox-long-long ( n func -- )
  91     [ int-rep ] dip %unbox ;
  92
  93 : %unbox-struct-field ( c-type i -- )
  94     ! Alien must be in param-reg-1.
  95     R11 swap cells [+] swap rep>> reg-class-of {
  96         { int-regs [ int-regs get pop swap MOV ] }
  97         { float-regs [ float-regs get pop swap MOVSD ] }
  98     } case ;
  99
 100
 101 M: x86.64 %unbox-small-struct ( c-type -- )
 102     ! Alien must be in param-reg-1.
 103     "alien_offset" %vm-invoke-2nd-arg
 104     ! Move alien_offset() return value to R11 so that we don't
 105     ! clobber it.
 106     R11 RAX MOV
 107     [
 108         flatten-value-type [ %unbox-struct-field ] each-index
 109     ] with-return-regs ;
 110
 111 M:: x86.64 %unbox-large-struct ( n c-type -- )
 112     ! Source is in param-reg-1
 113     ! Load destination address into param-reg-2
 114     param-reg-2 n param@ LEA
 115     ! Load structure size into param-reg-3
 116     param-reg-3 c-type heap-size MOV
 117     ! Copy the struct to the C stack
 118     "to_value_struct" f %alien-invoke ;
 119
 120 : load-return-value ( rep -- )
 121     [ [ 0 ] dip reg-class-of param-reg ]
 122     [ reg-class-of return-reg ]
 123     [ ]
 124     tri copy-register ;
 125
 126 M:: x86.64 %box ( n rep func -- )
 127     n [
 128         n
 129         0 rep reg-class-of param-reg
 130         rep %load-param-reg
 131     ] [
 132         rep load-return-value
 133     ] if
 134     func %vm-invoke-2nd-arg ;
 135
 136 M: x86.64 %box-long-long ( n func -- )
 137     [ int-rep ] dip %box ;
 138
 139 : box-struct-field@ ( i -- operand ) 1 + cells param@ ;
 140
 141 : %box-struct-field ( c-type i -- )
 142     box-struct-field@ swap c-type-rep reg-class-of {
 143         { int-regs [ int-regs get pop MOV ] }
 144         { float-regs [ float-regs get pop MOVSD ] }
 145     } case ;
 146
 147 M: x86.64 %box-small-struct ( c-type -- )
 148     #! Box a <= 16-byte struct.
 149     [
 150         [ flatten-value-type [ %box-struct-field ] each-index ]
 151         [ param-reg-3 swap heap-size MOV ] bi
 152         param-reg-1 0 box-struct-field@ MOV
 153         param-reg-2 1 box-struct-field@ MOV
 154         "box_small_struct" f %alien-invoke
 155     ] with-return-regs ;
 156
 157 : struct-return@ ( n -- operand )
 158     [ stack-frame get params>> ] unless* param@ ;
 159
 160 M: x86.64 %box-large-struct ( n c-type -- )
 161     ! Struct size is parameter 2
 162     param-reg-2 swap heap-size MOV
 163     ! Compute destination address
 164     param-reg-1 swap struct-return@ LEA
 165     ! Copy the struct from the C stack
 166     "box_value_struct" f %alien-invoke ;
 167
 168 M: x86.64 %prepare-box-struct ( -- )
 169     ! Compute target address for value struct return
 170     RAX f struct-return@ LEA
 171     ! Store it as the first parameter
 172     0 param@ RAX MOV ;
 173
 174 M: x86.64 %prepare-var-args RAX RAX XOR ;
 175
 176 M: x86.64 %alien-invoke
 177     R11 0 MOV
 178     rc-absolute-cell rel-dlsym
 179     R11 CALL ;
 180
 181 M: x86.64 %vm-invoke-1st-arg ( function -- )
 182     param-reg-1 0 MOV rc-absolute-cell rt-vm rel-fixup
 183     f %alien-invoke ;
 184
 185
 186 M: x86.64 %vm-invoke-3rd-arg ( function -- )
 187     param-reg-3 0 MOV rc-absolute-cell rt-vm rel-fixup
 188     f %alien-invoke ;
 189
 190 M: x86.64 %prepare-alien-indirect ( -- )
 191     "unbox_alien" f %alien-invoke
 192     RBP RAX MOV ;
 193
 194 M: x86.64 %alien-indirect ( -- )
 195     RBP CALL ;
 196
 197 M: x86.64 %alien-callback ( quot -- )
 198     param-reg-1 swap %load-reference
 199     "c_to_factor" f %alien-invoke ;
 200
 201 M: x86.64 %callback-value ( ctype -- )
 202     ! Save top of data stack
 203     %prepare-unbox
 204     ! Save top of data stack
 205     RSP 8 SUB
 206     param-reg-1 PUSH
 207     ! Restore data/call/retain stacks
 208     "unnest_stacks" f %alien-invoke
 209     ! Put former top of data stack in param-reg-1
 210     param-reg-1 POP
 211     RSP 8 ADD
 212     ! Unbox former top of data stack to return registers
 213     unbox-return ;
 214
 215 : float-function-param ( i spill-slot -- )
 216     [ float-regs param-regs nth ] [ n>> spill@ ] bi* MOVSD ;
 217
 218 : float-function-return ( reg -- )
 219     float-regs return-reg double-rep copy-register ;
 220
 221 M:: x86.64 %unary-float-function ( dst src func -- )
 222     0 src float-function-param
 223     func f %alien-invoke
 224     dst float-function-return ;
 225
 226 M:: x86.64 %binary-float-function ( dst src1 src2 func -- )
 227     0 src1 float-function-param
 228     1 src2 float-function-param
 229     func f %alien-invoke
 230     dst float-function-return ;
 231
 232 ! The result of reading 4 bytes from memory is a fixnum on
 233 ! x86-64.
 234 enable-alien-4-intrinsics
 235
 236 ! Enable fast calling of libc math functions
 237 enable-float-functions
 238
 239 USE: vocabs.loader
 240
 241 {
 242     { [ os unix? ] [ "cpu.x86.64.unix" require ] }
 243     { [ os winnt? ] [ "cpu.x86.64.winnt" require ] }
 244 } cond
 245
 246 "cpu.x86.features" require