basis/cpu/x86/assembler/assembler.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays io.binary kernel combinators
   4 combinators.short-circuit math math.bitwise locals namespaces
   5 make sequences words system layouts math.order accessors
   6 cpu.x86.assembler.operands cpu.x86.assembler.operands.private ;
   7 IN: cpu.x86.assembler
   8
   9 ! A postfix assembler for x86-32 and x86-64.
  10
  11 <PRIVATE
  12
  13 : reg-code ( reg -- n ) "register" word-prop 7 bitand ;
  14
  15 : indirect-base* ( op -- n ) base>> EBP or reg-code ;
  16
  17 : indirect-index* ( op -- n ) index>> ESP or reg-code ;
  18
  19 : indirect-scale* ( op -- n ) scale>> 0 or ;
  20
  21 GENERIC: sib-present? ( op -- ? )
  22
  23 M: indirect sib-present?
  24     {
  25         [ base>> { ESP RSP R12 } member? ]
  26         [ index>> ]
  27         [ scale>> ]
  28     } 1|| ;
  29
  30 M: register sib-present? drop f ;
  31
  32 GENERIC: r/m ( operand -- n )
  33
  34 M: indirect r/m
  35     dup sib-present?
  36     [ drop ESP reg-code ] [ indirect-base* ] if ;
  37
  38 M: register r/m reg-code ;
  39
  40 ! Immediate operands
  41 UNION: immediate byte integer ;
  42
  43 GENERIC: fits-in-byte? ( value -- ? )
  44
  45 M: byte fits-in-byte? drop t ;
  46
  47 M: integer fits-in-byte? -128 127 between? ;
  48
  49 GENERIC: modifier ( op -- n )
  50
  51 M: indirect modifier
  52     dup base>> [
  53         displacement>> {
  54             { [ dup not ] [ 0b00 ] }
  55             { [ dup fits-in-byte? ] [ 0b01 ] }
  56             { [ dup immediate? ] [ 0b10 ] }
  57         } cond nip
  58     ] [
  59         drop 0b00
  60     ] if ;
  61
  62 M: register modifier drop 0b11 ;
  63
  64 GENERIC# n, 1 ( value n -- )
  65
  66 M: integer n, >le % ;
  67 M: byte n, [ value>> ] dip n, ;
  68 : 1, ( n -- ) 1 n, ; inline
  69 : 4, ( n -- ) 4 n, ; inline
  70 : 2, ( n -- ) 2 n, ; inline
  71 : cell, ( n -- ) bootstrap-cell n, ; inline
  72
  73 : mod-r/m, ( reg operand -- )
  74     [ 3 shift ] [ [ modifier 6 shift ] [ r/m ] bi ] bi* bitor bitor , ;
  75
  76 : sib, ( operand -- )
  77     dup sib-present? [
  78         [ indirect-base* ]
  79         [ indirect-index* 3 shift ]
  80         [ indirect-scale* 6 shift ] tri bitor bitor ,
  81     ] [
  82         drop
  83     ] if ;
  84
  85 GENERIC: displacement, ( op -- )
  86
  87 M: indirect displacement,
  88     dup displacement>> dup [
  89         swap base>>
  90         [ dup fits-in-byte? [ , ] [ 4, ] if ] [ 4, ] if
  91     ] [ 2drop ] if ;
  92
  93 M: register displacement, drop ;
  94
  95 : addressing ( reg operand -- )
  96     [ mod-r/m, ] [ sib, ] [ displacement, ] tri ;
  97
  98 : rex.w? ( rex.w reg r/m -- ? )
  99     {
 100         { [ over register-128? ] [ nip operand-64? ] }
 101         { [ over not ] [ nip operand-64? ] }
 102         [ drop operand-64? ]
 103     } cond and ;
 104
 105 : rex.r ( m op -- n )
 106     extended? [ 0b00000100 bitor ] when ;
 107
 108 : rex.b ( m op -- n )
 109     [ extended? [ 0b00000001 bitor ] when ] keep
 110     dup indirect? [ index>> extended? [ 0b00000010 bitor ] when ] [ drop ] if ;
 111
 112 : no-prefix? ( prefix reg r/m -- ? )
 113     [ 0b01000000 = ]
 114     [ extended-8-bit-register? not ]
 115     [ extended-8-bit-register? not ] tri*
 116     and and ;
 117
 118 :: rex-prefix ( reg r/m rex.w -- )
 119     #! Compile an AMD64 REX prefix.
 120     rex.w reg r/m rex.w? 0b01001000 0b01000000 ?
 121     reg rex.r
 122     r/m rex.b
 123     dup reg r/m no-prefix? [ drop ] [ , ] if ;
 124
 125 : 16-prefix ( reg -- )
 126     register-16? [ 0x66 , ] when ;
 127
 128 : prefix-1 ( reg rex.w -- )
 129     [ drop 16-prefix ] [ [ f ] 2dip rex-prefix ] 2bi ;
 130
 131 : short-operand ( reg rex.w n -- )
 132     #! Some instructions encode their single operand as part of
 133     #! the opcode.
 134     [ dupd prefix-1 reg-code ] dip + , ;
 135
 136 : opcode, ( opcode -- ) dup array? [ % ] [ , ] if ;
 137
 138 : extended-opcode ( opcode -- opcode' )
 139     dup array? [ 0o17 prefix ] [ 0o17 swap 2array ] if ;
 140
 141 : extended-opcode, ( opcode -- ) extended-opcode opcode, ;
 142
 143 : opcode-or ( opcode mask -- opcode' )
 144     over array?
 145     [ [ unclip-last ] dip bitor suffix ] [ bitor ] if ;
 146
 147 : 1-operand ( operand reg,rex.w,opcode -- )
 148     #! The 'reg' is not really a register, but a value for the
 149     #! 'reg' field of the mod-r/m byte.
 150     first3 [ [ over ] dip prefix-1 ] dip opcode, swap addressing ;
 151
 152 : immediate-operand-size-bit ( dst imm reg,rex.w,opcode -- imm dst reg,rex.w,opcode )
 153     over integer? [ first3 0b1 opcode-or 3array ] when ;
 154
 155 : immediate-1* ( dst imm reg,rex.w,opcode -- )
 156     swap [ 1-operand ] dip 1, ;
 157
 158 : immediate-1 ( dst imm reg,rex.w,opcode -- )
 159     immediate-operand-size-bit immediate-1* ;
 160
 161 : immediate-4 ( dst imm reg,rex.w,opcode -- )
 162     immediate-operand-size-bit swap [ 1-operand ] dip 4, ;
 163
 164 : immediate-fits-in-size-bit ( dst imm reg,rex.w,opcode -- imm dst reg,rex.w,opcode )
 165     over integer? [ first3 0b10 opcode-or 3array ] when ;
 166
 167 : immediate-1/4 ( dst imm reg,rex.w,opcode -- )
 168     #! If imm is a byte, compile the opcode and the byte.
 169     #! Otherwise, set the 8-bit operand flag in the opcode, and
 170     #! compile the cell. The 'reg' is not really a register, but
 171     #! a value for the 'reg' field of the mod-r/m byte.
 172     over fits-in-byte? [
 173         immediate-fits-in-size-bit immediate-1
 174     ] [
 175         immediate-4
 176     ] if ;
 177
 178 : (2-operand) ( reg operand op -- )
 179     [ 2dup t rex-prefix ] dip opcode,
 180     [ reg-code ] dip addressing ;
 181
 182 : direction-bit ( dst src op -- reg operand op' )
 183     pick register? pick register? not and
 184     [ 0b10 opcode-or ] [ swapd ] if ;
 185
 186 : operand-size-bit ( reg operand op -- reg operand op' )
 187     pick register-8? [ 0b1 opcode-or ] unless ;
 188
 189 : 2-operand ( dst src op -- )
 190     direction-bit operand-size-bit
 191     pick 16-prefix
 192     (2-operand) ;
 193
 194 PRIVATE>
 195
 196 ! Segment override prefixes
 197 : CS ( -- ) 0x2e , ;
 198 : ES ( -- ) 0x26 , ;
 199 : SS ( -- ) 0x36 , ;
 200 : FS ( -- ) 0x64 , ;
 201 : GS ( -- ) 0x65 , ;
 202
 203 ! Moving stuff
 204 GENERIC: PUSH ( op -- )
 205 M: register PUSH f 0x50 short-operand ;
 206 M: immediate PUSH 0x68 , 4, ;
 207 M: operand PUSH { 0b110 f 0xff } 1-operand ;
 208
 209 GENERIC: POP ( op -- )
 210 M: register POP f 0x58 short-operand ;
 211 M: operand POP { 0b000 f 0x8f } 1-operand ;
 212
 213 ! MOV where the src is immediate.
 214 <PRIVATE
 215
 216 GENERIC# (MOV-I) 1 ( dst src -- )
 217
 218 M: register (MOV-I)
 219     dup byte?
 220     [ [ t 0xb0 short-operand ] [ 1, ] bi* ]
 221     [ [ t 0xb8 short-operand ] [ cell, ] bi* ]
 222     if ;
 223
 224 M: operand (MOV-I)
 225     { 0b000 t 0xc6 }
 226     over byte? [ immediate-1 ] [ immediate-4 ] if ;
 227
 228 PRIVATE>
 229
 230 GENERIC: MOV ( dst src -- )
 231 M: immediate MOV (MOV-I) ;
 232 M: operand MOV 0x88 2-operand ;
 233
 234 ERROR: bad-movabs-operands dst src ;
 235
 236 GENERIC: MOVABS ( dst src -- )
 237 M: object MOVABS bad-movabs-operands ;
 238 M: register MOVABS
 239     {
 240         { AL [ 0xa2 , cell, ] }
 241         { AX [ 0x66 , 0xa3 , cell, ] }
 242         { EAX [ 0xa3 , cell, ] }
 243         { RAX [ 0x48 , 0xa3 , cell, ] }
 244         [ swap bad-movabs-operands ]
 245     } case ;
 246 M: integer MOVABS
 247     swap {
 248         { AL [ 0xa0 , cell, ] }
 249         { AX [ 0x66 , 0xa1 , cell, ] }
 250         { EAX [ 0xa1 , cell, ] }
 251         { RAX [ 0x48 , 0xa1 , cell, ] }
 252         [ swap bad-movabs-operands ]
 253     } case ;
 254
 255 : LEA ( dst src -- ) swap 0x8d 2-operand ;
 256
 257 ! Control flow
 258 GENERIC: JMP ( op -- )
 259 M: integer JMP 0xe9 , 4, ;
 260 M: operand JMP { 0b100 t 0xff } 1-operand ;
 261
 262 GENERIC: CALL ( op -- )
 263 M: integer CALL 0xe8 , 4, ;
 264 M: operand CALL { 0b010 t 0xff } 1-operand ;
 265
 266 <PRIVATE
 267
 268 GENERIC# JUMPcc 1 ( addr opcode -- )
 269 M: integer JUMPcc extended-opcode, 4, ;
 270
 271 : SETcc ( dst opcode -- )
 272     { 0b000 t } swap suffix 1-operand ;
 273
 274 PRIVATE>
 275
 276 : JO  ( dst -- ) 0x80 JUMPcc ;
 277 : JNO ( dst -- ) 0x81 JUMPcc ;
 278 : JB  ( dst -- ) 0x82 JUMPcc ;
 279 : JAE ( dst -- ) 0x83 JUMPcc ;
 280 : JE  ( dst -- ) 0x84 JUMPcc ; ! aka JZ
 281 : JNE ( dst -- ) 0x85 JUMPcc ;
 282 : JBE ( dst -- ) 0x86 JUMPcc ;
 283 : JA  ( dst -- ) 0x87 JUMPcc ;
 284 : JS  ( dst -- ) 0x88 JUMPcc ;
 285 : JNS ( dst -- ) 0x89 JUMPcc ;
 286 : JP  ( dst -- ) 0x8a JUMPcc ;
 287 : JNP ( dst -- ) 0x8b JUMPcc ;
 288 : JL  ( dst -- ) 0x8c JUMPcc ;
 289 : JGE ( dst -- ) 0x8d JUMPcc ;
 290 : JLE ( dst -- ) 0x8e JUMPcc ;
 291 : JG  ( dst -- ) 0x8f JUMPcc ;
 292
 293 : SETO  ( dst -- ) { 0x0f 0x90 } SETcc ;
 294 : SETNO ( dst -- ) { 0x0f 0x91 } SETcc ;
 295 : SETB  ( dst -- ) { 0x0f 0x92 } SETcc ;
 296 : SETAE ( dst -- ) { 0x0f 0x93 } SETcc ;
 297 : SETE  ( dst -- ) { 0x0f 0x94 } SETcc ;
 298 : SETNE ( dst -- ) { 0x0f 0x95 } SETcc ;
 299 : SETBE ( dst -- ) { 0x0f 0x96 } SETcc ;
 300 : SETA  ( dst -- ) { 0x0f 0x97 } SETcc ;
 301 : SETS  ( dst -- ) { 0x0f 0x98 } SETcc ;
 302 : SETNS ( dst -- ) { 0x0f 0x99 } SETcc ;
 303 : SETP  ( dst -- ) { 0x0f 0x9a } SETcc ;
 304 : SETNP ( dst -- ) { 0x0f 0x9b } SETcc ;
 305 : SETL  ( dst -- ) { 0x0f 0x9c } SETcc ;
 306 : SETGE ( dst -- ) { 0x0f 0x9d } SETcc ;
 307 : SETLE ( dst -- ) { 0x0f 0x9e } SETcc ;
 308 : SETG  ( dst -- ) { 0x0f 0x9f } SETcc ;
 309
 310 : LEAVE ( -- ) 0xc9 , ;
 311
 312 : RET ( n -- )
 313     dup zero? [ drop 0xc3 , ] [ 0xc2 , 2, ] if ;
 314
 315 ! Arithmetic
 316
 317 GENERIC: ADD ( dst src -- )
 318 M: immediate ADD { 0b000 t 0x80 } immediate-1/4 ;
 319 M: operand ADD 0o000 2-operand ;
 320
 321 GENERIC: OR ( dst src -- )
 322 M: immediate OR { 0b001 t 0x80 } immediate-1/4 ;
 323 M: operand OR 0o010 2-operand ;
 324
 325 GENERIC: ADC ( dst src -- )
 326 M: immediate ADC { 0b010 t 0x80 } immediate-1/4 ;
 327 M: operand ADC 0o020 2-operand ;
 328
 329 GENERIC: SBB ( dst src -- )
 330 M: immediate SBB { 0b011 t 0x80 } immediate-1/4 ;
 331 M: operand SBB 0o030 2-operand ;
 332
 333 GENERIC: AND ( dst src -- )
 334 M: immediate AND { 0b100 t 0x80 } immediate-1/4 ;
 335 M: operand AND 0o040 2-operand ;
 336
 337 GENERIC: SUB ( dst src -- )
 338 M: immediate SUB { 0b101 t 0x80 } immediate-1/4 ;
 339 M: operand SUB 0o050 2-operand ;
 340
 341 GENERIC: XOR ( dst src -- )
 342 M: immediate XOR { 0b110 t 0x80 } immediate-1/4 ;
 343 M: operand XOR 0o060 2-operand ;
 344
 345 GENERIC: CMP ( dst src -- )
 346 M: immediate CMP { 0b111 t 0x80 } immediate-1/4 ;
 347 M: operand CMP 0o070 2-operand ;
 348
 349 GENERIC: TEST ( dst src -- )
 350 M: immediate TEST { 0b0 t 0xf7 } immediate-4 ;
 351 M: operand TEST 0o204 2-operand ;
 352
 353 : XCHG ( dst src -- ) 0o207 2-operand ;
 354
 355 : BSR ( dst src -- ) { 0x0f 0xbd } (2-operand) ;
 356
 357 GENERIC: BT ( value n -- )
 358 M: immediate BT ( value n -- ) { 0b100 t { 0x0f 0xba } } immediate-1* ;
 359 M: operand   BT ( value n -- ) swap { 0x0f 0xa3 } (2-operand) ;
 360
 361 GENERIC: BTC ( value n -- )
 362 M: immediate BTC ( value n -- ) { 0b111 t { 0x0f 0xba } } immediate-1* ;
 363 M: operand   BTC ( value n -- ) swap { 0x0f 0xbb } (2-operand) ;
 364
 365 GENERIC: BTR ( value n -- )
 366 M: immediate BTR ( value n -- ) { 0b110 t { 0x0f 0xba } } immediate-1* ;
 367 M: operand   BTR ( value n -- ) swap { 0x0f 0xb3 } (2-operand) ;
 368
 369 GENERIC: BTS ( value n -- )
 370 M: immediate BTS ( value n -- ) { 0b101 t { 0x0f 0xba } } immediate-1* ;
 371 M: operand   BTS ( value n -- ) swap { 0x0f 0xab } (2-operand) ;
 372
 373 : NOT  ( dst -- ) { 0b010 t 0xf7 } 1-operand ;
 374 : NEG  ( dst -- ) { 0b011 t 0xf7 } 1-operand ;
 375 : MUL  ( dst -- ) { 0b100 t 0xf7 } 1-operand ;
 376 : IMUL ( src -- ) { 0b101 t 0xf7 } 1-operand ;
 377 : DIV  ( dst -- ) { 0b110 t 0xf7 } 1-operand ;
 378 : IDIV ( src -- ) { 0b111 t 0xf7 } 1-operand ;
 379
 380 : CDQ ( -- ) 0x99 , ;
 381 : CQO ( -- ) 0x48 , CDQ ;
 382
 383 <PRIVATE
 384
 385 :: (SHIFT) ( dst src op -- )
 386     src CL eq? [
 387         dst { op t 0xd3 } 1-operand
 388     ] [
 389         dst src { op t 0xc0 } immediate-1
 390     ] if ; inline
 391
 392 PRIVATE>
 393
 394 : ROL ( dst n -- ) 0b000 (SHIFT) ;
 395 : ROR ( dst n -- ) 0b001 (SHIFT) ;
 396 : RCL ( dst n -- ) 0b010 (SHIFT) ;
 397 : RCR ( dst n -- ) 0b011 (SHIFT) ;
 398 : SHL ( dst n -- ) 0b100 (SHIFT) ;
 399 : SHR ( dst n -- ) 0b101 (SHIFT) ;
 400 : SAR ( dst n -- ) 0b111 (SHIFT) ;
 401
 402 : IMUL2 ( dst src -- )
 403     0o257 extended-opcode (2-operand) ;
 404
 405 : IMUL3 ( dst src imm -- )
 406     dup fits-in-byte? [
 407         [ swap 0x6a 2-operand ] dip 1,
 408     ] [
 409         [ swap 0x68 2-operand ] dip 4,
 410     ] if ;
 411
 412 : MOVSX ( dst src -- )
 413     dup register-32? 0o143 0o276 extended-opcode ?
 414     over register-16? [ 0b1 opcode-or ] when
 415     (2-operand) ;
 416
 417 : MOVZX ( dst src -- )
 418     0o266 extended-opcode
 419     over register-16? [ 0b1 opcode-or ] when
 420     (2-operand) ;
 421
 422 ! Conditional move
 423 : MOVcc ( dst src cc -- ) extended-opcode (2-operand) ;
 424
 425 : CMOVO  ( dst src -- ) 0x40 MOVcc ;
 426 : CMOVNO ( dst src -- ) 0x41 MOVcc ;
 427 : CMOVB  ( dst src -- ) 0x42 MOVcc ;
 428 : CMOVAE ( dst src -- ) 0x43 MOVcc ;
 429 : CMOVE  ( dst src -- ) 0x44 MOVcc ; ! aka CMOVZ
 430 : CMOVNE ( dst src -- ) 0x45 MOVcc ;
 431 : CMOVBE ( dst src -- ) 0x46 MOVcc ;
 432 : CMOVA  ( dst src -- ) 0x47 MOVcc ;
 433 : CMOVS  ( dst src -- ) 0x48 MOVcc ;
 434 : CMOVNS ( dst src -- ) 0x49 MOVcc ;
 435 : CMOVP  ( dst src -- ) 0x4a MOVcc ;
 436 : CMOVNP ( dst src -- ) 0x4b MOVcc ;
 437 : CMOVL  ( dst src -- ) 0x4c MOVcc ;
 438 : CMOVGE ( dst src -- ) 0x4d MOVcc ;
 439 : CMOVLE ( dst src -- ) 0x4e MOVcc ;
 440 : CMOVG  ( dst src -- ) 0x4f MOVcc ;
 441
 442 ! CPU Identification
 443
 444 : CPUID ( -- ) 0xa2 extended-opcode, ;
 445
 446 ! Misc
 447
 448 : NOP ( -- ) 0x90 , ;
 449 : PAUSE ( -- ) 0xf3 , 0x90 , ;
 450
 451 : RDTSC ( -- ) 0x0f , 0x31 , ;
 452 : RDPMC ( -- ) 0x0f , 0x33 , ;
 453
 454 ! x87 Floating Point Unit
 455
 456 : FSTPS ( operand -- ) { 0b011 f 0xd9 } 1-operand ;
 457 : FSTPL ( operand -- ) { 0b011 f 0xdd } 1-operand ;
 458
 459 : FLDS ( operand -- ) { 0b000 f 0xd9 } 1-operand ;
 460 : FLDL ( operand -- ) { 0b000 f 0xdd } 1-operand ;
 461
 462 : FNSTCW ( operand -- ) { 0b111 f 0xd9 } 1-operand ;
 463 : FNSTSW ( operand -- ) { 0b111 f 0xdd } 1-operand ;
 464 : FLDCW ( operand -- ) { 0b101 f 0xd9 } 1-operand ;
 465
 466 : FNCLEX ( -- ) 0xdb , 0xe2 , ;
 467 : FNINIT ( -- ) 0xdb , 0xe3 , ;
 468
 469 ERROR: bad-x87-operands ;
 470
 471 <PRIVATE
 472
 473 :: (x87-op) ( operand opcode reg -- )
 474     opcode ,
 475     0b1100,0000 reg
 476     3 shift bitor
 477     operand reg-code bitor , ;
 478
 479 :: x87-st0-op ( src opcode reg -- )
 480     src register?
 481     [ src opcode reg (x87-op) ]
 482     [ bad-x87-operands ] if ;
 483
 484 :: x87-m-st0/n-op ( dst src opcode reg -- )
 485     {
 486         { [ dst ST0 = src indirect? and ] [
 487             src { reg f opcode } 1-operand
 488         ] }
 489         { [ dst ST0 = src register? and ] [
 490             src opcode reg (x87-op)
 491         ] }
 492         { [ src ST0 = dst register? and ] [
 493             dst opcode 4 + reg (x87-op)
 494         ] }
 495         [ bad-x87-operands ]
 496     } cond ;
 497
 498 PRIVATE>
 499
 500 : F2XM1 ( -- ) { 0xD9 0xF0 } % ;
 501 : FABS ( -- ) { 0xD9 0xE1 } % ;
 502 : FADD ( dst src -- ) 0xD8 0 x87-m-st0/n-op ;
 503 : FCHS ( -- ) { 0xD9 0xE0 } % ;
 504
 505 : FCMOVB   ( src -- ) 0xDA 0 x87-st0-op ;
 506 : FCMOVE   ( src -- ) 0xDA 1 x87-st0-op ;
 507 : FCMOVBE  ( src -- ) 0xDA 2 x87-st0-op ;
 508 : FCMOVU   ( src -- ) 0xDA 3 x87-st0-op ;
 509 : FCMOVNB  ( src -- ) 0xDB 0 x87-st0-op ;
 510 : FCMOVNE  ( src -- ) 0xDB 1 x87-st0-op ;
 511 : FCMOVNBE ( src -- ) 0xDB 2 x87-st0-op ;
 512 : FCMOVNU  ( src -- ) 0xDB 3 x87-st0-op ;
 513
 514 : FCOMI ( src -- ) 0xDB 6 x87-st0-op ;
 515 : FUCOMI ( src -- ) 0xDB 5 x87-st0-op ;
 516 : FCOS ( -- ) { 0xD9 0xFF } % ;
 517 : FDECSTP ( -- ) { 0xD9 0xF6 } % ;
 518 : FINCSTP ( -- ) { 0xD9 0xF7 } % ;
 519 : FDIV  ( dst src -- ) 0xD8 6 x87-m-st0/n-op ;
 520 : FDIVR ( dst src -- ) 0xD8 7 x87-m-st0/n-op ;
 521
 522 : FILDD ( src -- )  { 0b000 f 0xDB } 1-operand ;
 523 : FILDQ ( src -- )  { 0b101 f 0xDF } 1-operand ;
 524 : FISTPD ( dst -- ) { 0b011 f 0xDB } 1-operand ;
 525 : FISTPQ ( dst -- ) { 0b111 f 0xDF } 1-operand ;
 526 : FISTTPD ( dst -- ) { 0b001 f 0xDB } 1-operand ;
 527 : FISTTPQ ( dst -- ) { 0b001 f 0xDF } 1-operand ;
 528
 529 : FLD    ( src -- ) 0xD9 0 x87-st0-op ;
 530 : FLD1   ( -- ) { 0xD9 0xE8 } % ;
 531 : FLDL2T ( -- ) { 0xD9 0xE9 } % ;
 532 : FLDL2E ( -- ) { 0xD9 0xEA } % ;
 533 : FLDPI  ( -- ) { 0xD9 0xEB } % ;
 534 : FLDLG2 ( -- ) { 0xD9 0xEC } % ;
 535 : FLDLN2 ( -- ) { 0xD9 0xED } % ;
 536 : FLDZ   ( -- ) { 0xD9 0xEE } % ;
 537
 538 : FMUL ( dst src -- ) 0xD8 1 x87-m-st0/n-op ;
 539 : FNOP ( -- ) { 0xD9 0xD0 } % ;
 540 : FPATAN ( -- ) { 0xD9 0xF3 } % ;
 541 : FPREM  ( -- ) { 0xD9 0xF8 } % ;
 542 : FPREM1 ( -- ) { 0xD9 0xF5 } % ;
 543 : FRNDINT ( -- ) { 0xD9 0xFC } % ;
 544 : FSCALE ( -- ) { 0xD9 0xFD } % ;
 545 : FSIN ( -- ) { 0xD9 0xFE } % ;
 546 : FSINCOS ( -- ) { 0xD9 0xFB } % ;
 547 : FSQRT ( -- ) { 0xD9 0xFA } % ;
 548
 549 : FSUB  ( dst src -- ) 0xD8 0x4 x87-m-st0/n-op ;
 550 : FSUBR ( dst src -- ) 0xD8 0x5 x87-m-st0/n-op ;
 551
 552 : FST  ( src -- ) 0xDD 2 x87-st0-op ;
 553 : FSTP ( src -- ) 0xDD 3 x87-st0-op ;
 554
 555 : FXAM ( -- ) { 0xD9 0xE5 } % ;
 556 : FXCH ( src -- ) 0xD9 1 x87-st0-op ;
 557
 558 : FXTRACT ( -- ) { 0xD9 0xF4 } % ;
 559 : FYL2X ( -- ) { 0xD9 0xF1 } % ;
 560 : FYL2XP1 ( -- ) { 0xD9 0xF1 } % ;
 561
 562 ! SSE multimedia instructions
 563
 564 <PRIVATE
 565
 566 : direction-bit-sse ( dst src op1 -- dst' src' op1' )
 567     pick register-128? [ swapd 0b1 bitor ] unless ;
 568
 569 : 2-operand-sse ( dst src op1 op2 -- )
 570     [ , ] when* direction-bit-sse extended-opcode (2-operand) ;
 571
 572 : direction-op-sse ( dst src op1s -- dst' src' op1' )
 573     pick register-128? [ first ] [ swapd second ] if ;
 574
 575 : 2-operand-rm-mr-sse ( dst src op1{rm,mr} op2 -- )
 576     [ , ] when* direction-op-sse extended-opcode (2-operand) ;
 577
 578 : 2-operand-rm-mr-sse* ( dst src op12{rm,mr} -- )
 579     direction-op-sse first2 [ , ] when* extended-opcode (2-operand) ;
 580
 581 : 2-operand-rm-sse ( dst src op1 op2 -- )
 582     [ , ] when* extended-opcode (2-operand) ;
 583
 584 : 2-operand-mr-sse ( dst src op1 op2 -- )
 585     [ , ] when* extended-opcode swapd (2-operand) ;
 586
 587 : 2-operand-int/sse ( dst src op1 op2 -- )
 588     [ , ] when* extended-opcode (2-operand) ;
 589
 590 :: 3-operand-rm-sse ( dst src imm op1 op2 -- )
 591     dst src op1 op2 2-operand-rm-sse imm , ;
 592
 593 :: 3-operand-mr-sse ( dst src imm op1 op2 -- )
 594     dst src op1 op2 2-operand-mr-sse imm , ;
 595
 596 :: 3-operand-rm-mr-sse ( dst src imm op1 op2 -- )
 597     dst src op1 op2 2-operand-rm-mr-sse imm , ;
 598
 599 : 2-operand-sse-cmp ( dst src cmp op1 op2 -- )
 600     3-operand-rm-sse ; inline
 601
 602 : 2-operand-sse-shift ( dst imm reg op1 op2 -- )
 603     [ , ] when*
 604     [ f 0x0f ] dip 2array 3array
 605     swapd 1-operand , ;
 606
 607 PRIVATE>
 608
 609 : MOVUPS     ( dest src -- ) 0x10 f       2-operand-sse ;
 610 : MOVUPD     ( dest src -- ) 0x10 0x66 2-operand-sse ;
 611 : MOVSD      ( dest src -- ) 0x10 0xf2 2-operand-sse ;
 612 : MOVSS      ( dest src -- ) 0x10 0xf3 2-operand-sse ;
 613 : MOVLPS     ( dest src -- ) 0x12 f       2-operand-sse ;
 614 : MOVLPD     ( dest src -- ) 0x12 0x66 2-operand-sse ;
 615 : MOVDDUP    ( dest src -- ) 0x12 0xf2 2-operand-rm-sse ;
 616 : MOVSLDUP   ( dest src -- ) 0x12 0xf3 2-operand-rm-sse ;
 617 : UNPCKLPS   ( dest src -- ) 0x14 f       2-operand-rm-sse ;
 618 : UNPCKLPD   ( dest src -- ) 0x14 0x66 2-operand-rm-sse ;
 619 : UNPCKHPS   ( dest src -- ) 0x15 f       2-operand-rm-sse ;
 620 : UNPCKHPD   ( dest src -- ) 0x15 0x66 2-operand-rm-sse ;
 621 : MOVHPS     ( dest src -- ) 0x16 f       2-operand-sse ;
 622 : MOVHPD     ( dest src -- ) 0x16 0x66 2-operand-sse ;
 623 : MOVSHDUP   ( dest src -- ) 0x16 0xf3 2-operand-rm-sse ;
 624
 625 ALIAS: MOVHLPS MOVLPS
 626 ALIAS: MOVLHPS MOVHPS
 627
 628 : PREFETCHNTA ( mem -- )  { 0b000 f { 0x0f 0x18 } } 1-operand ;
 629 : PREFETCHT0  ( mem -- )  { 0b001 f { 0x0f 0x18 } } 1-operand ;
 630 : PREFETCHT1  ( mem -- )  { 0b010 f { 0x0f 0x18 } } 1-operand ;
 631 : PREFETCHT2  ( mem -- )  { 0b011 f { 0x0f 0x18 } } 1-operand ;
 632
 633 : MOVAPS     ( dest src -- ) 0x28 f       2-operand-sse ;
 634 : MOVAPD     ( dest src -- ) 0x28 0x66 2-operand-sse ;
 635 : CVTSI2SD   ( dest src -- ) 0x2a 0xf2 2-operand-int/sse ;
 636 : CVTSI2SS   ( dest src -- ) 0x2a 0xf3 2-operand-int/sse ;
 637 : MOVNTPS    ( dest src -- ) 0x2b f       2-operand-mr-sse ;
 638 : MOVNTPD    ( dest src -- ) 0x2b 0x66 2-operand-mr-sse ;
 639 : CVTTSD2SI  ( dest src -- ) 0x2c 0xf2 2-operand-int/sse ;
 640 : CVTTSS2SI  ( dest src -- ) 0x2c 0xf3 2-operand-int/sse ;
 641 : CVTSD2SI   ( dest src -- ) 0x2d 0xf2 2-operand-int/sse ;
 642 : CVTSS2SI   ( dest src -- ) 0x2d 0xf3 2-operand-int/sse ;
 643 : UCOMISS    ( dest src -- ) 0x2e f       2-operand-rm-sse ;
 644 : UCOMISD    ( dest src -- ) 0x2e 0x66 2-operand-rm-sse ;
 645 : COMISS     ( dest src -- ) 0x2f f       2-operand-rm-sse ;
 646 : COMISD     ( dest src -- ) 0x2f 0x66 2-operand-rm-sse ;
 647
 648 : PSHUFB     ( dest src -- ) { 0x38 0x00 } 0x66 2-operand-rm-sse ;
 649 : PHADDW     ( dest src -- ) { 0x38 0x01 } 0x66 2-operand-rm-sse ;
 650 : PHADDD     ( dest src -- ) { 0x38 0x02 } 0x66 2-operand-rm-sse ;
 651 : PHADDSW    ( dest src -- ) { 0x38 0x03 } 0x66 2-operand-rm-sse ;
 652 : PMADDUBSW  ( dest src -- ) { 0x38 0x04 } 0x66 2-operand-rm-sse ;
 653 : PHSUBW     ( dest src -- ) { 0x38 0x05 } 0x66 2-operand-rm-sse ;
 654 : PHSUBD     ( dest src -- ) { 0x38 0x06 } 0x66 2-operand-rm-sse ;
 655 : PHSUBSW    ( dest src -- ) { 0x38 0x07 } 0x66 2-operand-rm-sse ;
 656 : PSIGNB     ( dest src -- ) { 0x38 0x08 } 0x66 2-operand-rm-sse ;
 657 : PSIGNW     ( dest src -- ) { 0x38 0x09 } 0x66 2-operand-rm-sse ;
 658 : PSIGND     ( dest src -- ) { 0x38 0x0a } 0x66 2-operand-rm-sse ;
 659 : PMULHRSW   ( dest src -- ) { 0x38 0x0b } 0x66 2-operand-rm-sse ;
 660 : PBLENDVB   ( dest src -- ) { 0x38 0x10 } 0x66 2-operand-rm-sse ;
 661 : BLENDVPS   ( dest src -- ) { 0x38 0x14 } 0x66 2-operand-rm-sse ;
 662 : BLENDVPD   ( dest src -- ) { 0x38 0x15 } 0x66 2-operand-rm-sse ;
 663 : PTEST      ( dest src -- ) { 0x38 0x17 } 0x66 2-operand-rm-sse ;
 664 : PABSB      ( dest src -- ) { 0x38 0x1c } 0x66 2-operand-rm-sse ;
 665 : PABSW      ( dest src -- ) { 0x38 0x1d } 0x66 2-operand-rm-sse ;
 666 : PABSD      ( dest src -- ) { 0x38 0x1e } 0x66 2-operand-rm-sse ;
 667 : PMOVSXBW   ( dest src -- ) { 0x38 0x20 } 0x66 2-operand-rm-sse ;
 668 : PMOVSXBD   ( dest src -- ) { 0x38 0x21 } 0x66 2-operand-rm-sse ;
 669 : PMOVSXBQ   ( dest src -- ) { 0x38 0x22 } 0x66 2-operand-rm-sse ;
 670 : PMOVSXWD   ( dest src -- ) { 0x38 0x23 } 0x66 2-operand-rm-sse ;
 671 : PMOVSXWQ   ( dest src -- ) { 0x38 0x24 } 0x66 2-operand-rm-sse ;
 672 : PMOVSXDQ   ( dest src -- ) { 0x38 0x25 } 0x66 2-operand-rm-sse ;
 673 : PMULDQ     ( dest src -- ) { 0x38 0x28 } 0x66 2-operand-rm-sse ;
 674 : PCMPEQQ    ( dest src -- ) { 0x38 0x29 } 0x66 2-operand-rm-sse ;
 675 : MOVNTDQA   ( dest src -- ) { 0x38 0x2a } 0x66 2-operand-rm-sse ;
 676 : PACKUSDW   ( dest src -- ) { 0x38 0x2b } 0x66 2-operand-rm-sse ;
 677 : PMOVZXBW   ( dest src -- ) { 0x38 0x30 } 0x66 2-operand-rm-sse ;
 678 : PMOVZXBD   ( dest src -- ) { 0x38 0x31 } 0x66 2-operand-rm-sse ;
 679 : PMOVZXBQ   ( dest src -- ) { 0x38 0x32 } 0x66 2-operand-rm-sse ;
 680 : PMOVZXWD   ( dest src -- ) { 0x38 0x33 } 0x66 2-operand-rm-sse ;
 681 : PMOVZXWQ   ( dest src -- ) { 0x38 0x34 } 0x66 2-operand-rm-sse ;
 682 : PMOVZXDQ   ( dest src -- ) { 0x38 0x35 } 0x66 2-operand-rm-sse ;
 683 : PCMPGTQ    ( dest src -- ) { 0x38 0x37 } 0x66 2-operand-rm-sse ;
 684 : PMINSB     ( dest src -- ) { 0x38 0x38 } 0x66 2-operand-rm-sse ;
 685 : PMINSD     ( dest src -- ) { 0x38 0x39 } 0x66 2-operand-rm-sse ;
 686 : PMINUW     ( dest src -- ) { 0x38 0x3a } 0x66 2-operand-rm-sse ;
 687 : PMINUD     ( dest src -- ) { 0x38 0x3b } 0x66 2-operand-rm-sse ;
 688 : PMAXSB     ( dest src -- ) { 0x38 0x3c } 0x66 2-operand-rm-sse ;
 689 : PMAXSD     ( dest src -- ) { 0x38 0x3d } 0x66 2-operand-rm-sse ;
 690 : PMAXUW     ( dest src -- ) { 0x38 0x3e } 0x66 2-operand-rm-sse ;
 691 : PMAXUD     ( dest src -- ) { 0x38 0x3f } 0x66 2-operand-rm-sse ;
 692 : PMULLD     ( dest src -- ) { 0x38 0x40 } 0x66 2-operand-rm-sse ;
 693 : PHMINPOSUW ( dest src -- ) { 0x38 0x41 } 0x66 2-operand-rm-sse ;
 694 : CRC32B     ( dest src -- ) { 0x38 0xf0 } 0xf2 2-operand-rm-sse ;
 695 : CRC32      ( dest src -- ) { 0x38 0xf1 } 0xf2 2-operand-rm-sse ;
 696
 697 : ROUNDPS    ( dest src imm -- ) { 0x3a 0x08 } 0x66 3-operand-rm-sse ;
 698 : ROUNDPD    ( dest src imm -- ) { 0x3a 0x09 } 0x66 3-operand-rm-sse ;
 699 : ROUNDSS    ( dest src imm -- ) { 0x3a 0x0a } 0x66 3-operand-rm-sse ;
 700 : ROUNDSD    ( dest src imm -- ) { 0x3a 0x0b } 0x66 3-operand-rm-sse ;
 701 : BLENDPS    ( dest src imm -- ) { 0x3a 0x0c } 0x66 3-operand-rm-sse ;
 702 : BLENDPD    ( dest src imm -- ) { 0x3a 0x0d } 0x66 3-operand-rm-sse ;
 703 : PBLENDW    ( dest src imm -- ) { 0x3a 0x0e } 0x66 3-operand-rm-sse ;
 704 : PALIGNR    ( dest src imm -- ) { 0x3a 0x0f } 0x66 3-operand-rm-sse ;
 705
 706 : PEXTRB     ( dest src imm -- ) { 0x3a 0x14 } 0x66 3-operand-mr-sse ;
 707
 708 <PRIVATE
 709 : (PEXTRW-sse1) ( dest src imm -- ) 0xc5 0x66 3-operand-rm-sse ;
 710 : (PEXTRW-sse4) ( dest src imm -- ) { 0x3a 0x15 } 0x66 3-operand-mr-sse ;
 711 PRIVATE>
 712
 713 : PEXTRW     ( dest src imm -- ) pick indirect? [ (PEXTRW-sse4) ] [ (PEXTRW-sse1) ] if ;
 714 : PEXTRD     ( dest src imm -- ) { 0x3a 0x16 } 0x66 3-operand-mr-sse ;
 715 ALIAS: PEXTRQ PEXTRD
 716 : EXTRACTPS  ( dest src imm -- ) { 0x3a 0x17 } 0x66 3-operand-mr-sse ;
 717
 718 : PINSRB     ( dest src imm -- ) { 0x3a 0x20 } 0x66 3-operand-rm-sse ;
 719 : INSERTPS   ( dest src imm -- ) { 0x3a 0x21 } 0x66 3-operand-rm-sse ;
 720 : PINSRD     ( dest src imm -- ) { 0x3a 0x22 } 0x66 3-operand-rm-sse ;
 721 ALIAS: PINSRQ PINSRD
 722 : DPPS       ( dest src imm -- ) { 0x3a 0x40 } 0x66 3-operand-rm-sse ;
 723 : DPPD       ( dest src imm -- ) { 0x3a 0x41 } 0x66 3-operand-rm-sse ;
 724 : MPSADBW    ( dest src imm -- ) { 0x3a 0x42 } 0x66 3-operand-rm-sse ;
 725 : PCMPESTRM  ( dest src imm -- ) { 0x3a 0x60 } 0x66 3-operand-rm-sse ;
 726 : PCMPESTRI  ( dest src imm -- ) { 0x3a 0x61 } 0x66 3-operand-rm-sse ;
 727 : PCMPISTRM  ( dest src imm -- ) { 0x3a 0x62 } 0x66 3-operand-rm-sse ;
 728 : PCMPISTRI  ( dest src imm -- ) { 0x3a 0x63 } 0x66 3-operand-rm-sse ;
 729
 730 : MOVMSKPS   ( dest src -- ) 0x50 f       2-operand-int/sse ;
 731 : MOVMSKPD   ( dest src -- ) 0x50 0x66 2-operand-int/sse ;
 732 : SQRTPS     ( dest src -- ) 0x51 f       2-operand-rm-sse ;
 733 : SQRTPD     ( dest src -- ) 0x51 0x66 2-operand-rm-sse ;
 734 : SQRTSD     ( dest src -- ) 0x51 0xf2 2-operand-rm-sse ;
 735 : SQRTSS     ( dest src -- ) 0x51 0xf3 2-operand-rm-sse ;
 736 : RSQRTPS    ( dest src -- ) 0x52 f       2-operand-rm-sse ;
 737 : RSQRTSS    ( dest src -- ) 0x52 0xf3 2-operand-rm-sse ;
 738 : RCPPS      ( dest src -- ) 0x53 f       2-operand-rm-sse ;
 739 : RCPSS      ( dest src -- ) 0x53 0xf3 2-operand-rm-sse ;
 740 : ANDPS      ( dest src -- ) 0x54 f       2-operand-rm-sse ;
 741 : ANDPD      ( dest src -- ) 0x54 0x66 2-operand-rm-sse ;
 742 : ANDNPS     ( dest src -- ) 0x55 f       2-operand-rm-sse ;
 743 : ANDNPD     ( dest src -- ) 0x55 0x66 2-operand-rm-sse ;
 744 : ORPS       ( dest src -- ) 0x56 f       2-operand-rm-sse ;
 745 : ORPD       ( dest src -- ) 0x56 0x66 2-operand-rm-sse ;
 746 : XORPS      ( dest src -- ) 0x57 f       2-operand-rm-sse ;
 747 : XORPD      ( dest src -- ) 0x57 0x66 2-operand-rm-sse ;
 748 : ADDPS      ( dest src -- ) 0x58 f       2-operand-rm-sse ;
 749 : ADDPD      ( dest src -- ) 0x58 0x66 2-operand-rm-sse ;
 750 : ADDSD      ( dest src -- ) 0x58 0xf2 2-operand-rm-sse ;
 751 : ADDSS      ( dest src -- ) 0x58 0xf3 2-operand-rm-sse ;
 752 : MULPS      ( dest src -- ) 0x59 f       2-operand-rm-sse ;
 753 : MULPD      ( dest src -- ) 0x59 0x66 2-operand-rm-sse ;
 754 : MULSD      ( dest src -- ) 0x59 0xf2 2-operand-rm-sse ;
 755 : MULSS      ( dest src -- ) 0x59 0xf3 2-operand-rm-sse ;
 756 : CVTPS2PD   ( dest src -- ) 0x5a f       2-operand-rm-sse ;
 757 : CVTPD2PS   ( dest src -- ) 0x5a 0x66 2-operand-rm-sse ;
 758 : CVTSD2SS   ( dest src -- ) 0x5a 0xf2 2-operand-rm-sse ;
 759 : CVTSS2SD   ( dest src -- ) 0x5a 0xf3 2-operand-rm-sse ;
 760 : CVTDQ2PS   ( dest src -- ) 0x5b f       2-operand-rm-sse ;
 761 : CVTPS2DQ   ( dest src -- ) 0x5b 0x66 2-operand-rm-sse ;
 762 : CVTTPS2DQ  ( dest src -- ) 0x5b 0xf3 2-operand-rm-sse ;
 763 : SUBPS      ( dest src -- ) 0x5c f       2-operand-rm-sse ;
 764 : SUBPD      ( dest src -- ) 0x5c 0x66 2-operand-rm-sse ;
 765 : SUBSD      ( dest src -- ) 0x5c 0xf2 2-operand-rm-sse ;
 766 : SUBSS      ( dest src -- ) 0x5c 0xf3 2-operand-rm-sse ;
 767 : MINPS      ( dest src -- ) 0x5d f       2-operand-rm-sse ;
 768 : MINPD      ( dest src -- ) 0x5d 0x66 2-operand-rm-sse ;
 769 : MINSD      ( dest src -- ) 0x5d 0xf2 2-operand-rm-sse ;
 770 : MINSS      ( dest src -- ) 0x5d 0xf3 2-operand-rm-sse ;
 771 : DIVPS      ( dest src -- ) 0x5e f       2-operand-rm-sse ;
 772 : DIVPD      ( dest src -- ) 0x5e 0x66 2-operand-rm-sse ;
 773 : DIVSD      ( dest src -- ) 0x5e 0xf2 2-operand-rm-sse ;
 774 : DIVSS      ( dest src -- ) 0x5e 0xf3 2-operand-rm-sse ;
 775 : MAXPS      ( dest src -- ) 0x5f f       2-operand-rm-sse ;
 776 : MAXPD      ( dest src -- ) 0x5f 0x66 2-operand-rm-sse ;
 777 : MAXSD      ( dest src -- ) 0x5f 0xf2 2-operand-rm-sse ;
 778 : MAXSS      ( dest src -- ) 0x5f 0xf3 2-operand-rm-sse ;
 779 : PUNPCKLBW  ( dest src -- ) 0x60 0x66 2-operand-rm-sse ;
 780 : PUNPCKLWD  ( dest src -- ) 0x61 0x66 2-operand-rm-sse ;
 781 : PUNPCKLDQ  ( dest src -- ) 0x62 0x66 2-operand-rm-sse ;
 782 : PACKSSWB   ( dest src -- ) 0x63 0x66 2-operand-rm-sse ;
 783 : PCMPGTB    ( dest src -- ) 0x64 0x66 2-operand-rm-sse ;
 784 : PCMPGTW    ( dest src -- ) 0x65 0x66 2-operand-rm-sse ;
 785 : PCMPGTD    ( dest src -- ) 0x66 0x66 2-operand-rm-sse ;
 786 : PACKUSWB   ( dest src -- ) 0x67 0x66 2-operand-rm-sse ;
 787 : PUNPCKHBW  ( dest src -- ) 0x68 0x66 2-operand-rm-sse ;
 788 : PUNPCKHWD  ( dest src -- ) 0x69 0x66 2-operand-rm-sse ;
 789 : PUNPCKHDQ  ( dest src -- ) 0x6a 0x66 2-operand-rm-sse ;
 790 : PACKSSDW   ( dest src -- ) 0x6b 0x66 2-operand-rm-sse ;
 791 : PUNPCKLQDQ ( dest src -- ) 0x6c 0x66 2-operand-rm-sse ;
 792 : PUNPCKHQDQ ( dest src -- ) 0x6d 0x66 2-operand-rm-sse ;
 793
 794 : MOVD       ( dest src -- ) { 0x6e 0x7e } 0x66 2-operand-rm-mr-sse ;
 795 : MOVDQA     ( dest src -- ) { 0x6f 0x7f } 0x66 2-operand-rm-mr-sse ;
 796 : MOVDQU     ( dest src -- ) { 0x6f 0x7f } 0xf3 2-operand-rm-mr-sse ;
 797
 798 : MOVQ       ( dest src -- )
 799     { { 0x7e 0xf3 } { 0xd6 0x66 } } 2-operand-rm-mr-sse* ;
 800
 801 <PRIVATE
 802
 803 : 2shuffler ( indexes/mask -- mask )
 804     dup integer? [ first2 { 1 0 } bitfield ] unless ;
 805 : 4shuffler ( indexes/mask -- mask )
 806     dup integer? [ first4 { 6 4 2 0 } bitfield ] unless ;
 807
 808 PRIVATE>
 809
 810 : PSHUFD     ( dest src imm -- ) 4shuffler 0x70 0x66 3-operand-rm-sse ;
 811 : PSHUFLW    ( dest src imm -- ) 4shuffler 0x70 0xf2 3-operand-rm-sse ;
 812 : PSHUFHW    ( dest src imm -- ) 4shuffler 0x70 0xf3 3-operand-rm-sse ;
 813
 814 <PRIVATE
 815
 816 : (PSRLW-imm) ( dest imm -- ) 0b010 0x71 0x66 2-operand-sse-shift ;
 817 : (PSRAW-imm) ( dest imm -- ) 0b100 0x71 0x66 2-operand-sse-shift ;
 818 : (PSLLW-imm) ( dest imm -- ) 0b110 0x71 0x66 2-operand-sse-shift ;
 819 : (PSRLD-imm) ( dest imm -- ) 0b010 0x72 0x66 2-operand-sse-shift ;
 820 : (PSRAD-imm) ( dest imm -- ) 0b100 0x72 0x66 2-operand-sse-shift ;
 821 : (PSLLD-imm) ( dest imm -- ) 0b110 0x72 0x66 2-operand-sse-shift ;
 822 : (PSRLQ-imm) ( dest imm -- ) 0b010 0x73 0x66 2-operand-sse-shift ;
 823 : (PSLLQ-imm) ( dest imm -- ) 0b110 0x73 0x66 2-operand-sse-shift ;
 824
 825 : (PSRLW-reg) ( dest src -- ) 0xd1 0x66 2-operand-rm-sse ;
 826 : (PSRLD-reg) ( dest src -- ) 0xd2 0x66 2-operand-rm-sse ;
 827 : (PSRLQ-reg) ( dest src -- ) 0xd3 0x66 2-operand-rm-sse ;
 828 : (PSRAW-reg) ( dest src -- ) 0xe1 0x66 2-operand-rm-sse ;
 829 : (PSRAD-reg) ( dest src -- ) 0xe2 0x66 2-operand-rm-sse ;
 830 : (PSLLW-reg) ( dest src -- ) 0xf1 0x66 2-operand-rm-sse ;
 831 : (PSLLD-reg) ( dest src -- ) 0xf2 0x66 2-operand-rm-sse ;
 832 : (PSLLQ-reg) ( dest src -- ) 0xf3 0x66 2-operand-rm-sse ;
 833
 834 PRIVATE>
 835
 836 : PSRLW ( dest src -- ) dup integer? [ (PSRLW-imm) ] [ (PSRLW-reg) ] if ;
 837 : PSRAW ( dest src -- ) dup integer? [ (PSRAW-imm) ] [ (PSRAW-reg) ] if ;
 838 : PSLLW ( dest src -- ) dup integer? [ (PSLLW-imm) ] [ (PSLLW-reg) ] if ;
 839 : PSRLD ( dest src -- ) dup integer? [ (PSRLD-imm) ] [ (PSRLD-reg) ] if ;
 840 : PSRAD ( dest src -- ) dup integer? [ (PSRAD-imm) ] [ (PSRAD-reg) ] if ;
 841 : PSLLD ( dest src -- ) dup integer? [ (PSLLD-imm) ] [ (PSLLD-reg) ] if ;
 842 : PSRLQ ( dest src -- ) dup integer? [ (PSRLQ-imm) ] [ (PSRLQ-reg) ] if ;
 843 : PSLLQ ( dest src -- ) dup integer? [ (PSLLQ-imm) ] [ (PSLLQ-reg) ] if ;
 844
 845 : PSRLDQ     ( dest imm -- ) 0b011 0x73 0x66 2-operand-sse-shift ;
 846 : PSLLDQ     ( dest imm -- ) 0b111 0x73 0x66 2-operand-sse-shift ;
 847
 848 : PCMPEQB    ( dest src -- ) 0x74 0x66 2-operand-rm-sse ;
 849 : PCMPEQW    ( dest src -- ) 0x75 0x66 2-operand-rm-sse ;
 850 : PCMPEQD    ( dest src -- ) 0x76 0x66 2-operand-rm-sse ;
 851 : HADDPD     ( dest src -- ) 0x7c 0x66 2-operand-rm-sse ;
 852 : HADDPS     ( dest src -- ) 0x7c 0xf2 2-operand-rm-sse ;
 853 : HSUBPD     ( dest src -- ) 0x7d 0x66 2-operand-rm-sse ;
 854 : HSUBPS     ( dest src -- ) 0x7d 0xf2 2-operand-rm-sse ;
 855
 856 : FXSAVE     ( dest -- ) { 0b000 f { 0x0f 0xae } } 1-operand ;
 857 : FXRSTOR    ( src -- )  { 0b001 f { 0x0f 0xae } } 1-operand ;
 858 : LDMXCSR    ( src -- )  { 0b010 f { 0x0f 0xae } } 1-operand ;
 859 : STMXCSR    ( dest -- ) { 0b011 f { 0x0f 0xae } } 1-operand ;
 860 : LFENCE     ( -- ) 0x0f , 0xae , 0o350 , ;
 861 : MFENCE     ( -- ) 0x0f , 0xae , 0o360 , ;
 862 : SFENCE     ( -- ) 0x0f , 0xae , 0o370 , ;
 863 : CLFLUSH    ( dest -- ) { 0b111 f { 0x0f 0xae } } 1-operand ;
 864
 865 : POPCNT     ( dest src -- ) 0xb8 0xf3 2-operand-rm-sse ;
 866
 867 : CMPEQPS    ( dest src -- ) 0 0xc2 f       2-operand-sse-cmp ;
 868 : CMPLTPS    ( dest src -- ) 1 0xc2 f       2-operand-sse-cmp ;
 869 : CMPLEPS    ( dest src -- ) 2 0xc2 f       2-operand-sse-cmp ;
 870 : CMPUNORDPS ( dest src -- ) 3 0xc2 f       2-operand-sse-cmp ;
 871 : CMPNEQPS   ( dest src -- ) 4 0xc2 f       2-operand-sse-cmp ;
 872 : CMPNLTPS   ( dest src -- ) 5 0xc2 f       2-operand-sse-cmp ;
 873 : CMPNLEPS   ( dest src -- ) 6 0xc2 f       2-operand-sse-cmp ;
 874 : CMPORDPS   ( dest src -- ) 7 0xc2 f       2-operand-sse-cmp ;
 875
 876 : CMPEQPD    ( dest src -- ) 0 0xc2 0x66 2-operand-sse-cmp ;
 877 : CMPLTPD    ( dest src -- ) 1 0xc2 0x66 2-operand-sse-cmp ;
 878 : CMPLEPD    ( dest src -- ) 2 0xc2 0x66 2-operand-sse-cmp ;
 879 : CMPUNORDPD ( dest src -- ) 3 0xc2 0x66 2-operand-sse-cmp ;
 880 : CMPNEQPD   ( dest src -- ) 4 0xc2 0x66 2-operand-sse-cmp ;
 881 : CMPNLTPD   ( dest src -- ) 5 0xc2 0x66 2-operand-sse-cmp ;
 882 : CMPNLEPD   ( dest src -- ) 6 0xc2 0x66 2-operand-sse-cmp ;
 883 : CMPORDPD   ( dest src -- ) 7 0xc2 0x66 2-operand-sse-cmp ;
 884
 885 : CMPEQSD    ( dest src -- ) 0 0xc2 0xf2 2-operand-sse-cmp ;
 886 : CMPLTSD    ( dest src -- ) 1 0xc2 0xf2 2-operand-sse-cmp ;
 887 : CMPLESD    ( dest src -- ) 2 0xc2 0xf2 2-operand-sse-cmp ;
 888 : CMPUNORDSD ( dest src -- ) 3 0xc2 0xf2 2-operand-sse-cmp ;
 889 : CMPNEQSD   ( dest src -- ) 4 0xc2 0xf2 2-operand-sse-cmp ;
 890 : CMPNLTSD   ( dest src -- ) 5 0xc2 0xf2 2-operand-sse-cmp ;
 891 : CMPNLESD   ( dest src -- ) 6 0xc2 0xf2 2-operand-sse-cmp ;
 892 : CMPORDSD   ( dest src -- ) 7 0xc2 0xf2 2-operand-sse-cmp ;
 893
 894 : CMPEQSS    ( dest src -- ) 0 0xc2 0xf3 2-operand-sse-cmp ;
 895 : CMPLTSS    ( dest src -- ) 1 0xc2 0xf3 2-operand-sse-cmp ;
 896 : CMPLESS    ( dest src -- ) 2 0xc2 0xf3 2-operand-sse-cmp ;
 897 : CMPUNORDSS ( dest src -- ) 3 0xc2 0xf3 2-operand-sse-cmp ;
 898 : CMPNEQSS   ( dest src -- ) 4 0xc2 0xf3 2-operand-sse-cmp ;
 899 : CMPNLTSS   ( dest src -- ) 5 0xc2 0xf3 2-operand-sse-cmp ;
 900 : CMPNLESS   ( dest src -- ) 6 0xc2 0xf3 2-operand-sse-cmp ;
 901 : CMPORDSS   ( dest src -- ) 7 0xc2 0xf3 2-operand-sse-cmp ;
 902
 903 : MOVNTI     ( dest src -- ) swap { 0x0f 0xc3 } (2-operand) ;
 904
 905 : PINSRW     ( dest src imm -- ) 0xc4 0x66 3-operand-rm-sse ;
 906 : SHUFPS     ( dest src imm -- ) 4shuffler 0xc6 f       3-operand-rm-sse ;
 907 : SHUFPD     ( dest src imm -- ) 2shuffler 0xc6 0x66 3-operand-rm-sse ;
 908
 909 : ADDSUBPD   ( dest src -- ) 0xd0 0x66 2-operand-rm-sse ;
 910 : ADDSUBPS   ( dest src -- ) 0xd0 0xf2 2-operand-rm-sse ;
 911 : PADDQ      ( dest src -- ) 0xd4 0x66 2-operand-rm-sse ;
 912 : PMULLW     ( dest src -- ) 0xd5 0x66 2-operand-rm-sse ;
 913 : PMOVMSKB   ( dest src -- ) 0xd7 0x66 2-operand-rm-sse ;
 914 : PSUBUSB    ( dest src -- ) 0xd8 0x66 2-operand-rm-sse ;
 915 : PSUBUSW    ( dest src -- ) 0xd9 0x66 2-operand-rm-sse ;
 916 : PMINUB     ( dest src -- ) 0xda 0x66 2-operand-rm-sse ;
 917 : PAND       ( dest src -- ) 0xdb 0x66 2-operand-rm-sse ;
 918 : PADDUSB    ( dest src -- ) 0xdc 0x66 2-operand-rm-sse ;
 919 : PADDUSW    ( dest src -- ) 0xdd 0x66 2-operand-rm-sse ;
 920 : PMAXUB     ( dest src -- ) 0xde 0x66 2-operand-rm-sse ;
 921 : PANDN      ( dest src -- ) 0xdf 0x66 2-operand-rm-sse ;
 922 : PAVGB      ( dest src -- ) 0xe0 0x66 2-operand-rm-sse ;
 923 : PAVGW      ( dest src -- ) 0xe3 0x66 2-operand-rm-sse ;
 924 : PMULHUW    ( dest src -- ) 0xe4 0x66 2-operand-rm-sse ;
 925 : PMULHW     ( dest src -- ) 0xe5 0x66 2-operand-rm-sse ;
 926 : CVTTPD2DQ  ( dest src -- ) 0xe6 0x66 2-operand-rm-sse ;
 927 : CVTPD2DQ   ( dest src -- ) 0xe6 0xf2 2-operand-rm-sse ;
 928 : CVTDQ2PD   ( dest src -- ) 0xe6 0xf3 2-operand-rm-sse ;
 929
 930 : MOVNTDQ    ( dest src -- ) 0xe7 0x66 2-operand-mr-sse ;
 931
 932 : PSUBSB     ( dest src -- ) 0xe8 0x66 2-operand-rm-sse ;
 933 : PSUBSW     ( dest src -- ) 0xe9 0x66 2-operand-rm-sse ;
 934 : PMINSW     ( dest src -- ) 0xea 0x66 2-operand-rm-sse ;
 935 : POR        ( dest src -- ) 0xeb 0x66 2-operand-rm-sse ;
 936 : PADDSB     ( dest src -- ) 0xec 0x66 2-operand-rm-sse ;
 937 : PADDSW     ( dest src -- ) 0xed 0x66 2-operand-rm-sse ;
 938 : PMAXSW     ( dest src -- ) 0xee 0x66 2-operand-rm-sse ;
 939 : PXOR       ( dest src -- ) 0xef 0x66 2-operand-rm-sse ;
 940 : LDDQU      ( dest src -- ) 0xf0 0xf2 2-operand-rm-sse ;
 941 : PMULUDQ    ( dest src -- ) 0xf4 0x66 2-operand-rm-sse ;
 942 : PMADDWD    ( dest src -- ) 0xf5 0x66 2-operand-rm-sse ;
 943 : PSADBW     ( dest src -- ) 0xf6 0x66 2-operand-rm-sse ;
 944 : MASKMOVDQU ( dest src -- ) 0xf7 0x66 2-operand-rm-sse ;
 945 : PSUBB      ( dest src -- ) 0xf8 0x66 2-operand-rm-sse ;
 946 : PSUBW      ( dest src -- ) 0xf9 0x66 2-operand-rm-sse ;
 947 : PSUBD      ( dest src -- ) 0xfa 0x66 2-operand-rm-sse ;
 948 : PSUBQ      ( dest src -- ) 0xfb 0x66 2-operand-rm-sse ;
 949 : PADDB      ( dest src -- ) 0xfc 0x66 2-operand-rm-sse ;
 950 : PADDW      ( dest src -- ) 0xfd 0x66 2-operand-rm-sse ;
 951 : PADDD      ( dest src -- ) 0xfe 0x66 2-operand-rm-sse ;
 952
 953 ! x86-64 branch prediction hints
 954
 955 : HWNT ( -- ) 0x2e , ; ! Hint branch Weakly Not Taken
 956 : HST  ( -- ) 0x3e , ; ! Hint branch Strongly Taken
 957
 958 ! interrupt instructions
 959
 960 : INT ( n -- ) dup 3 = [ drop 0xcc , ] [ 0xcd , 1, ] if ;
 961
 962 ! push/pop flags
 963
 964 : PUSHF ( -- ) 0x9c , ;
 965 : POPF  ( -- ) 0x9d , ;