basis/cpu/x86/assembler/assembler.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays io.binary kernel combinators
   4 combinators.short-circuit math math.bitwise locals namespaces
   5 make sequences words system layouts math.order accessors
   6 cpu.x86.assembler.operands cpu.x86.assembler.operands.private ;
   7 IN: cpu.x86.assembler
   8
   9 ! A postfix assembler for x86-32 and x86-64.
  10
  11 <PRIVATE
  12
  13 : reg-code ( reg -- n ) "register" word-prop 7 bitand ;
  14
  15 : indirect-base* ( op -- n ) base>> EBP or reg-code ;
  16
  17 : indirect-index* ( op -- n ) index>> ESP or reg-code ;
  18
  19 : indirect-scale* ( op -- n ) scale>> 0 or ;
  20
  21 GENERIC: sib-present? ( op -- ? )
  22
  23 M: indirect sib-present?
  24     {
  25         [ base>> { ESP RSP R12 } member? ]
  26         [ index>> ]
  27         [ scale>> ]
  28     } 1|| ;
  29
  30 M: register sib-present? drop f ;
  31
  32 GENERIC: r/m ( operand -- n )
  33
  34 M: indirect r/m
  35     dup sib-present?
  36     [ drop ESP reg-code ] [ indirect-base* ] if ;
  37
  38 M: register r/m reg-code ;
  39
  40 ! Immediate operands
  41 UNION: immediate byte integer ;
  42
  43 GENERIC: fits-in-byte? ( value -- ? )
  44
  45 M: byte fits-in-byte? drop t ;
  46
  47 M: integer fits-in-byte? -128 127 between? ;
  48
  49 GENERIC: modifier ( op -- n )
  50
  51 M: indirect modifier
  52     dup base>> [
  53         displacement>> {
  54             { [ dup not ] [ BIN: 00 ] }
  55             { [ dup fits-in-byte? ] [ BIN: 01 ] }
  56             { [ dup immediate? ] [ BIN: 10 ] }
  57         } cond nip
  58     ] [
  59         drop BIN: 00
  60     ] if ;
  61
  62 M: register modifier drop BIN: 11 ;
  63
  64 GENERIC# n, 1 ( value n -- )
  65
  66 M: integer n, >le % ;
  67 M: byte n, [ value>> ] dip n, ;
  68 : 1, ( n -- ) 1 n, ; inline
  69 : 4, ( n -- ) 4 n, ; inline
  70 : 2, ( n -- ) 2 n, ; inline
  71 : cell, ( n -- ) bootstrap-cell n, ; inline
  72
  73 : mod-r/m, ( reg operand -- )
  74     [ 3 shift ] [ [ modifier 6 shift ] [ r/m ] bi ] bi* bitor bitor , ;
  75
  76 : sib, ( operand -- )
  77     dup sib-present? [
  78         [ indirect-base* ]
  79         [ indirect-index* 3 shift ]
  80         [ indirect-scale* 6 shift ] tri bitor bitor ,
  81     ] [
  82         drop
  83     ] if ;
  84
  85 GENERIC: displacement, ( op -- )
  86
  87 M: indirect displacement,
  88     dup displacement>> dup [
  89         swap base>>
  90         [ dup fits-in-byte? [ , ] [ 4, ] if ] [ 4, ] if
  91     ] [ 2drop ] if ;
  92
  93 M: register displacement, drop ;
  94
  95 : addressing ( reg operand -- )
  96     [ mod-r/m, ] [ sib, ] [ displacement, ] tri ;
  97
  98 : rex.w? ( rex.w reg r/m -- ? )
  99     {
 100         { [ over register-128? ] [ nip operand-64? ] }
 101         { [ over not ] [ nip operand-64? ] }
 102         [ drop operand-64? ]
 103     } cond and ;
 104
 105 : rex.r ( m op -- n )
 106     extended? [ BIN: 00000100 bitor ] when ;
 107
 108 : rex.b ( m op -- n )
 109     [ extended? [ BIN: 00000001 bitor ] when ] keep
 110     dup indirect? [ index>> extended? [ BIN: 00000010 bitor ] when ] [ drop ] if ;
 111
 112 : no-prefix? ( prefix reg r/m -- ? )
 113     [ BIN: 01000000 = ]
 114     [ extended-8-bit-register? not ]
 115     [ extended-8-bit-register? not ] tri*
 116     and and ;
 117
 118 :: rex-prefix ( reg r/m rex.w -- )
 119     #! Compile an AMD64 REX prefix.
 120     rex.w reg r/m rex.w? BIN: 01001000 BIN: 01000000 ?
 121     reg rex.r
 122     r/m rex.b
 123     dup reg r/m no-prefix? [ drop ] [ , ] if ;
 124
 125 : 16-prefix ( reg -- )
 126     register-16? [ HEX: 66 , ] when ;
 127
 128 : prefix-1 ( reg rex.w -- )
 129     [ drop 16-prefix ] [ [ f ] 2dip rex-prefix ] 2bi ;
 130
 131 : short-operand ( reg rex.w n -- )
 132     #! Some instructions encode their single operand as part of
 133     #! the opcode.
 134     [ dupd prefix-1 reg-code ] dip + , ;
 135
 136 : opcode, ( opcode -- ) dup array? [ % ] [ , ] if ;
 137
 138 : extended-opcode ( opcode -- opcode' )
 139     dup array? [ OCT: 17 prefix ] [ OCT: 17 swap 2array ] if ;
 140
 141 : extended-opcode, ( opcode -- ) extended-opcode opcode, ;
 142
 143 : opcode-or ( opcode mask -- opcode' )
 144     over array?
 145     [ [ unclip-last ] dip bitor suffix ] [ bitor ] if ;
 146
 147 : 1-operand ( operand reg,rex.w,opcode -- )
 148     #! The 'reg' is not really a register, but a value for the
 149     #! 'reg' field of the mod-r/m byte.
 150     first3 [ [ over ] dip prefix-1 ] dip opcode, swap addressing ;
 151
 152 : immediate-operand-size-bit ( dst imm reg,rex.w,opcode -- imm dst reg,rex.w,opcode )
 153     over integer? [ first3 BIN: 1 opcode-or 3array ] when ;
 154
 155 : immediate-1* ( dst imm reg,rex.w,opcode -- )
 156     swap [ 1-operand ] dip 1, ;
 157
 158 : immediate-1 ( dst imm reg,rex.w,opcode -- )
 159     immediate-operand-size-bit immediate-1* ;
 160
 161 : immediate-4 ( dst imm reg,rex.w,opcode -- )
 162     immediate-operand-size-bit swap [ 1-operand ] dip 4, ;
 163
 164 : immediate-fits-in-size-bit ( dst imm reg,rex.w,opcode -- imm dst reg,rex.w,opcode )
 165     over integer? [ first3 BIN: 10 opcode-or 3array ] when ;
 166
 167 : immediate-1/4 ( dst imm reg,rex.w,opcode -- )
 168     #! If imm is a byte, compile the opcode and the byte.
 169     #! Otherwise, set the 8-bit operand flag in the opcode, and
 170     #! compile the cell. The 'reg' is not really a register, but
 171     #! a value for the 'reg' field of the mod-r/m byte.
 172     over fits-in-byte? [
 173         immediate-fits-in-size-bit immediate-1
 174     ] [
 175         immediate-4
 176     ] if ;
 177
 178 : (2-operand) ( reg operand op -- )
 179     [ 2dup t rex-prefix ] dip opcode,
 180     [ reg-code ] dip addressing ;
 181
 182 : direction-bit ( dst src op -- reg operand op' )
 183     pick register? pick register? not and
 184     [ BIN: 10 opcode-or ] [ swapd ] if ;
 185
 186 : operand-size-bit ( reg operand op -- reg operand op' )
 187     pick register-8? [ BIN: 1 opcode-or ] unless ;
 188
 189 : 2-operand ( dst src op -- )
 190     direction-bit operand-size-bit
 191     pick 16-prefix
 192     (2-operand) ;
 193
 194 PRIVATE>
 195
 196 ! Segment override prefixes
 197 : CS ( -- ) HEX: 2e , ;
 198 : ES ( -- ) HEX: 26 , ;
 199 : SS ( -- ) HEX: 36 , ;
 200 : FS ( -- ) HEX: 64 , ;
 201 : GS ( -- ) HEX: 65 , ;
 202
 203 ! Moving stuff
 204 GENERIC: PUSH ( op -- )
 205 M: register PUSH f HEX: 50 short-operand ;
 206 M: immediate PUSH HEX: 68 , 4, ;
 207 M: operand PUSH { BIN: 110 f HEX: ff } 1-operand ;
 208
 209 GENERIC: POP ( op -- )
 210 M: register POP f HEX: 58 short-operand ;
 211 M: operand POP { BIN: 000 f HEX: 8f } 1-operand ;
 212
 213 ! MOV where the src is immediate.
 214 <PRIVATE
 215
 216 GENERIC# (MOV-I) 1 ( dst src -- )
 217 M: register (MOV-I) [ t HEX: b8 short-operand ] [ cell, ] bi* ;
 218 M: operand (MOV-I)
 219     { BIN: 000 t HEX: c6 }
 220     over byte? [ immediate-1 ] [ immediate-4 ] if ;
 221
 222 PRIVATE>
 223
 224 GENERIC: MOV ( dst src -- )
 225 M: immediate MOV (MOV-I) ;
 226 M: operand MOV HEX: 88 2-operand ;
 227
 228 : LEA ( dst src -- ) swap HEX: 8d 2-operand ;
 229
 230 ! Control flow
 231 GENERIC: JMP ( op -- )
 232 M: integer JMP HEX: e9 , 4, ;
 233 M: operand JMP { BIN: 100 t HEX: ff } 1-operand ;
 234
 235 GENERIC: CALL ( op -- )
 236 M: integer CALL HEX: e8 , 4, ;
 237 M: operand CALL { BIN: 010 t HEX: ff } 1-operand ;
 238
 239 <PRIVATE
 240
 241 GENERIC# JUMPcc 1 ( addr opcode -- )
 242 M: integer JUMPcc extended-opcode, 4, ;
 243
 244 PRIVATE>
 245
 246 : JO  ( dst -- ) HEX: 80 JUMPcc ;
 247 : JNO ( dst -- ) HEX: 81 JUMPcc ;
 248 : JB  ( dst -- ) HEX: 82 JUMPcc ;
 249 : JAE ( dst -- ) HEX: 83 JUMPcc ;
 250 : JE  ( dst -- ) HEX: 84 JUMPcc ; ! aka JZ
 251 : JNE ( dst -- ) HEX: 85 JUMPcc ;
 252 : JBE ( dst -- ) HEX: 86 JUMPcc ;
 253 : JA  ( dst -- ) HEX: 87 JUMPcc ;
 254 : JS  ( dst -- ) HEX: 88 JUMPcc ;
 255 : JNS ( dst -- ) HEX: 89 JUMPcc ;
 256 : JP  ( dst -- ) HEX: 8a JUMPcc ;
 257 : JNP ( dst -- ) HEX: 8b JUMPcc ;
 258 : JL  ( dst -- ) HEX: 8c JUMPcc ;
 259 : JGE ( dst -- ) HEX: 8d JUMPcc ;
 260 : JLE ( dst -- ) HEX: 8e JUMPcc ;
 261 : JG  ( dst -- ) HEX: 8f JUMPcc ;
 262
 263 : LEAVE ( -- ) HEX: c9 , ;
 264
 265 : RET ( n -- )
 266     dup zero? [ drop HEX: c3 , ] [ HEX: c2 , 2, ] if ;
 267
 268 ! Arithmetic
 269
 270 GENERIC: ADD ( dst src -- )
 271 M: immediate ADD { BIN: 000 t HEX: 80 } immediate-1/4 ;
 272 M: operand ADD OCT: 000 2-operand ;
 273
 274 GENERIC: OR ( dst src -- )
 275 M: immediate OR { BIN: 001 t HEX: 80 } immediate-1/4 ;
 276 M: operand OR OCT: 010 2-operand ;
 277
 278 GENERIC: ADC ( dst src -- )
 279 M: immediate ADC { BIN: 010 t HEX: 80 } immediate-1/4 ;
 280 M: operand ADC OCT: 020 2-operand ;
 281
 282 GENERIC: SBB ( dst src -- )
 283 M: immediate SBB { BIN: 011 t HEX: 80 } immediate-1/4 ;
 284 M: operand SBB OCT: 030 2-operand ;
 285
 286 GENERIC: AND ( dst src -- )
 287 M: immediate AND { BIN: 100 t HEX: 80 } immediate-1/4 ;
 288 M: operand AND OCT: 040 2-operand ;
 289
 290 GENERIC: SUB ( dst src -- )
 291 M: immediate SUB { BIN: 101 t HEX: 80 } immediate-1/4 ;
 292 M: operand SUB OCT: 050 2-operand ;
 293
 294 GENERIC: XOR ( dst src -- )
 295 M: immediate XOR { BIN: 110 t HEX: 80 } immediate-1/4 ;
 296 M: operand XOR OCT: 060 2-operand ;
 297
 298 GENERIC: CMP ( dst src -- )
 299 M: immediate CMP { BIN: 111 t HEX: 80 } immediate-1/4 ;
 300 M: operand CMP OCT: 070 2-operand ;
 301
 302 GENERIC: TEST ( dst src -- )
 303 M: immediate TEST { BIN: 0 t HEX: f7 } immediate-4 ;
 304 M: operand TEST OCT: 204 2-operand ;
 305
 306 : XCHG ( dst src -- ) OCT: 207 2-operand ;
 307
 308 : BSR ( dst src -- ) { HEX: 0f HEX: bd } (2-operand) ;
 309
 310 GENERIC: BT ( value n -- )
 311 M: immediate BT ( value n -- ) { BIN: 100 t { HEX: 0f HEX: ba } } immediate-1* ;
 312 M: operand   BT ( value n -- ) swap { HEX: 0f HEX: a3 } (2-operand) ;
 313
 314 GENERIC: BTC ( value n -- )
 315 M: immediate BTC ( value n -- ) { BIN: 111 t { HEX: 0f HEX: ba } } immediate-1* ;
 316 M: operand   BTC ( value n -- ) swap { HEX: 0f HEX: bb } (2-operand) ;
 317
 318 GENERIC: BTR ( value n -- )
 319 M: immediate BTR ( value n -- ) { BIN: 110 t { HEX: 0f HEX: ba } } immediate-1* ;
 320 M: operand   BTR ( value n -- ) swap { HEX: 0f HEX: b3 } (2-operand) ;
 321
 322 GENERIC: BTS ( value n -- )
 323 M: immediate BTS ( value n -- ) { BIN: 101 t { HEX: 0f HEX: ba } } immediate-1* ;
 324 M: operand   BTS ( value n -- ) swap { HEX: 0f HEX: ab } (2-operand) ;
 325
 326 : NOT  ( dst -- ) { BIN: 010 t HEX: f7 } 1-operand ;
 327 : NEG  ( dst -- ) { BIN: 011 t HEX: f7 } 1-operand ;
 328 : MUL  ( dst -- ) { BIN: 100 t HEX: f7 } 1-operand ;
 329 : IMUL ( src -- ) { BIN: 101 t HEX: f7 } 1-operand ;
 330 : DIV  ( dst -- ) { BIN: 110 t HEX: f7 } 1-operand ;
 331 : IDIV ( src -- ) { BIN: 111 t HEX: f7 } 1-operand ;
 332
 333 : CDQ ( -- ) HEX: 99 , ;
 334 : CQO ( -- ) HEX: 48 , CDQ ;
 335
 336 <PRIVATE
 337
 338 :: (SHIFT) ( dst src op -- )
 339     src CL eq? [
 340         dst { op t HEX: d3 } 1-operand
 341     ] [
 342         dst src { op t HEX: c0 } immediate-1
 343     ] if ; inline
 344
 345 PRIVATE>
 346
 347 : ROL ( dst n -- ) BIN: 000 (SHIFT) ;
 348 : ROR ( dst n -- ) BIN: 001 (SHIFT) ;
 349 : RCL ( dst n -- ) BIN: 010 (SHIFT) ;
 350 : RCR ( dst n -- ) BIN: 011 (SHIFT) ;
 351 : SHL ( dst n -- ) BIN: 100 (SHIFT) ;
 352 : SHR ( dst n -- ) BIN: 101 (SHIFT) ;
 353 : SAR ( dst n -- ) BIN: 111 (SHIFT) ;
 354
 355 : IMUL2 ( dst src -- )
 356     OCT: 257 extended-opcode (2-operand) ;
 357
 358 : IMUL3 ( dst src imm -- )
 359     dup fits-in-byte? [
 360         [ swap HEX: 6a 2-operand ] dip 1,
 361     ] [
 362         [ swap HEX: 68 2-operand ] dip 4,
 363     ] if ;
 364
 365 : MOVSX ( dst src -- )
 366     dup register-32? OCT: 143 OCT: 276 extended-opcode ?
 367     over register-16? [ BIN: 1 opcode-or ] when
 368     (2-operand) ;
 369
 370 : MOVZX ( dst src -- )
 371     OCT: 266 extended-opcode
 372     over register-16? [ BIN: 1 opcode-or ] when
 373     (2-operand) ;
 374
 375 ! Conditional move
 376 : MOVcc ( dst src cc -- ) extended-opcode (2-operand) ;
 377
 378 : CMOVO  ( dst src -- ) HEX: 40 MOVcc ;
 379 : CMOVNO ( dst src -- ) HEX: 41 MOVcc ;
 380 : CMOVB  ( dst src -- ) HEX: 42 MOVcc ;
 381 : CMOVAE ( dst src -- ) HEX: 43 MOVcc ;
 382 : CMOVE  ( dst src -- ) HEX: 44 MOVcc ; ! aka CMOVZ
 383 : CMOVNE ( dst src -- ) HEX: 45 MOVcc ;
 384 : CMOVBE ( dst src -- ) HEX: 46 MOVcc ;
 385 : CMOVA  ( dst src -- ) HEX: 47 MOVcc ;
 386 : CMOVS  ( dst src -- ) HEX: 48 MOVcc ;
 387 : CMOVNS ( dst src -- ) HEX: 49 MOVcc ;
 388 : CMOVP  ( dst src -- ) HEX: 4a MOVcc ;
 389 : CMOVNP ( dst src -- ) HEX: 4b MOVcc ;
 390 : CMOVL  ( dst src -- ) HEX: 4c MOVcc ;
 391 : CMOVGE ( dst src -- ) HEX: 4d MOVcc ;
 392 : CMOVLE ( dst src -- ) HEX: 4e MOVcc ;
 393 : CMOVG  ( dst src -- ) HEX: 4f MOVcc ;
 394
 395 ! CPU Identification
 396
 397 : CPUID ( -- ) HEX: a2 extended-opcode, ;
 398
 399 ! Misc
 400
 401 : NOP ( -- ) HEX: 90 , ;
 402 : PAUSE ( -- ) HEX: f3 , HEX: 90 , ;
 403
 404 : RDTSC ( -- ) HEX: 0f , HEX: 31 , ;
 405 : RDPMC ( -- ) HEX: 0f , HEX: 33 , ;
 406
 407 ! x87 Floating Point Unit
 408
 409 : FSTPS ( operand -- ) { BIN: 011 f HEX: d9 } 1-operand ;
 410 : FSTPL ( operand -- ) { BIN: 011 f HEX: dd } 1-operand ;
 411
 412 : FLDS ( operand -- ) { BIN: 000 f HEX: d9 } 1-operand ;
 413 : FLDL ( operand -- ) { BIN: 000 f HEX: dd } 1-operand ;
 414
 415 : FNSTCW ( operand -- ) { BIN: 111 f HEX: d9 } 1-operand ;
 416 : FNSTSW ( operand -- ) { BIN: 111 f HEX: dd } 1-operand ;
 417 : FLDCW ( operand -- ) { BIN: 101 f HEX: d9 } 1-operand ;
 418
 419 : FNCLEX ( -- ) HEX: db , HEX: e2 , ;
 420 : FNINIT ( -- ) HEX: db , HEX: e3 , ;
 421
 422 ! SSE multimedia instructions
 423
 424 <PRIVATE
 425
 426 : direction-bit-sse ( dst src op1 -- dst' src' op1' )
 427     pick register-128? [ swapd BIN: 1 bitor ] unless ;
 428
 429 : 2-operand-sse ( dst src op1 op2 -- )
 430     [ , ] when* direction-bit-sse extended-opcode (2-operand) ;
 431
 432 : direction-op-sse ( dst src op1s -- dst' src' op1' )
 433     pick register-128? [ first ] [ swapd second ] if ;
 434
 435 : 2-operand-rm-mr-sse ( dst src op1{rm,mr} op2 -- )
 436     [ , ] when* direction-op-sse extended-opcode (2-operand) ;
 437
 438 : 2-operand-rm-sse ( dst src op1 op2 -- )
 439     [ , ] when* extended-opcode (2-operand) ;
 440
 441 : 2-operand-mr-sse ( dst src op1 op2 -- )
 442     [ , ] when* extended-opcode swapd (2-operand) ;
 443
 444 : 2-operand-int/sse ( dst src op1 op2 -- )
 445     [ , ] when* extended-opcode (2-operand) ;
 446
 447 :: 3-operand-rm-sse ( dst src imm op1 op2 -- )
 448     dst src op1 op2 2-operand-rm-sse imm , ;
 449
 450 :: 3-operand-mr-sse ( dst src imm op1 op2 -- )
 451     dst src op1 op2 2-operand-mr-sse imm , ;
 452
 453 :: 3-operand-rm-mr-sse ( dst src imm op1 op2 -- )
 454     dst src op1 op2 2-operand-rm-mr-sse imm , ;
 455
 456 : 2-operand-sse-cmp ( dst src cmp op1 op2 -- )
 457     3-operand-rm-sse ; inline
 458
 459 : 2-operand-sse-shift ( dst imm reg op1 op2 -- )
 460     [ , ] when*
 461     [ f HEX: 0f ] dip 2array 3array
 462     swapd 1-operand , ;
 463
 464 PRIVATE>
 465
 466 : MOVUPS     ( dest src -- ) HEX: 10 f       2-operand-sse ;
 467 : MOVUPD     ( dest src -- ) HEX: 10 HEX: 66 2-operand-sse ;
 468 : MOVSD      ( dest src -- ) HEX: 10 HEX: f2 2-operand-sse ;
 469 : MOVSS      ( dest src -- ) HEX: 10 HEX: f3 2-operand-sse ;
 470 : MOVLPS     ( dest src -- ) HEX: 12 f       2-operand-sse ;
 471 : MOVLPD     ( dest src -- ) HEX: 12 HEX: 66 2-operand-sse ;
 472 : MOVDDUP    ( dest src -- ) HEX: 12 HEX: f2 2-operand-rm-sse ;
 473 : MOVSLDUP   ( dest src -- ) HEX: 12 HEX: f3 2-operand-rm-sse ;
 474 : UNPCKLPS   ( dest src -- ) HEX: 14 f       2-operand-rm-sse ;
 475 : UNPCKLPD   ( dest src -- ) HEX: 14 HEX: 66 2-operand-rm-sse ;
 476 : UNPCKHPS   ( dest src -- ) HEX: 15 f       2-operand-rm-sse ;
 477 : UNPCKHPD   ( dest src -- ) HEX: 15 HEX: 66 2-operand-rm-sse ;
 478 : MOVHPS     ( dest src -- ) HEX: 16 f       2-operand-sse ;
 479 : MOVHPD     ( dest src -- ) HEX: 16 HEX: 66 2-operand-sse ;
 480 : MOVSHDUP   ( dest src -- ) HEX: 16 HEX: f3 2-operand-rm-sse ;
 481
 482 ALIAS: MOVHLPS MOVLPS
 483 ALIAS: MOVLHPS MOVHPS
 484
 485 : PREFETCHNTA ( mem -- )  { BIN: 000 f { HEX: 0f HEX: 18 } } 1-operand ;
 486 : PREFETCHT0  ( mem -- )  { BIN: 001 f { HEX: 0f HEX: 18 } } 1-operand ;
 487 : PREFETCHT1  ( mem -- )  { BIN: 010 f { HEX: 0f HEX: 18 } } 1-operand ;
 488 : PREFETCHT2  ( mem -- )  { BIN: 011 f { HEX: 0f HEX: 18 } } 1-operand ;
 489
 490 : MOVAPS     ( dest src -- ) HEX: 28 f       2-operand-sse ;
 491 : MOVAPD     ( dest src -- ) HEX: 28 HEX: 66 2-operand-sse ;
 492 : CVTSI2SD   ( dest src -- ) HEX: 2a HEX: f2 2-operand-int/sse ;
 493 : CVTSI2SS   ( dest src -- ) HEX: 2a HEX: f3 2-operand-int/sse ;
 494 : MOVNTPS    ( dest src -- ) HEX: 2b f       2-operand-mr-sse ;
 495 : MOVNTPD    ( dest src -- ) HEX: 2b HEX: 66 2-operand-mr-sse ;
 496 : CVTTSD2SI  ( dest src -- ) HEX: 2c HEX: f2 2-operand-int/sse ;
 497 : CVTTSS2SI  ( dest src -- ) HEX: 2c HEX: f3 2-operand-int/sse ;
 498 : CVTSD2SI   ( dest src -- ) HEX: 2d HEX: f2 2-operand-int/sse ;
 499 : CVTSS2SI   ( dest src -- ) HEX: 2d HEX: f3 2-operand-int/sse ;
 500 : UCOMISS    ( dest src -- ) HEX: 2e f       2-operand-rm-sse ;
 501 : UCOMISD    ( dest src -- ) HEX: 2e HEX: 66 2-operand-rm-sse ;
 502 : COMISS     ( dest src -- ) HEX: 2f f       2-operand-rm-sse ;
 503 : COMISD     ( dest src -- ) HEX: 2f HEX: 66 2-operand-rm-sse ;
 504
 505 : PSHUFB     ( dest src -- ) { HEX: 38 HEX: 00 } HEX: 66 2-operand-rm-sse ;
 506 : PHADDW     ( dest src -- ) { HEX: 38 HEX: 01 } HEX: 66 2-operand-rm-sse ;
 507 : PHADDD     ( dest src -- ) { HEX: 38 HEX: 02 } HEX: 66 2-operand-rm-sse ;
 508 : PHADDSW    ( dest src -- ) { HEX: 38 HEX: 03 } HEX: 66 2-operand-rm-sse ;
 509 : PMADDUBSW  ( dest src -- ) { HEX: 38 HEX: 04 } HEX: 66 2-operand-rm-sse ;
 510 : PHSUBW     ( dest src -- ) { HEX: 38 HEX: 05 } HEX: 66 2-operand-rm-sse ;
 511 : PHSUBD     ( dest src -- ) { HEX: 38 HEX: 06 } HEX: 66 2-operand-rm-sse ;
 512 : PHSUBSW    ( dest src -- ) { HEX: 38 HEX: 07 } HEX: 66 2-operand-rm-sse ;
 513 : PSIGNB     ( dest src -- ) { HEX: 38 HEX: 08 } HEX: 66 2-operand-rm-sse ;
 514 : PSIGNW     ( dest src -- ) { HEX: 38 HEX: 09 } HEX: 66 2-operand-rm-sse ;
 515 : PSIGND     ( dest src -- ) { HEX: 38 HEX: 0a } HEX: 66 2-operand-rm-sse ;
 516 : PMULHRSW   ( dest src -- ) { HEX: 38 HEX: 0b } HEX: 66 2-operand-rm-sse ;
 517 : PBLENDVB   ( dest src -- ) { HEX: 38 HEX: 10 } HEX: 66 2-operand-rm-sse ;
 518 : BLENDVPS   ( dest src -- ) { HEX: 38 HEX: 14 } HEX: 66 2-operand-rm-sse ;
 519 : BLENDVPD   ( dest src -- ) { HEX: 38 HEX: 15 } HEX: 66 2-operand-rm-sse ;
 520 : PTEST      ( dest src -- ) { HEX: 38 HEX: 17 } HEX: 66 2-operand-rm-sse ;
 521 : PABSB      ( dest src -- ) { HEX: 38 HEX: 1c } HEX: 66 2-operand-rm-sse ;
 522 : PABSW      ( dest src -- ) { HEX: 38 HEX: 1d } HEX: 66 2-operand-rm-sse ;
 523 : PABSD      ( dest src -- ) { HEX: 38 HEX: 1e } HEX: 66 2-operand-rm-sse ;
 524 : PMOVSXBW   ( dest src -- ) { HEX: 38 HEX: 20 } HEX: 66 2-operand-rm-sse ;
 525 : PMOVSXBD   ( dest src -- ) { HEX: 38 HEX: 21 } HEX: 66 2-operand-rm-sse ;
 526 : PMOVSXBQ   ( dest src -- ) { HEX: 38 HEX: 22 } HEX: 66 2-operand-rm-sse ;
 527 : PMOVSXWD   ( dest src -- ) { HEX: 38 HEX: 23 } HEX: 66 2-operand-rm-sse ;
 528 : PMOVSXWQ   ( dest src -- ) { HEX: 38 HEX: 24 } HEX: 66 2-operand-rm-sse ;
 529 : PMOVSXDQ   ( dest src -- ) { HEX: 38 HEX: 25 } HEX: 66 2-operand-rm-sse ;
 530 : PMULDQ     ( dest src -- ) { HEX: 38 HEX: 28 } HEX: 66 2-operand-rm-sse ;
 531 : PCMPEQQ    ( dest src -- ) { HEX: 38 HEX: 29 } HEX: 66 2-operand-rm-sse ;
 532 : MOVNTDQA   ( dest src -- ) { HEX: 38 HEX: 2a } HEX: 66 2-operand-rm-sse ;
 533 : PACKUSDW   ( dest src -- ) { HEX: 38 HEX: 2b } HEX: 66 2-operand-rm-sse ;
 534 : PMOVZXBW   ( dest src -- ) { HEX: 38 HEX: 30 } HEX: 66 2-operand-rm-sse ;
 535 : PMOVZXBD   ( dest src -- ) { HEX: 38 HEX: 31 } HEX: 66 2-operand-rm-sse ;
 536 : PMOVZXBQ   ( dest src -- ) { HEX: 38 HEX: 32 } HEX: 66 2-operand-rm-sse ;
 537 : PMOVZXWD   ( dest src -- ) { HEX: 38 HEX: 33 } HEX: 66 2-operand-rm-sse ;
 538 : PMOVZXWQ   ( dest src -- ) { HEX: 38 HEX: 34 } HEX: 66 2-operand-rm-sse ;
 539 : PMOVZXDQ   ( dest src -- ) { HEX: 38 HEX: 35 } HEX: 66 2-operand-rm-sse ;
 540 : PCMPGTQ    ( dest src -- ) { HEX: 38 HEX: 37 } HEX: 66 2-operand-rm-sse ;
 541 : PMINSB     ( dest src -- ) { HEX: 38 HEX: 38 } HEX: 66 2-operand-rm-sse ;
 542 : PMINSD     ( dest src -- ) { HEX: 38 HEX: 39 } HEX: 66 2-operand-rm-sse ;
 543 : PMINUW     ( dest src -- ) { HEX: 38 HEX: 3a } HEX: 66 2-operand-rm-sse ;
 544 : PMINUD     ( dest src -- ) { HEX: 38 HEX: 3b } HEX: 66 2-operand-rm-sse ;
 545 : PMAXSB     ( dest src -- ) { HEX: 38 HEX: 3c } HEX: 66 2-operand-rm-sse ;
 546 : PMAXSD     ( dest src -- ) { HEX: 38 HEX: 3d } HEX: 66 2-operand-rm-sse ;
 547 : PMAXUW     ( dest src -- ) { HEX: 38 HEX: 3e } HEX: 66 2-operand-rm-sse ;
 548 : PMAXUD     ( dest src -- ) { HEX: 38 HEX: 3f } HEX: 66 2-operand-rm-sse ;
 549 : PMULLD     ( dest src -- ) { HEX: 38 HEX: 40 } HEX: 66 2-operand-rm-sse ;
 550 : PHMINPOSUW ( dest src -- ) { HEX: 38 HEX: 41 } HEX: 66 2-operand-rm-sse ;
 551 : CRC32B     ( dest src -- ) { HEX: 38 HEX: f0 } HEX: f2 2-operand-rm-sse ;
 552 : CRC32      ( dest src -- ) { HEX: 38 HEX: f1 } HEX: f2 2-operand-rm-sse ;
 553
 554 : ROUNDPS    ( dest src imm -- ) { HEX: 3a HEX: 08 } HEX: 66 3-operand-rm-sse ;
 555 : ROUNDPD    ( dest src imm -- ) { HEX: 3a HEX: 09 } HEX: 66 3-operand-rm-sse ;
 556 : ROUNDSS    ( dest src imm -- ) { HEX: 3a HEX: 0a } HEX: 66 3-operand-rm-sse ;
 557 : ROUNDSD    ( dest src imm -- ) { HEX: 3a HEX: 0b } HEX: 66 3-operand-rm-sse ;
 558 : BLENDPS    ( dest src imm -- ) { HEX: 3a HEX: 0c } HEX: 66 3-operand-rm-sse ;
 559 : BLENDPD    ( dest src imm -- ) { HEX: 3a HEX: 0d } HEX: 66 3-operand-rm-sse ;
 560 : PBLENDW    ( dest src imm -- ) { HEX: 3a HEX: 0e } HEX: 66 3-operand-rm-sse ;
 561 : PALIGNR    ( dest src imm -- ) { HEX: 3a HEX: 0f } HEX: 66 3-operand-rm-sse ;
 562
 563 : PEXTRB     ( dest src imm -- ) { HEX: 3a HEX: 14 } HEX: 66 3-operand-mr-sse ;
 564
 565 <PRIVATE
 566 : (PEXTRW-sse1) ( dest src imm -- ) HEX: c5 HEX: 66 3-operand-rm-sse ;
 567 : (PEXTRW-sse4) ( dest src imm -- ) { HEX: 3a HEX: 15 } HEX: 66 3-operand-mr-sse ;
 568 PRIVATE>
 569
 570 : PEXTRW     ( dest src imm -- ) pick indirect? [ (PEXTRW-sse4) ] [ (PEXTRW-sse1) ] if ;
 571 : PEXTRD     ( dest src imm -- ) { HEX: 3a HEX: 16 } HEX: 66 3-operand-mr-sse ;
 572 ALIAS: PEXTRQ PEXTRD
 573 : EXTRACTPS  ( dest src imm -- ) { HEX: 3a HEX: 17 } HEX: 66 3-operand-mr-sse ;
 574
 575 : PINSRB     ( dest src imm -- ) { HEX: 3a HEX: 20 } HEX: 66 3-operand-rm-sse ;
 576 : INSERTPS   ( dest src imm -- ) { HEX: 3a HEX: 21 } HEX: 66 3-operand-rm-sse ;
 577 : PINSRD     ( dest src imm -- ) { HEX: 3a HEX: 22 } HEX: 66 3-operand-rm-sse ;
 578 ALIAS: PINSRQ PINSRD
 579 : DPPS       ( dest src imm -- ) { HEX: 3a HEX: 40 } HEX: 66 3-operand-rm-sse ;
 580 : DPPD       ( dest src imm -- ) { HEX: 3a HEX: 41 } HEX: 66 3-operand-rm-sse ;
 581 : MPSADBW    ( dest src imm -- ) { HEX: 3a HEX: 42 } HEX: 66 3-operand-rm-sse ;
 582 : PCMPESTRM  ( dest src imm -- ) { HEX: 3a HEX: 60 } HEX: 66 3-operand-rm-sse ;
 583 : PCMPESTRI  ( dest src imm -- ) { HEX: 3a HEX: 61 } HEX: 66 3-operand-rm-sse ;
 584 : PCMPISTRM  ( dest src imm -- ) { HEX: 3a HEX: 62 } HEX: 66 3-operand-rm-sse ;
 585 : PCMPISTRI  ( dest src imm -- ) { HEX: 3a HEX: 63 } HEX: 66 3-operand-rm-sse ;
 586
 587 : MOVMSKPS   ( dest src -- ) HEX: 50 f       2-operand-int/sse ;
 588 : MOVMSKPD   ( dest src -- ) HEX: 50 HEX: 66 2-operand-int/sse ;
 589 : SQRTPS     ( dest src -- ) HEX: 51 f       2-operand-rm-sse ;
 590 : SQRTPD     ( dest src -- ) HEX: 51 HEX: 66 2-operand-rm-sse ;
 591 : SQRTSD     ( dest src -- ) HEX: 51 HEX: f2 2-operand-rm-sse ;
 592 : SQRTSS     ( dest src -- ) HEX: 51 HEX: f3 2-operand-rm-sse ;
 593 : RSQRTPS    ( dest src -- ) HEX: 52 f       2-operand-rm-sse ;
 594 : RSQRTSS    ( dest src -- ) HEX: 52 HEX: f3 2-operand-rm-sse ;
 595 : RCPPS      ( dest src -- ) HEX: 53 f       2-operand-rm-sse ;
 596 : RCPSS      ( dest src -- ) HEX: 53 HEX: f3 2-operand-rm-sse ;
 597 : ANDPS      ( dest src -- ) HEX: 54 f       2-operand-rm-sse ;
 598 : ANDPD      ( dest src -- ) HEX: 54 HEX: 66 2-operand-rm-sse ;
 599 : ANDNPS     ( dest src -- ) HEX: 55 f       2-operand-rm-sse ;
 600 : ANDNPD     ( dest src -- ) HEX: 55 HEX: 66 2-operand-rm-sse ;
 601 : ORPS       ( dest src -- ) HEX: 56 f       2-operand-rm-sse ;
 602 : ORPD       ( dest src -- ) HEX: 56 HEX: 66 2-operand-rm-sse ;
 603 : XORPS      ( dest src -- ) HEX: 57 f       2-operand-rm-sse ;
 604 : XORPD      ( dest src -- ) HEX: 57 HEX: 66 2-operand-rm-sse ;
 605 : ADDPS      ( dest src -- ) HEX: 58 f       2-operand-rm-sse ;
 606 : ADDPD      ( dest src -- ) HEX: 58 HEX: 66 2-operand-rm-sse ;
 607 : ADDSD      ( dest src -- ) HEX: 58 HEX: f2 2-operand-rm-sse ;
 608 : ADDSS      ( dest src -- ) HEX: 58 HEX: f3 2-operand-rm-sse ;
 609 : MULPS      ( dest src -- ) HEX: 59 f       2-operand-rm-sse ;
 610 : MULPD      ( dest src -- ) HEX: 59 HEX: 66 2-operand-rm-sse ;
 611 : MULSD      ( dest src -- ) HEX: 59 HEX: f2 2-operand-rm-sse ;
 612 : MULSS      ( dest src -- ) HEX: 59 HEX: f3 2-operand-rm-sse ;
 613 : CVTPS2PD   ( dest src -- ) HEX: 5a f       2-operand-rm-sse ;
 614 : CVTPD2PS   ( dest src -- ) HEX: 5a HEX: 66 2-operand-rm-sse ;
 615 : CVTSD2SS   ( dest src -- ) HEX: 5a HEX: f2 2-operand-rm-sse ;
 616 : CVTSS2SD   ( dest src -- ) HEX: 5a HEX: f3 2-operand-rm-sse ;
 617 : CVTDQ2PS   ( dest src -- ) HEX: 5b f       2-operand-rm-sse ;
 618 : CVTPS2DQ   ( dest src -- ) HEX: 5b HEX: 66 2-operand-rm-sse ;
 619 : CVTTPS2DQ  ( dest src -- ) HEX: 5b HEX: f3 2-operand-rm-sse ;
 620 : SUBPS      ( dest src -- ) HEX: 5c f       2-operand-rm-sse ;
 621 : SUBPD      ( dest src -- ) HEX: 5c HEX: 66 2-operand-rm-sse ;
 622 : SUBSD      ( dest src -- ) HEX: 5c HEX: f2 2-operand-rm-sse ;
 623 : SUBSS      ( dest src -- ) HEX: 5c HEX: f3 2-operand-rm-sse ;
 624 : MINPS      ( dest src -- ) HEX: 5d f       2-operand-rm-sse ;
 625 : MINPD      ( dest src -- ) HEX: 5d HEX: 66 2-operand-rm-sse ;
 626 : MINSD      ( dest src -- ) HEX: 5d HEX: f2 2-operand-rm-sse ;
 627 : MINSS      ( dest src -- ) HEX: 5d HEX: f3 2-operand-rm-sse ;
 628 : DIVPS      ( dest src -- ) HEX: 5e f       2-operand-rm-sse ;
 629 : DIVPD      ( dest src -- ) HEX: 5e HEX: 66 2-operand-rm-sse ;
 630 : DIVSD      ( dest src -- ) HEX: 5e HEX: f2 2-operand-rm-sse ;
 631 : DIVSS      ( dest src -- ) HEX: 5e HEX: f3 2-operand-rm-sse ;
 632 : MAXPS      ( dest src -- ) HEX: 5f f       2-operand-rm-sse ;
 633 : MAXPD      ( dest src -- ) HEX: 5f HEX: 66 2-operand-rm-sse ;
 634 : MAXSD      ( dest src -- ) HEX: 5f HEX: f2 2-operand-rm-sse ;
 635 : MAXSS      ( dest src -- ) HEX: 5f HEX: f3 2-operand-rm-sse ;
 636 : PUNPCKLBW  ( dest src -- ) HEX: 60 HEX: 66 2-operand-rm-sse ;
 637 : PUNPCKLWD  ( dest src -- ) HEX: 61 HEX: 66 2-operand-rm-sse ;
 638 : PUNPCKLDQ  ( dest src -- ) HEX: 62 HEX: 66 2-operand-rm-sse ;
 639 : PACKSSWB   ( dest src -- ) HEX: 63 HEX: 66 2-operand-rm-sse ;
 640 : PCMPGTB    ( dest src -- ) HEX: 64 HEX: 66 2-operand-rm-sse ;
 641 : PCMPGTW    ( dest src -- ) HEX: 65 HEX: 66 2-operand-rm-sse ;
 642 : PCMPGTD    ( dest src -- ) HEX: 66 HEX: 66 2-operand-rm-sse ;
 643 : PACKUSWB   ( dest src -- ) HEX: 67 HEX: 66 2-operand-rm-sse ;
 644 : PUNPCKHBW  ( dest src -- ) HEX: 68 HEX: 66 2-operand-rm-sse ;
 645 : PUNPCKHWD  ( dest src -- ) HEX: 69 HEX: 66 2-operand-rm-sse ;
 646 : PUNPCKHDQ  ( dest src -- ) HEX: 6a HEX: 66 2-operand-rm-sse ;
 647 : PACKSSDW   ( dest src -- ) HEX: 6b HEX: 66 2-operand-rm-sse ;
 648 : PUNPCKLQDQ ( dest src -- ) HEX: 6c HEX: 66 2-operand-rm-sse ;
 649 : PUNPCKHQDQ ( dest src -- ) HEX: 6d HEX: 66 2-operand-rm-sse ;
 650
 651 : MOVD       ( dest src -- ) { HEX: 6e HEX: 7e } HEX: 66 2-operand-rm-mr-sse ;
 652 : MOVDQA     ( dest src -- ) { HEX: 6f HEX: 7f } HEX: 66 2-operand-rm-mr-sse ;
 653 : MOVDQU     ( dest src -- ) { HEX: 6f HEX: 7f } HEX: f3 2-operand-rm-mr-sse ;
 654
 655 <PRIVATE
 656
 657 : 2shuffler ( indexes/mask -- mask )
 658     dup integer? [ first2 { 1 0 } bitfield ] unless ;
 659 : 4shuffler ( indexes/mask -- mask )
 660     dup integer? [ first4 { 6 4 2 0 } bitfield ] unless ;
 661
 662 PRIVATE>
 663
 664 : PSHUFD     ( dest src imm -- ) 4shuffler HEX: 70 HEX: 66 3-operand-rm-sse ;
 665 : PSHUFLW    ( dest src imm -- ) 4shuffler HEX: 70 HEX: f2 3-operand-rm-sse ;
 666 : PSHUFHW    ( dest src imm -- ) 4shuffler HEX: 70 HEX: f3 3-operand-rm-sse ;
 667
 668 <PRIVATE
 669
 670 : (PSRLW-imm) ( dest imm -- ) BIN: 010 HEX: 71 HEX: 66 2-operand-sse-shift ;
 671 : (PSRAW-imm) ( dest imm -- ) BIN: 100 HEX: 71 HEX: 66 2-operand-sse-shift ;
 672 : (PSLLW-imm) ( dest imm -- ) BIN: 110 HEX: 71 HEX: 66 2-operand-sse-shift ;
 673 : (PSRLD-imm) ( dest imm -- ) BIN: 010 HEX: 72 HEX: 66 2-operand-sse-shift ;
 674 : (PSRAD-imm) ( dest imm -- ) BIN: 100 HEX: 72 HEX: 66 2-operand-sse-shift ;
 675 : (PSLLD-imm) ( dest imm -- ) BIN: 110 HEX: 72 HEX: 66 2-operand-sse-shift ;
 676 : (PSRLQ-imm) ( dest imm -- ) BIN: 010 HEX: 73 HEX: 66 2-operand-sse-shift ;
 677 : (PSLLQ-imm) ( dest imm -- ) BIN: 110 HEX: 73 HEX: 66 2-operand-sse-shift ;
 678
 679 : (PSRLW-reg) ( dest src -- ) HEX: d1 HEX: 66 2-operand-rm-sse ;
 680 : (PSRLD-reg) ( dest src -- ) HEX: d2 HEX: 66 2-operand-rm-sse ;
 681 : (PSRLQ-reg) ( dest src -- ) HEX: d3 HEX: 66 2-operand-rm-sse ;
 682 : (PSRAW-reg) ( dest src -- ) HEX: e1 HEX: 66 2-operand-rm-sse ;
 683 : (PSRAD-reg) ( dest src -- ) HEX: e2 HEX: 66 2-operand-rm-sse ;
 684 : (PSLLW-reg) ( dest src -- ) HEX: f1 HEX: 66 2-operand-rm-sse ;
 685 : (PSLLD-reg) ( dest src -- ) HEX: f2 HEX: 66 2-operand-rm-sse ;
 686 : (PSLLQ-reg) ( dest src -- ) HEX: f3 HEX: 66 2-operand-rm-sse ;
 687
 688 PRIVATE>
 689
 690 : PSRLW ( dest src -- ) dup integer? [ (PSRLW-imm) ] [ (PSRLW-reg) ] if ;
 691 : PSRAW ( dest src -- ) dup integer? [ (PSRAW-imm) ] [ (PSRAW-reg) ] if ;
 692 : PSLLW ( dest src -- ) dup integer? [ (PSLLW-imm) ] [ (PSLLW-reg) ] if ;
 693 : PSRLD ( dest src -- ) dup integer? [ (PSRLD-imm) ] [ (PSRLD-reg) ] if ;
 694 : PSRAD ( dest src -- ) dup integer? [ (PSRAD-imm) ] [ (PSRAD-reg) ] if ;
 695 : PSLLD ( dest src -- ) dup integer? [ (PSLLD-imm) ] [ (PSLLD-reg) ] if ;
 696 : PSRLQ ( dest src -- ) dup integer? [ (PSRLQ-imm) ] [ (PSRLQ-reg) ] if ;
 697 : PSLLQ ( dest src -- ) dup integer? [ (PSLLQ-imm) ] [ (PSLLQ-reg) ] if ;
 698
 699 : PSRLDQ     ( dest imm -- ) BIN: 011 HEX: 73 HEX: 66 2-operand-sse-shift ;
 700 : PSLLDQ     ( dest imm -- ) BIN: 111 HEX: 73 HEX: 66 2-operand-sse-shift ;
 701
 702 : PCMPEQB    ( dest src -- ) HEX: 74 HEX: 66 2-operand-rm-sse ;
 703 : PCMPEQW    ( dest src -- ) HEX: 75 HEX: 66 2-operand-rm-sse ;
 704 : PCMPEQD    ( dest src -- ) HEX: 76 HEX: 66 2-operand-rm-sse ;
 705 : HADDPD     ( dest src -- ) HEX: 7c HEX: 66 2-operand-rm-sse ;
 706 : HADDPS     ( dest src -- ) HEX: 7c HEX: f2 2-operand-rm-sse ;
 707 : HSUBPD     ( dest src -- ) HEX: 7d HEX: 66 2-operand-rm-sse ;
 708 : HSUBPS     ( dest src -- ) HEX: 7d HEX: f2 2-operand-rm-sse ;
 709
 710 : FXSAVE     ( dest -- ) { BIN: 000 f { HEX: 0f HEX: ae } } 1-operand ;
 711 : FXRSTOR    ( src -- )  { BIN: 001 f { HEX: 0f HEX: ae } } 1-operand ;
 712 : LDMXCSR    ( src -- )  { BIN: 010 f { HEX: 0f HEX: ae } } 1-operand ;
 713 : STMXCSR    ( dest -- ) { BIN: 011 f { HEX: 0f HEX: ae } } 1-operand ;
 714 : LFENCE     ( -- ) HEX: 0f , HEX: ae , OCT: 350 , ;
 715 : MFENCE     ( -- ) HEX: 0f , HEX: ae , OCT: 360 , ;
 716 : SFENCE     ( -- ) HEX: 0f , HEX: ae , OCT: 370 , ;
 717 : CLFLUSH    ( dest -- ) { BIN: 111 f { HEX: 0f HEX: ae } } 1-operand ;
 718
 719 : POPCNT     ( dest src -- ) HEX: b8 HEX: f3 2-operand-rm-sse ;
 720
 721 : CMPEQPS    ( dest src -- ) 0 HEX: c2 f       2-operand-sse-cmp ;
 722 : CMPLTPS    ( dest src -- ) 1 HEX: c2 f       2-operand-sse-cmp ;
 723 : CMPLEPS    ( dest src -- ) 2 HEX: c2 f       2-operand-sse-cmp ;
 724 : CMPUNORDPS ( dest src -- ) 3 HEX: c2 f       2-operand-sse-cmp ;
 725 : CMPNEQPS   ( dest src -- ) 4 HEX: c2 f       2-operand-sse-cmp ;
 726 : CMPNLTPS   ( dest src -- ) 5 HEX: c2 f       2-operand-sse-cmp ;
 727 : CMPNLEPS   ( dest src -- ) 6 HEX: c2 f       2-operand-sse-cmp ;
 728 : CMPORDPS   ( dest src -- ) 7 HEX: c2 f       2-operand-sse-cmp ;
 729
 730 : CMPEQPD    ( dest src -- ) 0 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 731 : CMPLTPD    ( dest src -- ) 1 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 732 : CMPLEPD    ( dest src -- ) 2 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 733 : CMPUNORDPD ( dest src -- ) 3 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 734 : CMPNEQPD   ( dest src -- ) 4 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 735 : CMPNLTPD   ( dest src -- ) 5 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 736 : CMPNLEPD   ( dest src -- ) 6 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 737 : CMPORDPD   ( dest src -- ) 7 HEX: c2 HEX: 66 2-operand-sse-cmp ;
 738
 739 : CMPEQSD    ( dest src -- ) 0 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 740 : CMPLTSD    ( dest src -- ) 1 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 741 : CMPLESD    ( dest src -- ) 2 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 742 : CMPUNORDSD ( dest src -- ) 3 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 743 : CMPNEQSD   ( dest src -- ) 4 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 744 : CMPNLTSD   ( dest src -- ) 5 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 745 : CMPNLESD   ( dest src -- ) 6 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 746 : CMPORDSD   ( dest src -- ) 7 HEX: c2 HEX: f2 2-operand-sse-cmp ;
 747
 748 : CMPEQSS    ( dest src -- ) 0 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 749 : CMPLTSS    ( dest src -- ) 1 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 750 : CMPLESS    ( dest src -- ) 2 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 751 : CMPUNORDSS ( dest src -- ) 3 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 752 : CMPNEQSS   ( dest src -- ) 4 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 753 : CMPNLTSS   ( dest src -- ) 5 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 754 : CMPNLESS   ( dest src -- ) 6 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 755 : CMPORDSS   ( dest src -- ) 7 HEX: c2 HEX: f3 2-operand-sse-cmp ;
 756
 757 : MOVNTI     ( dest src -- ) swap { HEX: 0f HEX: c3 } (2-operand) ;
 758
 759 : PINSRW     ( dest src imm -- ) HEX: c4 HEX: 66 3-operand-rm-sse ;
 760 : SHUFPS     ( dest src imm -- ) 4shuffler HEX: c6 f       3-operand-rm-sse ;
 761 : SHUFPD     ( dest src imm -- ) 2shuffler HEX: c6 HEX: 66 3-operand-rm-sse ;
 762
 763 : ADDSUBPD   ( dest src -- ) HEX: d0 HEX: 66 2-operand-rm-sse ;
 764 : ADDSUBPS   ( dest src -- ) HEX: d0 HEX: f2 2-operand-rm-sse ;
 765 : PADDQ      ( dest src -- ) HEX: d4 HEX: 66 2-operand-rm-sse ;
 766 : PMULLW     ( dest src -- ) HEX: d5 HEX: 66 2-operand-rm-sse ;
 767 : PMOVMSKB   ( dest src -- ) HEX: d7 HEX: 66 2-operand-rm-sse ;
 768 : PSUBUSB    ( dest src -- ) HEX: d8 HEX: 66 2-operand-rm-sse ;
 769 : PSUBUSW    ( dest src -- ) HEX: d9 HEX: 66 2-operand-rm-sse ;
 770 : PMINUB     ( dest src -- ) HEX: da HEX: 66 2-operand-rm-sse ;
 771 : PAND       ( dest src -- ) HEX: db HEX: 66 2-operand-rm-sse ;
 772 : PADDUSB    ( dest src -- ) HEX: dc HEX: 66 2-operand-rm-sse ;
 773 : PADDUSW    ( dest src -- ) HEX: dd HEX: 66 2-operand-rm-sse ;
 774 : PMAXUB     ( dest src -- ) HEX: de HEX: 66 2-operand-rm-sse ;
 775 : PANDN      ( dest src -- ) HEX: df HEX: 66 2-operand-rm-sse ;
 776 : PAVGB      ( dest src -- ) HEX: e0 HEX: 66 2-operand-rm-sse ;
 777 : PAVGW      ( dest src -- ) HEX: e3 HEX: 66 2-operand-rm-sse ;
 778 : PMULHUW    ( dest src -- ) HEX: e4 HEX: 66 2-operand-rm-sse ;
 779 : PMULHW     ( dest src -- ) HEX: e5 HEX: 66 2-operand-rm-sse ;
 780 : CVTTPD2DQ  ( dest src -- ) HEX: e6 HEX: 66 2-operand-rm-sse ;
 781 : CVTPD2DQ   ( dest src -- ) HEX: e6 HEX: f2 2-operand-rm-sse ;
 782 : CVTDQ2PD   ( dest src -- ) HEX: e6 HEX: f3 2-operand-rm-sse ;
 783
 784 : MOVNTDQ    ( dest src -- ) HEX: e7 HEX: 66 2-operand-mr-sse ;
 785
 786 : PSUBSB     ( dest src -- ) HEX: e8 HEX: 66 2-operand-rm-sse ;
 787 : PSUBSW     ( dest src -- ) HEX: e9 HEX: 66 2-operand-rm-sse ;
 788 : PMINSW     ( dest src -- ) HEX: ea HEX: 66 2-operand-rm-sse ;
 789 : POR        ( dest src -- ) HEX: eb HEX: 66 2-operand-rm-sse ;
 790 : PADDSB     ( dest src -- ) HEX: ec HEX: 66 2-operand-rm-sse ;
 791 : PADDSW     ( dest src -- ) HEX: ed HEX: 66 2-operand-rm-sse ;
 792 : PMAXSW     ( dest src -- ) HEX: ee HEX: 66 2-operand-rm-sse ;
 793 : PXOR       ( dest src -- ) HEX: ef HEX: 66 2-operand-rm-sse ;
 794 : LDDQU      ( dest src -- ) HEX: f0 HEX: f2 2-operand-rm-sse ;
 795 : PMULUDQ    ( dest src -- ) HEX: f4 HEX: 66 2-operand-rm-sse ;
 796 : PMADDWD    ( dest src -- ) HEX: f5 HEX: 66 2-operand-rm-sse ;
 797 : PSADBW     ( dest src -- ) HEX: f6 HEX: 66 2-operand-rm-sse ;
 798 : MASKMOVDQU ( dest src -- ) HEX: f7 HEX: 66 2-operand-rm-sse ;
 799 : PSUBB      ( dest src -- ) HEX: f8 HEX: 66 2-operand-rm-sse ;
 800 : PSUBW      ( dest src -- ) HEX: f9 HEX: 66 2-operand-rm-sse ;
 801 : PSUBD      ( dest src -- ) HEX: fa HEX: 66 2-operand-rm-sse ;
 802 : PSUBQ      ( dest src -- ) HEX: fb HEX: 66 2-operand-rm-sse ;
 803 : PADDB      ( dest src -- ) HEX: fc HEX: 66 2-operand-rm-sse ;
 804 : PADDW      ( dest src -- ) HEX: fd HEX: 66 2-operand-rm-sse ;
 805 : PADDD      ( dest src -- ) HEX: fe HEX: 66 2-operand-rm-sse ;
 806
 807 ! x86-64 branch prediction hints
 808
 809 : HWNT ( -- ) HEX: 2e , ; ! Hint branch Weakly Not Taken
 810 : HST  ( -- ) HEX: 3e , ; ! Hint branch Strongly Taken