basis/cpu/x86/x86.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs alien alien.c-types arrays strings
   4 cpu.x86.assembler cpu.x86.assembler.private cpu.architecture
   5 kernel kernel.private math memory namespaces make sequences
   6 words system layouts combinators math.order fry locals
   7 compiler.constants compiler.cfg.registers
   8 compiler.cfg.instructions compiler.cfg.intrinsics
   9 compiler.codegen compiler.codegen.fixup ;
  10 IN: cpu.x86
  11
  12 << enable-fixnum-log2 >>
  13
  14 ! Add some methods to the assembler to be more useful to the backend
  15 M: label JMP 0 JMP rc-relative label-fixup ;
  16 M: label JUMPcc [ 0 ] dip JUMPcc rc-relative label-fixup ;
  17
  18 M: x86 two-operand? t ;
  19
  20 HOOK: temp-reg-1 cpu ( -- reg )
  21 HOOK: temp-reg-2 cpu ( -- reg )
  22
  23 HOOK: param-reg-1 cpu ( -- reg )
  24 HOOK: param-reg-2 cpu ( -- reg )
  25
  26 M: x86 %load-immediate MOV ;
  27
  28 M: x86 %load-reference swap 0 MOV rc-absolute-cell rel-immediate ;
  29
  30 HOOK: ds-reg cpu ( -- reg )
  31 HOOK: rs-reg cpu ( -- reg )
  32
  33 : reg-stack ( n reg -- op ) swap cells neg [+] ;
  34
  35 GENERIC: loc>operand ( loc -- operand )
  36
  37 M: ds-loc loc>operand n>> ds-reg reg-stack ;
  38 M: rs-loc loc>operand n>> rs-reg reg-stack ;
  39
  40 M: x86 %peek loc>operand MOV ;
  41 M: x86 %replace loc>operand swap MOV ;
  42 : (%inc) ( n reg -- ) swap cells dup 0 > [ ADD ] [ neg SUB ] if ; inline
  43 M: x86 %inc-d ( n -- ) ds-reg (%inc) ;
  44 M: x86 %inc-r ( n -- ) rs-reg (%inc) ;
  45
  46 : align-stack ( n -- n' )
  47     os macosx? cpu x86.64? or [ 16 align ] when ;
  48
  49 HOOK: reserved-area-size cpu ( -- n )
  50
  51 M: x86 stack-frame-size ( stack-frame -- i )
  52     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
  53     [ params>> ]
  54     [ return>> ]
  55     tri + +
  56     3 cells +
  57     reserved-area-size +
  58     align-stack ;
  59
  60 M: x86 %call ( word -- ) 0 CALL rc-relative rel-word-pic ;
  61 M: x86 %jump ( word -- ) 0 JMP rc-relative rel-word ;
  62 M: x86 %jump-label ( label -- ) 0 JMP rc-relative label-fixup ;
  63 M: x86 %return ( -- ) 0 RET ;
  64
  65 : code-alignment ( align -- n )
  66     [ building get [ integer? ] count dup ] dip align swap - ;
  67
  68 : align-code ( n -- )
  69     0 <repetition> % ;
  70
  71 M: x86 %dispatch-label ( word -- )
  72     0 cell, rc-absolute-cell rel-word ;
  73
  74 :: (%slot) ( obj slot tag temp -- op )
  75     temp slot obj [+] LEA
  76     temp tag neg [+] ; inline
  77
  78 :: (%slot-imm) ( obj slot tag -- op )
  79     obj slot cells tag - [+] ; inline
  80
  81 M: x86 %slot ( dst obj slot tag temp -- ) (%slot) MOV ;
  82 M: x86 %slot-imm ( dst obj slot tag -- ) (%slot-imm) MOV ;
  83 M: x86 %set-slot ( src obj slot tag temp -- ) (%slot) swap MOV ;
  84 M: x86 %set-slot-imm ( src obj slot tag -- ) (%slot-imm) swap MOV ;
  85
  86 M: x86 %add     [+] LEA ;
  87 M: x86 %add-imm [+] LEA ;
  88 M: x86 %sub     nip SUB ;
  89 M: x86 %sub-imm neg [+] LEA ;
  90 M: x86 %mul     nip swap IMUL2 ;
  91 M: x86 %mul-imm nip IMUL2 ;
  92 M: x86 %and     nip AND ;
  93 M: x86 %and-imm nip AND ;
  94 M: x86 %or      nip OR ;
  95 M: x86 %or-imm  nip OR ;
  96 M: x86 %xor     nip XOR ;
  97 M: x86 %xor-imm nip XOR ;
  98 M: x86 %shl-imm nip SHL ;
  99 M: x86 %shr-imm nip SHR ;
 100 M: x86 %sar-imm nip SAR ;
 101 M: x86 %not     drop NOT ;
 102 M: x86 %log2    BSR ;
 103
 104 : ?MOV ( dst src -- )
 105     2dup = [ 2drop ] [ MOV ] if ; inline
 106
 107 :: move>args ( src1 src2 -- )
 108     {
 109         { [ src1 param-reg-2 = ] [ param-reg-1 src2 ?MOV param-reg-1 param-reg-2 XCHG ] }
 110         { [ src1 param-reg-1 = ] [ param-reg-2 src2 ?MOV ] }
 111         { [ src2 param-reg-1 = ] [ param-reg-2 src1 ?MOV param-reg-1 param-reg-2 XCHG ] }
 112         { [ src2 param-reg-2 = ] [ param-reg-1 src1 ?MOV ] }
 113         [
 114             param-reg-1 src1 MOV
 115             param-reg-2 src2 MOV
 116         ]
 117     } cond ;
 118
 119 HOOK: %alien-invoke-tail cpu ( func dll -- )
 120
 121 :: overflow-template ( src1 src2 insn inverse func -- )
 122     <label> "no-overflow" set
 123     src1 src2 insn call
 124     ds-reg [] src1 MOV
 125     "no-overflow" get JNO
 126     src1 src2 inverse call
 127     src1 src2 move>args
 128     %prepare-alien-invoke
 129     func f %alien-invoke
 130     "no-overflow" resolve-label ; inline
 131
 132 :: overflow-template-tail ( src1 src2 insn inverse func -- )
 133     <label> "no-overflow" set
 134     src1 src2 insn call
 135     "no-overflow" get JNO
 136     src1 src2 inverse call
 137     src1 src2 move>args
 138     %prepare-alien-invoke
 139     func f %alien-invoke-tail
 140     "no-overflow" resolve-label
 141     ds-reg [] src1 MOV
 142     0 RET ; inline
 143
 144 M: x86 %fixnum-add ( src1 src2 -- )
 145     [ ADD ] [ SUB ] "overflow_fixnum_add" overflow-template ;
 146
 147 M: x86 %fixnum-add-tail ( src1 src2 -- )
 148     [ ADD ] [ SUB ] "overflow_fixnum_add" overflow-template-tail ;
 149
 150 M: x86 %fixnum-sub ( src1 src2 -- )
 151     [ SUB ] [ ADD ] "overflow_fixnum_subtract" overflow-template ;
 152
 153 M: x86 %fixnum-sub-tail ( src1 src2 -- )
 154     [ SUB ] [ ADD ] "overflow_fixnum_subtract" overflow-template-tail ;
 155
 156 M:: x86 %fixnum-mul ( src1 src2 temp1 temp2 -- )
 157     "no-overflow" define-label
 158     temp1 src1 MOV
 159     temp1 tag-bits get SAR
 160     src2 temp1 IMUL2
 161     ds-reg [] temp1 MOV
 162     "no-overflow" get JNO
 163     src1 src2 move>args
 164     param-reg-1 tag-bits get SAR
 165     param-reg-2 tag-bits get SAR
 166     %prepare-alien-invoke
 167     "overflow_fixnum_multiply" f %alien-invoke
 168     "no-overflow" resolve-label ;
 169
 170 M:: x86 %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 171     "overflow" define-label
 172     temp1 src1 MOV
 173     temp1 tag-bits get SAR
 174     src2 temp1 IMUL2
 175     "overflow" get JO
 176     ds-reg [] temp1 MOV
 177     0 RET
 178     "overflow" resolve-label
 179     src1 src2 move>args
 180     param-reg-1 tag-bits get SAR
 181     param-reg-2 tag-bits get SAR
 182     %prepare-alien-invoke
 183     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 184
 185 : bignum@ ( reg n -- op )
 186     cells bignum tag-number - [+] ; inline
 187
 188 M:: x86 %integer>bignum ( dst src temp -- )
 189     #! on entry, inreg is a signed 32-bit quantity
 190     #! exits with tagged ptr to bignum in outreg
 191     #! 1 cell header, 1 cell length, 1 cell sign, + digits
 192     #! length is the # of digits + sign
 193     [
 194         "end" define-label
 195         ! Load cached zero value
 196         dst 0 >bignum %load-reference
 197         src 0 CMP
 198         ! Is it zero? Then just go to the end and return this zero
 199         "end" get JE
 200         ! Allocate a bignum
 201         dst 4 cells bignum temp %allot
 202         ! Write length
 203         dst 1 bignum@ 2 tag-fixnum MOV
 204         ! Store value
 205         dst 3 bignum@ src MOV
 206         ! Compute sign
 207         temp src MOV
 208         temp cell-bits 1- SAR
 209         temp 1 AND
 210         ! Store sign
 211         dst 2 bignum@ temp MOV
 212         ! Make negative value positive
 213         temp temp ADD
 214         temp NEG
 215         temp 1 ADD
 216         src temp IMUL2
 217         ! Store the bignum
 218         dst 3 bignum@ temp MOV
 219         "end" resolve-label
 220     ] with-scope ;
 221
 222 M:: x86 %bignum>integer ( dst src temp -- )
 223     [
 224         "end" define-label
 225         ! load length
 226         temp src 1 bignum@ MOV
 227         ! if the length is 1, its just the sign and nothing else,
 228         ! so output 0
 229         dst 0 MOV
 230         temp 1 tag-fixnum CMP
 231         "end" get JE
 232         ! load the value
 233         dst src 3 bignum@ MOV
 234         ! load the sign
 235         temp src 2 bignum@ MOV
 236         ! convert it into -1 or 1
 237         temp temp ADD
 238         temp NEG
 239         temp 1 ADD
 240         ! make dst signed
 241         temp dst IMUL2
 242         "end" resolve-label
 243     ] with-scope ;
 244
 245 M: x86 %add-float nip ADDSD ;
 246 M: x86 %sub-float nip SUBSD ;
 247 M: x86 %mul-float nip MULSD ;
 248 M: x86 %div-float nip DIVSD ;
 249
 250 M: x86 %integer>float CVTSI2SD ;
 251 M: x86 %float>integer CVTTSD2SI ;
 252
 253 M: x86 %copy ( dst src -- ) ?MOV ;
 254
 255 M: x86 %copy-float ( dst src -- )
 256     2dup = [ 2drop ] [ MOVSD ] if ;
 257
 258 M: x86 %unbox-float ( dst src -- )
 259     float-offset [+] MOVSD ;
 260
 261 M:: x86 %unbox-any-c-ptr ( dst src temp -- )
 262     [
 263         { "is-byte-array" "end" "start" } [ define-label ] each
 264         dst 0 MOV
 265         temp src MOV
 266         ! We come back here with displaced aliens
 267         "start" resolve-label
 268         ! Is the object f?
 269         temp \ f tag-number CMP
 270         "end" get JE
 271         ! Is the object an alien?
 272         temp header-offset [+] alien type-number tag-fixnum CMP
 273         "is-byte-array" get JNE
 274         ! If so, load the offset and add it to the address
 275         dst temp alien-offset [+] ADD
 276         ! Now recurse on the underlying alien
 277         temp temp underlying-alien-offset [+] MOV
 278         "start" get JMP
 279         "is-byte-array" resolve-label
 280         ! Add byte array address to address being computed
 281         dst temp ADD
 282         ! Add an offset to start of byte array's data
 283         dst byte-array-offset ADD
 284         "end" resolve-label
 285     ] with-scope ;
 286
 287 M:: x86 %box-float ( dst src temp -- )
 288     dst 16 float temp %allot
 289     dst float-offset [+] src MOVSD ;
 290
 291 : alien@ ( reg n -- op ) cells alien tag-number - [+] ;
 292
 293 M:: x86 %box-alien ( dst src temp -- )
 294     [
 295         "end" define-label
 296         dst \ f tag-number MOV
 297         src 0 CMP
 298         "end" get JE
 299         dst 4 cells alien temp %allot
 300         dst 1 alien@ \ f tag-number MOV
 301         dst 2 alien@ \ f tag-number MOV
 302         ! Store src in alien-offset slot
 303         dst 3 alien@ src MOV
 304         "end" resolve-label
 305     ] with-scope ;
 306
 307 : small-reg-4 ( reg -- reg' )
 308     H{
 309         { EAX EAX }
 310         { ECX ECX }
 311         { EDX EDX }
 312         { EBX EBX }
 313         { ESP ESP }
 314         { EBP EBP }
 315         { ESI ESP }
 316         { EDI EDI }
 317
 318         { RAX EAX }
 319         { RCX ECX }
 320         { RDX EDX }
 321         { RBX EBX }
 322         { RSP ESP }
 323         { RBP EBP }
 324         { RSI ESP }
 325         { RDI EDI }
 326     } at ; inline
 327
 328 : small-reg-2 ( reg -- reg' )
 329     small-reg-4 H{
 330         { EAX AX }
 331         { ECX CX }
 332         { EDX DX }
 333         { EBX BX }
 334         { ESP SP }
 335         { EBP BP }
 336         { ESI SI }
 337         { EDI DI }
 338     } at ; inline
 339
 340 : small-reg-1 ( reg -- reg' )
 341     small-reg-4 {
 342         { EAX AL }
 343         { ECX CL }
 344         { EDX DL }
 345         { EBX BL }
 346     } at ; inline
 347
 348 : small-reg ( reg size -- reg' )
 349     {
 350         { 1 [ small-reg-1 ] }
 351         { 2 [ small-reg-2 ] }
 352         { 4 [ small-reg-4 ] }
 353     } case ;
 354
 355 : small-regs ( -- regs ) { EAX ECX EDX EBX } ; inline
 356
 357 : small-reg-that-isn't ( exclude -- reg' )
 358     small-regs swap [ small-reg-4 ] map '[ _ memq? not ] find nip ;
 359
 360 : with-save/restore ( reg quot -- )
 361     [ drop PUSH ] [ call ] [ drop POP ] 2tri ; inline
 362
 363 :: with-small-register ( dst exclude quot: ( new-dst -- ) -- )
 364     #! If the destination register overlaps a small register, we
 365     #! call the quot with that. Otherwise, we find a small
 366     #! register that is not in exclude, and call quot, saving
 367     #! and restoring the small register.
 368     dst small-reg-4 small-regs memq? [ dst quot call ] [
 369         exclude small-reg-that-isn't
 370         [ quot call ] with-save/restore
 371     ] if ; inline
 372
 373 M:: x86 %string-nth ( dst src index temp -- )
 374     "end" define-label
 375     dst { src index temp } [| new-dst |
 376         ! Load the least significant 7 bits into new-dst.
 377         ! 8th bit indicates whether we have to load from
 378         ! the aux vector or not.
 379         temp src index [+] LEA
 380         new-dst 1 small-reg temp string-offset [+] MOV
 381         new-dst new-dst 1 small-reg MOVZX
 382         ! Do we have to look at the aux vector?
 383         new-dst HEX: 80 CMP
 384         "end" get JL
 385         ! Yes, this is a non-ASCII character. Load aux vector
 386         temp src string-aux-offset [+] MOV
 387         new-dst temp XCHG
 388         ! Compute index
 389         new-dst index ADD
 390         new-dst index ADD
 391         ! Load high 16 bits
 392         new-dst 2 small-reg new-dst byte-array-offset [+] MOV
 393         new-dst new-dst 2 small-reg MOVZX
 394         new-dst 7 SHL
 395         ! Compute code point
 396         new-dst temp XOR
 397         "end" resolve-label
 398         dst new-dst ?MOV
 399     ] with-small-register ;
 400
 401 M:: x86 %set-string-nth-fast ( ch str index temp -- )
 402     ch { index str temp } [| new-ch |
 403         new-ch ch ?MOV
 404         temp str index [+] LEA
 405         temp string-offset [+] new-ch 1 small-reg MOV
 406     ] with-small-register ;
 407
 408 :: %alien-integer-getter ( dst src size quot -- )
 409     dst { src } [| new-dst |
 410         new-dst dup size small-reg dup src [] MOV
 411         quot call
 412         dst new-dst ?MOV
 413     ] with-small-register ; inline
 414
 415 : %alien-unsigned-getter ( dst src size -- )
 416     [ MOVZX ] %alien-integer-getter ; inline
 417
 418 M: x86 %alien-unsigned-1 1 %alien-unsigned-getter ;
 419 M: x86 %alien-unsigned-2 2 %alien-unsigned-getter ;
 420
 421 : %alien-signed-getter ( dst src size -- )
 422     [ MOVSX ] %alien-integer-getter ; inline
 423
 424 M: x86 %alien-signed-1 1 %alien-signed-getter ;
 425 M: x86 %alien-signed-2 2 %alien-signed-getter ;
 426 M: x86 %alien-signed-4 4 %alien-signed-getter ;
 427
 428 M: x86 %alien-unsigned-4 4 [ 2drop ] %alien-integer-getter ;
 429
 430 M: x86 %alien-cell [] MOV ;
 431 M: x86 %alien-float dupd [] MOVSS dup CVTSS2SD ;
 432 M: x86 %alien-double [] MOVSD ;
 433
 434 :: %alien-integer-setter ( ptr value size -- )
 435     value { ptr } [| new-value |
 436         new-value value ?MOV
 437         ptr [] new-value size small-reg MOV
 438     ] with-small-register ; inline
 439
 440 M: x86 %set-alien-integer-1 1 %alien-integer-setter ;
 441 M: x86 %set-alien-integer-2 2 %alien-integer-setter ;
 442 M: x86 %set-alien-integer-4 4 %alien-integer-setter ;
 443 M: x86 %set-alien-cell [ [] ] dip MOV ;
 444 M: x86 %set-alien-float dup dup CVTSD2SS [ [] ] dip MOVSS ;
 445 M: x86 %set-alien-double [ [] ] dip MOVSD ;
 446
 447 : load-zone-ptr ( reg -- )
 448     #! Load pointer to start of zone array
 449     0 MOV "nursery" f rc-absolute-cell rel-dlsym ;
 450
 451 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 452     [ drop load-zone-ptr ] [ swap cell [+] MOV ] 2bi ;
 453
 454 : inc-allot-ptr ( nursery-ptr n -- )
 455     [ cell [+] ] dip 8 align ADD ;
 456
 457 : store-header ( temp class -- )
 458     [ [] ] [ type-number tag-fixnum ] bi* MOV ;
 459
 460 : store-tagged ( dst tag -- )
 461     tag-number OR ;
 462
 463 M:: x86 %allot ( dst size class nursery-ptr -- )
 464     nursery-ptr dst load-allot-ptr
 465     dst class store-header
 466     dst class store-tagged
 467     nursery-ptr size inc-allot-ptr ;
 468
 469 M:: x86 %write-barrier ( src card# table -- )
 470     #! Mark the card pointed to by vreg.
 471     ! Mark the card
 472     card# src MOV
 473     card# card-bits SHR
 474     table "cards_offset" f %alien-global
 475     table table [] MOV
 476     table card# [+] card-mark <byte> MOV
 477
 478     ! Mark the card deck
 479     card# deck-bits card-bits - SHR
 480     table "decks_offset" f %alien-global
 481     table table [] MOV
 482     table card# [+] card-mark <byte> MOV ;
 483
 484 M: x86 %gc ( -- )
 485     "end" define-label
 486     temp-reg-1 load-zone-ptr
 487     temp-reg-2 temp-reg-1 cell [+] MOV
 488     temp-reg-2 1024 ADD
 489     temp-reg-1 temp-reg-1 3 cells [+] MOV
 490     temp-reg-2 temp-reg-1 CMP
 491     "end" get JLE
 492     %prepare-alien-invoke
 493     "minor_gc" f %alien-invoke
 494     "end" resolve-label ;
 495
 496 M: x86 %alien-global
 497     [ 0 MOV ] 2dip rc-absolute-cell rel-dlsym ;
 498
 499 HOOK: stack-reg cpu ( -- reg )
 500
 501 : decr-stack-reg ( n -- )
 502     dup 0 = [ drop ] [ stack-reg swap SUB ] if ;
 503
 504 : incr-stack-reg ( n -- )
 505     dup 0 = [ drop ] [ stack-reg swap ADD ] if ;
 506
 507 M: x86 %epilogue ( n -- ) cell - incr-stack-reg ;
 508
 509 :: %boolean ( dst temp word -- )
 510     dst \ f tag-number MOV
 511     temp 0 MOV \ t rc-absolute-cell rel-immediate
 512     dst temp word execute ; inline
 513
 514 M: x86 %compare ( dst temp cc src1 src2 -- )
 515     CMP {
 516         { cc< [ \ CMOVL %boolean ] }
 517         { cc<= [ \ CMOVLE %boolean ] }
 518         { cc> [ \ CMOVG %boolean ] }
 519         { cc>= [ \ CMOVGE %boolean ] }
 520         { cc= [ \ CMOVE %boolean ] }
 521         { cc/= [ \ CMOVNE %boolean ] }
 522     } case ;
 523
 524 M: x86 %compare-imm ( dst temp cc src1 src2 -- )
 525     %compare ;
 526
 527 M: x86 %compare-float ( dst temp cc src1 src2 -- )
 528     UCOMISD {
 529         { cc< [ \ CMOVB %boolean ] }
 530         { cc<= [ \ CMOVBE %boolean ] }
 531         { cc> [ \ CMOVA %boolean ] }
 532         { cc>= [ \ CMOVAE %boolean ] }
 533         { cc= [ \ CMOVE %boolean ] }
 534         { cc/= [ \ CMOVNE %boolean ] }
 535     } case ;
 536
 537 M: x86 %compare-branch ( label cc src1 src2 -- )
 538     CMP {
 539         { cc< [ JL ] }
 540         { cc<= [ JLE ] }
 541         { cc> [ JG ] }
 542         { cc>= [ JGE ] }
 543         { cc= [ JE ] }
 544         { cc/= [ JNE ] }
 545     } case ;
 546
 547 M: x86 %compare-imm-branch ( label src1 src2 cc -- )
 548     %compare-branch ;
 549
 550 M: x86 %compare-float-branch ( label cc src1 src2 -- )
 551     UCOMISD {
 552         { cc< [ JB ] }
 553         { cc<= [ JBE ] }
 554         { cc> [ JA ] }
 555         { cc>= [ JAE ] }
 556         { cc= [ JE ] }
 557         { cc/= [ JNE ] }
 558     } case ;
 559
 560 : stack@ ( n -- op ) stack-reg swap [+] ;
 561
 562 : param@ ( n -- op ) reserved-area-size + stack@ ;
 563
 564 : spill-integer-base ( stack-frame -- n )
 565     [ params>> ] [ return>> ] bi + reserved-area-size + ;
 566
 567 : spill-integer@ ( n -- op )
 568     cells
 569     stack-frame get spill-integer-base
 570     + stack@ ;
 571
 572 : spill-float-base ( stack-frame -- n )
 573     [ spill-integer-base ]
 574     [ spill-counts>> int-regs swap at int-regs reg-size * ]
 575     bi + ;
 576
 577 : spill-float@ ( n -- op )
 578     double-float-regs reg-size *
 579     stack-frame get spill-float-base
 580     + stack@ ;
 581
 582 M: x86 %spill-integer ( src n -- ) spill-integer@ swap MOV ;
 583 M: x86 %reload-integer ( dst n -- ) spill-integer@ MOV ;
 584
 585 M: x86 %spill-float ( src n -- ) spill-float@ swap MOVSD ;
 586 M: x86 %reload-float ( dst n -- ) spill-float@ MOVSD ;
 587
 588 M: x86 %loop-entry 16 code-alignment [ NOP ] times ;
 589
 590 M: int-regs %save-param-reg drop [ param@ ] dip MOV ;
 591 M: int-regs %load-param-reg drop swap param@ MOV ;
 592
 593 GENERIC: MOVSS/D ( dst src reg-class -- )
 594
 595 M: single-float-regs MOVSS/D drop MOVSS ;
 596 M: double-float-regs MOVSS/D drop MOVSD ;
 597
 598 M: float-regs %save-param-reg [ param@ ] 2dip MOVSS/D ;
 599 M: float-regs %load-param-reg [ swap param@ ] dip MOVSS/D ;
 600
 601 GENERIC: push-return-reg ( reg-class -- )
 602 GENERIC: load-return-reg ( n reg-class -- )
 603 GENERIC: store-return-reg ( n reg-class -- )
 604
 605 M: x86 %prepare-alien-invoke
 606     #! Save Factor stack pointers in case the C code calls a
 607     #! callback which does a GC, which must reliably trace
 608     #! all roots.
 609     temp-reg-1 "stack_chain" f %alien-global
 610     temp-reg-1 temp-reg-1 [] MOV
 611     temp-reg-1 [] stack-reg MOV
 612     temp-reg-1 [] cell SUB
 613     temp-reg-1 2 cells [+] ds-reg MOV
 614     temp-reg-1 3 cells [+] rs-reg MOV ;
 615
 616 M: x86 value-struct? drop t ;
 617
 618 M: x86 small-enough? ( n -- ? )
 619     HEX: -80000000 HEX: 7fffffff between? ;
 620
 621 : next-stack@ ( n -- operand )
 622     #! nth parameter from the next stack frame. Used to box
 623     #! input values to callbacks; the callback has its own
 624     #! stack frame set up, and we want to read the frame
 625     #! set up by the caller.
 626     stack-frame get total-size>> + stack@ ;