basis/cpu/x86/x86.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs alien alien.c-types arrays strings
   4 cpu.x86.assembler cpu.x86.assembler.private cpu.architecture
   5 kernel kernel.private math memory namespaces make sequences
   6 words system layouts combinators math.order fry locals
   7 compiler.constants compiler.cfg.registers
   8 compiler.cfg.instructions compiler.cfg.intrinsics
   9 compiler.codegen compiler.codegen.fixup ;
  10 IN: cpu.x86
  11
  12 << enable-fixnum-log2 >>
  13
  14 M: x86 two-operand? t ;
  15
  16 HOOK: temp-reg-1 cpu ( -- reg )
  17 HOOK: temp-reg-2 cpu ( -- reg )
  18
  19 HOOK: param-reg-1 cpu ( -- reg )
  20 HOOK: param-reg-2 cpu ( -- reg )
  21
  22 M: x86 %load-immediate MOV ;
  23
  24 M: x86 %load-reference swap 0 MOV rc-absolute-cell rel-immediate ;
  25
  26 HOOK: ds-reg cpu ( -- reg )
  27 HOOK: rs-reg cpu ( -- reg )
  28
  29 : reg-stack ( n reg -- op ) swap cells neg [+] ;
  30
  31 GENERIC: loc>operand ( loc -- operand )
  32
  33 M: ds-loc loc>operand n>> ds-reg reg-stack ;
  34 M: rs-loc loc>operand n>> rs-reg reg-stack ;
  35
  36 M: x86 %peek loc>operand MOV ;
  37 M: x86 %replace loc>operand swap MOV ;
  38 : (%inc) ( n reg -- ) swap cells dup 0 > [ ADD ] [ neg SUB ] if ; inline
  39 M: x86 %inc-d ( n -- ) ds-reg (%inc) ;
  40 M: x86 %inc-r ( n -- ) rs-reg (%inc) ;
  41
  42 : align-stack ( n -- n' )
  43     os macosx? cpu x86.64? or [ 16 align ] when ;
  44
  45 HOOK: reserved-area-size cpu ( -- n )
  46
  47 M: x86 stack-frame-size ( stack-frame -- i )
  48     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
  49     [ params>> ]
  50     [ return>> ]
  51     tri + +
  52     3 cells +
  53     reserved-area-size +
  54     align-stack ;
  55
  56 M: x86 %call ( label -- ) CALL ;
  57 M: x86 %jump-label ( label -- ) JMP ;
  58 M: x86 %return ( -- ) 0 RET ;
  59
  60 : code-alignment ( align -- n )
  61     [ building get [ integer? ] count dup ] dip align swap - ;
  62
  63 : align-code ( n -- )
  64     0 <repetition> % ;
  65
  66 M: x86 %dispatch-label ( word -- )
  67     0 cell, rc-absolute-cell rel-word ;
  68
  69 :: (%slot) ( obj slot tag temp -- op )
  70     temp slot obj [+] LEA
  71     temp tag neg [+] ; inline
  72
  73 :: (%slot-imm) ( obj slot tag -- op )
  74     obj slot cells tag - [+] ; inline
  75
  76 M: x86 %slot ( dst obj slot tag temp -- ) (%slot) MOV ;
  77 M: x86 %slot-imm ( dst obj slot tag -- ) (%slot-imm) MOV ;
  78 M: x86 %set-slot ( src obj slot tag temp -- ) (%slot) swap MOV ;
  79 M: x86 %set-slot-imm ( src obj slot tag -- ) (%slot-imm) swap MOV ;
  80
  81 M: x86 %add     [+] LEA ;
  82 M: x86 %add-imm [+] LEA ;
  83 M: x86 %sub     nip SUB ;
  84 M: x86 %sub-imm neg [+] LEA ;
  85 M: x86 %mul     nip swap IMUL2 ;
  86 M: x86 %mul-imm nip IMUL2 ;
  87 M: x86 %and     nip AND ;
  88 M: x86 %and-imm nip AND ;
  89 M: x86 %or      nip OR ;
  90 M: x86 %or-imm  nip OR ;
  91 M: x86 %xor     nip XOR ;
  92 M: x86 %xor-imm nip XOR ;
  93 M: x86 %shl-imm nip SHL ;
  94 M: x86 %shr-imm nip SHR ;
  95 M: x86 %sar-imm nip SAR ;
  96 M: x86 %not     drop NOT ;
  97 M: x86 %log2    BSR ;
  98
  99 : ?MOV ( dst src -- )
 100     2dup = [ 2drop ] [ MOV ] if ; inline
 101
 102 :: move>args ( src1 src2 -- )
 103     {
 104         { [ src1 param-reg-2 = ] [ param-reg-1 src2 ?MOV param-reg-1 param-reg-2 XCHG ] }
 105         { [ src1 param-reg-1 = ] [ param-reg-2 src2 ?MOV ] }
 106         { [ src2 param-reg-1 = ] [ param-reg-2 src1 ?MOV param-reg-1 param-reg-2 XCHG ] }
 107         { [ src2 param-reg-2 = ] [ param-reg-1 src1 ?MOV ] }
 108         [
 109             param-reg-1 src1 MOV
 110             param-reg-2 src2 MOV
 111         ]
 112     } cond ;
 113
 114 HOOK: %alien-invoke-tail cpu ( func dll -- )
 115
 116 :: overflow-template ( src1 src2 insn inverse func -- )
 117     <label> "no-overflow" set
 118     src1 src2 insn call
 119     ds-reg [] src1 MOV
 120     "no-overflow" get JNO
 121     src1 src2 inverse call
 122     src1 src2 move>args
 123     %prepare-alien-invoke
 124     func f %alien-invoke
 125     "no-overflow" resolve-label ; inline
 126
 127 :: overflow-template-tail ( src1 src2 insn inverse func -- )
 128     <label> "no-overflow" set
 129     src1 src2 insn call
 130     "no-overflow" get JNO
 131     src1 src2 inverse call
 132     src1 src2 move>args
 133     %prepare-alien-invoke
 134     func f %alien-invoke-tail
 135     "no-overflow" resolve-label
 136     ds-reg [] src1 MOV
 137     0 RET ; inline
 138
 139 M: x86 %fixnum-add ( src1 src2 -- )
 140     [ ADD ] [ SUB ] "overflow_fixnum_add" overflow-template ;
 141
 142 M: x86 %fixnum-add-tail ( src1 src2 -- )
 143     [ ADD ] [ SUB ] "overflow_fixnum_add" overflow-template-tail ;
 144
 145 M: x86 %fixnum-sub ( src1 src2 -- )
 146     [ SUB ] [ ADD ] "overflow_fixnum_subtract" overflow-template ;
 147
 148 M: x86 %fixnum-sub-tail ( src1 src2 -- )
 149     [ SUB ] [ ADD ] "overflow_fixnum_subtract" overflow-template-tail ;
 150
 151 M:: x86 %fixnum-mul ( src1 src2 temp1 temp2 -- )
 152     "no-overflow" define-label
 153     temp1 src1 MOV
 154     temp1 tag-bits get SAR
 155     src2 temp1 IMUL2
 156     ds-reg [] temp1 MOV
 157     "no-overflow" get JNO
 158     src1 src2 move>args
 159     param-reg-1 tag-bits get SAR
 160     param-reg-2 tag-bits get SAR
 161     %prepare-alien-invoke
 162     "overflow_fixnum_multiply" f %alien-invoke
 163     "no-overflow" resolve-label ;
 164
 165 M:: x86 %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 166     "overflow" define-label
 167     temp1 src1 MOV
 168     temp1 tag-bits get SAR
 169     src2 temp1 IMUL2
 170     "overflow" get JO
 171     ds-reg [] temp1 MOV
 172     0 RET
 173     "overflow" resolve-label
 174     src1 src2 move>args
 175     param-reg-1 tag-bits get SAR
 176     param-reg-2 tag-bits get SAR
 177     %prepare-alien-invoke
 178     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 179
 180 : bignum@ ( reg n -- op )
 181     cells bignum tag-number - [+] ; inline
 182
 183 M:: x86 %integer>bignum ( dst src temp -- )
 184     #! on entry, inreg is a signed 32-bit quantity
 185     #! exits with tagged ptr to bignum in outreg
 186     #! 1 cell header, 1 cell length, 1 cell sign, + digits
 187     #! length is the # of digits + sign
 188     [
 189         "end" define-label
 190         ! Load cached zero value
 191         dst 0 >bignum %load-reference
 192         src 0 CMP
 193         ! Is it zero? Then just go to the end and return this zero
 194         "end" get JE
 195         ! Allocate a bignum
 196         dst 4 cells bignum temp %allot
 197         ! Write length
 198         dst 1 bignum@ 2 tag-fixnum MOV
 199         ! Store value
 200         dst 3 bignum@ src MOV
 201         ! Compute sign
 202         temp src MOV
 203         temp cell-bits 1- SAR
 204         temp 1 AND
 205         ! Store sign
 206         dst 2 bignum@ temp MOV
 207         ! Make negative value positive
 208         temp temp ADD
 209         temp NEG
 210         temp 1 ADD
 211         src temp IMUL2
 212         ! Store the bignum
 213         dst 3 bignum@ temp MOV
 214         "end" resolve-label
 215     ] with-scope ;
 216
 217 M:: x86 %bignum>integer ( dst src temp -- )
 218     [
 219         "end" define-label
 220         ! load length
 221         temp src 1 bignum@ MOV
 222         ! if the length is 1, its just the sign and nothing else,
 223         ! so output 0
 224         dst 0 MOV
 225         temp 1 tag-fixnum CMP
 226         "end" get JE
 227         ! load the value
 228         dst src 3 bignum@ MOV
 229         ! load the sign
 230         temp src 2 bignum@ MOV
 231         ! convert it into -1 or 1
 232         temp temp ADD
 233         temp NEG
 234         temp 1 ADD
 235         ! make dst signed
 236         temp dst IMUL2
 237         "end" resolve-label
 238     ] with-scope ;
 239
 240 M: x86 %add-float nip ADDSD ;
 241 M: x86 %sub-float nip SUBSD ;
 242 M: x86 %mul-float nip MULSD ;
 243 M: x86 %div-float nip DIVSD ;
 244
 245 M: x86 %integer>float CVTSI2SD ;
 246 M: x86 %float>integer CVTTSD2SI ;
 247
 248 M: x86 %copy ( dst src -- ) ?MOV ;
 249
 250 M: x86 %copy-float ( dst src -- )
 251     2dup = [ 2drop ] [ MOVSD ] if ;
 252
 253 M: x86 %unbox-float ( dst src -- )
 254     float-offset [+] MOVSD ;
 255
 256 M:: x86 %unbox-any-c-ptr ( dst src temp -- )
 257     [
 258         { "is-byte-array" "end" "start" } [ define-label ] each
 259         dst 0 MOV
 260         temp src MOV
 261         ! We come back here with displaced aliens
 262         "start" resolve-label
 263         ! Is the object f?
 264         temp \ f tag-number CMP
 265         "end" get JE
 266         ! Is the object an alien?
 267         temp header-offset [+] alien type-number tag-fixnum CMP
 268         "is-byte-array" get JNE
 269         ! If so, load the offset and add it to the address
 270         dst temp alien-offset [+] ADD
 271         ! Now recurse on the underlying alien
 272         temp temp underlying-alien-offset [+] MOV
 273         "start" get JMP
 274         "is-byte-array" resolve-label
 275         ! Add byte array address to address being computed
 276         dst temp ADD
 277         ! Add an offset to start of byte array's data
 278         dst byte-array-offset ADD
 279         "end" resolve-label
 280     ] with-scope ;
 281
 282 M:: x86 %box-float ( dst src temp -- )
 283     dst 16 float temp %allot
 284     dst float-offset [+] src MOVSD ;
 285
 286 : alien@ ( reg n -- op ) cells alien tag-number - [+] ;
 287
 288 M:: x86 %box-alien ( dst src temp -- )
 289     [
 290         "end" define-label
 291         dst \ f tag-number MOV
 292         src 0 CMP
 293         "end" get JE
 294         dst 4 cells alien temp %allot
 295         dst 1 alien@ \ f tag-number MOV
 296         dst 2 alien@ \ f tag-number MOV
 297         ! Store src in alien-offset slot
 298         dst 3 alien@ src MOV
 299         "end" resolve-label
 300     ] with-scope ;
 301
 302 : small-reg-4 ( reg -- reg' )
 303     H{
 304         { EAX EAX }
 305         { ECX ECX }
 306         { EDX EDX }
 307         { EBX EBX }
 308         { ESP ESP }
 309         { EBP EBP }
 310         { ESI ESP }
 311         { EDI EDI }
 312
 313         { RAX EAX }
 314         { RCX ECX }
 315         { RDX EDX }
 316         { RBX EBX }
 317         { RSP ESP }
 318         { RBP EBP }
 319         { RSI ESP }
 320         { RDI EDI }
 321     } at ; inline
 322
 323 : small-reg-2 ( reg -- reg' )
 324     small-reg-4 H{
 325         { EAX AX }
 326         { ECX CX }
 327         { EDX DX }
 328         { EBX BX }
 329         { ESP SP }
 330         { EBP BP }
 331         { ESI SI }
 332         { EDI DI }
 333     } at ; inline
 334
 335 : small-reg-1 ( reg -- reg' )
 336     small-reg-4 {
 337         { EAX AL }
 338         { ECX CL }
 339         { EDX DL }
 340         { EBX BL }
 341     } at ; inline
 342
 343 : small-reg ( reg size -- reg' )
 344     {
 345         { 1 [ small-reg-1 ] }
 346         { 2 [ small-reg-2 ] }
 347         { 4 [ small-reg-4 ] }
 348     } case ;
 349
 350 : small-regs ( -- regs ) { EAX ECX EDX EBX } ; inline
 351
 352 : small-reg-that-isn't ( exclude -- reg' )
 353     small-regs swap [ small-reg-4 ] map '[ _ memq? not ] find nip ;
 354
 355 : with-save/restore ( reg quot -- )
 356     [ drop PUSH ] [ call ] [ drop POP ] 2tri ; inline
 357
 358 :: with-small-register ( dst exclude quot: ( new-dst -- ) -- )
 359     #! If the destination register overlaps a small register, we
 360     #! call the quot with that. Otherwise, we find a small
 361     #! register that is not in exclude, and call quot, saving
 362     #! and restoring the small register.
 363     dst small-reg-4 small-regs memq? [ dst quot call ] [
 364         exclude small-reg-that-isn't
 365         [ quot call ] with-save/restore
 366     ] if ; inline
 367
 368 M:: x86 %string-nth ( dst src index temp -- )
 369     "end" define-label
 370     dst { src index temp } [| new-dst |
 371         ! Load the least significant 7 bits into new-dst.
 372         ! 8th bit indicates whether we have to load from
 373         ! the aux vector or not.
 374         temp src index [+] LEA
 375         new-dst 1 small-reg temp string-offset [+] MOV
 376         new-dst new-dst 1 small-reg MOVZX
 377         ! Do we have to look at the aux vector?
 378         new-dst HEX: 80 CMP
 379         "end" get JL
 380         ! Yes, this is a non-ASCII character. Load aux vector
 381         temp src string-aux-offset [+] MOV
 382         new-dst temp XCHG
 383         ! Compute index
 384         new-dst index ADD
 385         new-dst index ADD
 386         ! Load high 16 bits
 387         new-dst 2 small-reg new-dst byte-array-offset [+] MOV
 388         new-dst new-dst 2 small-reg MOVZX
 389         new-dst 7 SHL
 390         ! Compute code point
 391         new-dst temp XOR
 392         "end" resolve-label
 393         dst new-dst ?MOV
 394     ] with-small-register ;
 395
 396 M:: x86 %set-string-nth-fast ( ch str index temp -- )
 397     ch { index str temp } [| new-ch |
 398         new-ch ch ?MOV
 399         temp str index [+] LEA
 400         temp string-offset [+] new-ch 1 small-reg MOV
 401     ] with-small-register ;
 402
 403 :: %alien-integer-getter ( dst src size quot -- )
 404     dst { src } [| new-dst |
 405         new-dst dup size small-reg dup src [] MOV
 406         quot call
 407         dst new-dst ?MOV
 408     ] with-small-register ; inline
 409
 410 : %alien-unsigned-getter ( dst src size -- )
 411     [ MOVZX ] %alien-integer-getter ; inline
 412
 413 M: x86 %alien-unsigned-1 1 %alien-unsigned-getter ;
 414 M: x86 %alien-unsigned-2 2 %alien-unsigned-getter ;
 415
 416 : %alien-signed-getter ( dst src size -- )
 417     [ MOVSX ] %alien-integer-getter ; inline
 418
 419 M: x86 %alien-signed-1 1 %alien-signed-getter ;
 420 M: x86 %alien-signed-2 2 %alien-signed-getter ;
 421 M: x86 %alien-signed-4 4 %alien-signed-getter ;
 422
 423 M: x86 %alien-unsigned-4 4 [ 2drop ] %alien-integer-getter ;
 424
 425 M: x86 %alien-cell [] MOV ;
 426 M: x86 %alien-float dupd [] MOVSS dup CVTSS2SD ;
 427 M: x86 %alien-double [] MOVSD ;
 428
 429 :: %alien-integer-setter ( ptr value size -- )
 430     value { ptr } [| new-value |
 431         new-value value ?MOV
 432         ptr [] new-value size small-reg MOV
 433     ] with-small-register ; inline
 434
 435 M: x86 %set-alien-integer-1 1 %alien-integer-setter ;
 436 M: x86 %set-alien-integer-2 2 %alien-integer-setter ;
 437 M: x86 %set-alien-integer-4 4 %alien-integer-setter ;
 438 M: x86 %set-alien-cell [ [] ] dip MOV ;
 439 M: x86 %set-alien-float dup dup CVTSD2SS [ [] ] dip MOVSS ;
 440 M: x86 %set-alien-double [ [] ] dip MOVSD ;
 441
 442 : load-zone-ptr ( reg -- )
 443     #! Load pointer to start of zone array
 444     0 MOV "nursery" f rc-absolute-cell rel-dlsym ;
 445
 446 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 447     [ drop load-zone-ptr ] [ swap cell [+] MOV ] 2bi ;
 448
 449 : inc-allot-ptr ( nursery-ptr n -- )
 450     [ cell [+] ] dip 8 align ADD ;
 451
 452 : store-header ( temp class -- )
 453     [ [] ] [ type-number tag-fixnum ] bi* MOV ;
 454
 455 : store-tagged ( dst tag -- )
 456     tag-number OR ;
 457
 458 M:: x86 %allot ( dst size class nursery-ptr -- )
 459     nursery-ptr dst load-allot-ptr
 460     dst class store-header
 461     dst class store-tagged
 462     nursery-ptr size inc-allot-ptr ;
 463
 464 M:: x86 %write-barrier ( src card# table -- )
 465     #! Mark the card pointed to by vreg.
 466     ! Mark the card
 467     card# src MOV
 468     card# card-bits SHR
 469     table "cards_offset" f %alien-global
 470     table table [] MOV
 471     table card# [+] card-mark <byte> MOV
 472
 473     ! Mark the card deck
 474     card# deck-bits card-bits - SHR
 475     table "decks_offset" f %alien-global
 476     table table [] MOV
 477     table card# [+] card-mark <byte> MOV ;
 478
 479 M: x86 %gc ( -- )
 480     "end" define-label
 481     temp-reg-1 load-zone-ptr
 482     temp-reg-2 temp-reg-1 cell [+] MOV
 483     temp-reg-2 1024 ADD
 484     temp-reg-1 temp-reg-1 3 cells [+] MOV
 485     temp-reg-2 temp-reg-1 CMP
 486     "end" get JLE
 487     %prepare-alien-invoke
 488     "minor_gc" f %alien-invoke
 489     "end" resolve-label ;
 490
 491 M: x86 %alien-global
 492     [ 0 MOV ] 2dip rc-absolute-cell rel-dlsym ;
 493
 494 HOOK: stack-reg cpu ( -- reg )
 495
 496 : decr-stack-reg ( n -- )
 497     dup 0 = [ drop ] [ stack-reg swap SUB ] if ;
 498
 499 : incr-stack-reg ( n -- )
 500     dup 0 = [ drop ] [ stack-reg swap ADD ] if ;
 501
 502 M: x86 %epilogue ( n -- ) cell - incr-stack-reg ;
 503
 504 :: %boolean ( dst temp word -- )
 505     dst \ f tag-number MOV
 506     temp 0 MOV \ t rc-absolute-cell rel-immediate
 507     dst temp word execute ; inline
 508
 509 M: x86 %compare ( dst temp cc src1 src2 -- )
 510     CMP {
 511         { cc< [ \ CMOVL %boolean ] }
 512         { cc<= [ \ CMOVLE %boolean ] }
 513         { cc> [ \ CMOVG %boolean ] }
 514         { cc>= [ \ CMOVGE %boolean ] }
 515         { cc= [ \ CMOVE %boolean ] }
 516         { cc/= [ \ CMOVNE %boolean ] }
 517     } case ;
 518
 519 M: x86 %compare-imm ( dst temp cc src1 src2 -- )
 520     %compare ;
 521
 522 M: x86 %compare-float ( dst temp cc src1 src2 -- )
 523     UCOMISD {
 524         { cc< [ \ CMOVB %boolean ] }
 525         { cc<= [ \ CMOVBE %boolean ] }
 526         { cc> [ \ CMOVA %boolean ] }
 527         { cc>= [ \ CMOVAE %boolean ] }
 528         { cc= [ \ CMOVE %boolean ] }
 529         { cc/= [ \ CMOVNE %boolean ] }
 530     } case ;
 531
 532 M: x86 %compare-branch ( label cc src1 src2 -- )
 533     CMP {
 534         { cc< [ JL ] }
 535         { cc<= [ JLE ] }
 536         { cc> [ JG ] }
 537         { cc>= [ JGE ] }
 538         { cc= [ JE ] }
 539         { cc/= [ JNE ] }
 540     } case ;
 541
 542 M: x86 %compare-imm-branch ( label src1 src2 cc -- )
 543     %compare-branch ;
 544
 545 M: x86 %compare-float-branch ( label cc src1 src2 -- )
 546     UCOMISD {
 547         { cc< [ JB ] }
 548         { cc<= [ JBE ] }
 549         { cc> [ JA ] }
 550         { cc>= [ JAE ] }
 551         { cc= [ JE ] }
 552         { cc/= [ JNE ] }
 553     } case ;
 554
 555 : stack@ ( n -- op ) stack-reg swap [+] ;
 556
 557 : param@ ( n -- op ) reserved-area-size + stack@ ;
 558
 559 : spill-integer-base ( stack-frame -- n )
 560     [ params>> ] [ return>> ] bi + reserved-area-size + ;
 561
 562 : spill-integer@ ( n -- op )
 563     cells
 564     stack-frame get spill-integer-base
 565     + stack@ ;
 566
 567 : spill-float-base ( stack-frame -- n )
 568     [ spill-integer-base ]
 569     [ spill-counts>> int-regs swap at int-regs reg-size * ]
 570     bi + ;
 571
 572 : spill-float@ ( n -- op )
 573     double-float-regs reg-size *
 574     stack-frame get spill-float-base
 575     + stack@ ;
 576
 577 M: x86 %spill-integer ( src n -- ) spill-integer@ swap MOV ;
 578 M: x86 %reload-integer ( dst n -- ) spill-integer@ MOV ;
 579
 580 M: x86 %spill-float ( src n -- ) spill-float@ swap MOVSD ;
 581 M: x86 %reload-float ( dst n -- ) spill-float@ MOVSD ;
 582
 583 M: x86 %loop-entry 16 code-alignment [ NOP ] times ;
 584
 585 M: int-regs %save-param-reg drop [ param@ ] dip MOV ;
 586 M: int-regs %load-param-reg drop swap param@ MOV ;
 587
 588 GENERIC: MOVSS/D ( dst src reg-class -- )
 589
 590 M: single-float-regs MOVSS/D drop MOVSS ;
 591 M: double-float-regs MOVSS/D drop MOVSD ;
 592
 593 M: float-regs %save-param-reg [ param@ ] 2dip MOVSS/D ;
 594 M: float-regs %load-param-reg [ swap param@ ] dip MOVSS/D ;
 595
 596 GENERIC: push-return-reg ( reg-class -- )
 597 GENERIC: load-return-reg ( n reg-class -- )
 598 GENERIC: store-return-reg ( n reg-class -- )
 599
 600 M: x86 %prepare-alien-invoke
 601     #! Save Factor stack pointers in case the C code calls a
 602     #! callback which does a GC, which must reliably trace
 603     #! all roots.
 604     temp-reg-1 "stack_chain" f %alien-global
 605     temp-reg-1 temp-reg-1 [] MOV
 606     temp-reg-1 [] stack-reg MOV
 607     temp-reg-1 [] cell SUB
 608     temp-reg-1 2 cells [+] ds-reg MOV
 609     temp-reg-1 3 cells [+] rs-reg MOV ;
 610
 611 M: x86 value-struct? drop t ;
 612
 613 M: x86 small-enough? ( n -- ? )
 614     HEX: -80000000 HEX: 7fffffff between? ;
 615
 616 : next-stack@ ( n -- operand )
 617     #! nth parameter from the next stack frame. Used to box
 618     #! input values to callbacks; the callback has its own
 619     #! stack frame set up, and we want to read the frame
 620     #! set up by the caller.
 621     stack-frame get total-size>> + stack@ ;