basis/csv/csv.factor

   1 ! Copyright (C) 2007, 2008 Phil Dawes, 2013 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators fry io io.files io.streams.string kernel
   4 make math memoize namespaces sbufs sequences sequences.private
   5 unicode.categories ;
   6 IN: csv
   7
   8 SYMBOL: delimiter
   9
  10 CHAR: , delimiter set-global
  11
  12 <PRIVATE
  13
  14 MEMO: field-delimiters ( delimiter -- field-seps quote-seps )
  15     [ "\n" swap prefix ] [ "\"\n" swap prefix ] bi ; inline
  16
  17 DEFER: quoted-field,
  18
  19 : maybe-escaped-quote ( delimeter stream quoted? -- delimiter stream sep/f )
  20     2over stream-read1 swap over =
  21     [ nip ] [
  22         {
  23             { CHAR: "    [ [ CHAR: " , ] when quoted-field, ] }
  24             { CHAR: \n   [ ] } ! Error: newline inside string?
  25             [ [ , drop f maybe-escaped-quote ] when* ]
  26         } case
  27      ] if ; inline recursive
  28
  29 : quoted-field, ( delimiter stream -- delimiter stream sep/f )
  30     "\"" over stream-read-until drop % t maybe-escaped-quote ;
  31
  32 : quoted-field ( delimiter stream -- sep/f field )
  33     [ quoted-field, 2nip ] "" make ;
  34
  35 : ?trim ( string -- string' )
  36     dup length [ drop "" ] [
  37         over first-unsafe blank?
  38         [ drop t ] [ 1 - over nth-unsafe blank? ] if
  39         [ [ blank? ] trim ] when
  40     ] if-zero ; inline
  41
  42 : continue-field ( delimiter stream field-seps seq -- sep/f field )
  43     swap rot stream-read-until [ "\"" glue ] dip
  44     swap ?trim [ drop ] 2dip ; inline
  45
  46 : field ( delimiter stream field-seps quote-seps -- sep/f field )
  47     pick stream-read-until dup CHAR: " = [
  48         drop [ drop quoted-field ] [ continue-field ] if-empty
  49     ] [ [ 3drop ] 2dip swap ?trim ] if ;
  50
  51 : (stream-read-row) ( delimiter stream field-end quoted-field -- sep/f fields )
  52     [ [ dup '[ dup _ = ] ] keep ] 3dip
  53     '[ drop _ _ _ _ field ] produce ; inline
  54
  55 : (stream-read-csv) ( stream -- )
  56     [ dup [ empty? ] all? [ drop ] [ , ] if ]
  57     delimiter get rot over field-delimiters
  58     '[ _ _ _ _ (stream-read-row) ] do while ;
  59
  60 PRIVATE>
  61
  62 : stream-read-row ( stream -- row )
  63     delimiter get swap over field-delimiters
  64     (stream-read-row) nip ; inline
  65
  66 : read-row ( -- row )
  67     input-stream get stream-read-row ; inline
  68
  69 : stream-read-csv ( stream -- rows )
  70     [ (stream-read-csv) ] { } make
  71     dup last { "" } = [ but-last ] when ; inline
  72
  73 : read-csv ( -- rows )
  74     input-stream get stream-read-csv ; inline
  75
  76 : string>csv ( string -- csv )
  77     [ read-csv ] with-string-reader ;
  78
  79 : file>csv ( path encoding -- csv )
  80     [ read-csv ] with-file-reader ;
  81
  82 : with-delimiter ( ch quot -- )
  83     [ delimiter ] dip with-variable ; inline
  84
  85 <PRIVATE
  86
  87 : needs-escaping? ( cell delimiter -- ? )
  88     '[ dup "\n\"" member? [ drop t ] [ _ = ] if ] any? ; inline
  89
  90 : escape-quotes ( cell stream -- )
  91     CHAR: " over stream-write1 swap [
  92         [ over stream-write1 ]
  93         [ dup CHAR: " = [ over stream-write1 ] [ drop ] if ] bi
  94     ] each CHAR: " swap stream-write1 ;
  95
  96 : escape-if-required ( cell delimiter stream -- )
  97     [ dupd needs-escaping? ] dip
  98     [ escape-quotes ] [ stream-write ] bi-curry if ; inline
  99
 100 : (stream-write-row) ( row delimiter stream -- )
 101     [ '[ _ _ stream-write1 ] ] 2keep
 102     '[ _ _ escape-if-required ] interleave nl ; inline
 103
 104 PRIVATE>
 105
 106 : stream-write-row ( row stream -- )
 107     delimiter get swap (stream-write-row) ; inline
 108
 109 : write-row ( row -- )
 110     output-stream get stream-write-row ; inline
 111
 112 : stream-write-csv ( rows stream -- )
 113     delimiter get swap '[ _ _ (stream-write-row) ] each ;
 114
 115 : write-csv ( rows -- )
 116     output-stream get stream-write-csv ;
 117
 118 : csv>string ( csv -- string )
 119     [ write-csv ] with-string-writer ;
 120
 121 : csv>file ( rows path encoding -- )
 122     [ write-csv ] with-file-writer ;