basis/db/db.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs classes continuations destructors kernel math
   4 namespaces sequences classes.tuple words strings
   5 tools.walker accessors combinators fry ;
   6 IN: db
   7
   8 TUPLE: db
   9     handle
  10     insert-statements
  11     update-statements
  12     delete-statements ;
  13
  14 : new-db ( class -- obj )
  15     new
  16         H{ } clone >>insert-statements
  17         H{ } clone >>update-statements
  18         H{ } clone >>delete-statements ; inline
  19
  20 GENERIC: db-open ( db -- db )
  21 HOOK: db-close db ( handle -- )
  22
  23 : dispose-statements ( assoc -- ) values dispose-each ;
  24
  25 : db-dispose ( db -- )
  26     dup db [
  27         {
  28             [ insert-statements>> dispose-statements ]
  29             [ update-statements>> dispose-statements ]
  30             [ delete-statements>> dispose-statements ]
  31             [ handle>> db-close ]
  32         } cleave
  33     ] with-variable ;
  34
  35 TUPLE: result-set sql in-params out-params handle n max ;
  36
  37 GENERIC: query-results ( query -- result-set )
  38 GENERIC: #rows ( result-set -- n )
  39 GENERIC: #columns ( result-set -- n )
  40 GENERIC# row-column 1 ( result-set column -- obj )
  41 GENERIC# row-column-typed 1 ( result-set column -- sql )
  42 GENERIC: advance-row ( result-set -- )
  43 GENERIC: more-rows? ( result-set -- ? )
  44
  45 : init-result-set ( result-set -- )
  46     dup #rows >>max
  47     0 >>n drop ;
  48
  49 : new-result-set ( query handle class -- result-set )
  50     new
  51         swap >>handle
  52         >r [ sql>> ] [ in-params>> ] [ out-params>> ] tri r>
  53         swap >>out-params
  54         swap >>in-params
  55         swap >>sql ;
  56
  57 TUPLE: statement handle sql in-params out-params bind-params bound? type retries ;
  58 TUPLE: simple-statement < statement ;
  59 TUPLE: prepared-statement < statement ;
  60
  61 : new-statement ( sql in out class -- statement )
  62     new
  63         swap >>out-params
  64         swap >>in-params
  65         swap >>sql ;
  66
  67 HOOK: <simple-statement> db ( string in out -- statement )
  68 HOOK: <prepared-statement> db ( string in out -- statement )
  69 GENERIC: prepare-statement ( statement -- )
  70 GENERIC: bind-statement* ( statement -- )
  71 GENERIC: low-level-bind ( statement -- )
  72 GENERIC: bind-tuple ( tuple statement -- )
  73
  74 GENERIC: execute-statement* ( statement type -- )
  75
  76 M: object execute-statement* ( statement type -- )
  77     drop query-results dispose ;
  78
  79 : execute-one-statement ( statement -- )
  80     dup type>> execute-statement* ;
  81
  82 : execute-statement ( statement -- )
  83     dup sequence? [
  84         [ execute-one-statement ] each
  85     ] [
  86         execute-one-statement
  87     ] if ;
  88
  89 : bind-statement ( obj statement -- )
  90     swap >>bind-params
  91     [ bind-statement* ] keep
  92     t >>bound? drop ;
  93
  94 : sql-row ( result-set -- seq )
  95     dup #columns [ row-column ] with map ;
  96
  97 : sql-row-typed ( result-set -- seq )
  98     dup #columns [ row-column-typed ] with map ;
  99
 100 : query-each ( statement quot: ( statement -- ) -- )
 101     over more-rows? [
 102         [ call ] 2keep over advance-row query-each
 103     ] [
 104         2drop
 105     ] if ; inline recursive
 106
 107 : query-map ( statement quot -- seq )
 108     accumulator [ query-each ] dip { } like ; inline
 109
 110 : with-db ( db quot -- )
 111     [ db-open db ] dip
 112     '[ db get [ drop @ ] with-disposal ] with-variable ; inline
 113
 114 : default-query ( query -- result-set )
 115     query-results [ [ sql-row ] query-map ] with-disposal ;
 116
 117 : sql-query ( sql -- rows )
 118     f f <simple-statement> [ default-query ] with-disposal ;
 119
 120 : sql-command ( sql -- )
 121     dup string? [
 122         f f <simple-statement> [ execute-statement ] with-disposal
 123     ] [
 124         ! [
 125             [ sql-command ] each
 126         ! ] with-transaction
 127     ] if ;
 128
 129 SYMBOL: in-transaction
 130 HOOK: begin-transaction db ( -- )
 131 HOOK: commit-transaction db ( -- )
 132 HOOK: rollback-transaction db ( -- )
 133
 134 M: db begin-transaction ( -- ) "BEGIN" sql-command ;
 135 M: db commit-transaction ( -- ) "COMMIT" sql-command ;
 136 M: db rollback-transaction ( -- ) "ROLLBACK" sql-command ;
 137
 138 : in-transaction? ( -- ? ) in-transaction get ;
 139
 140 : with-transaction ( quot -- )
 141     t in-transaction [
 142         begin-transaction
 143         [ ] [ rollback-transaction ] cleanup commit-transaction
 144     ] with-variable ;