basis/db/queries/queries.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math namespaces make sequences random
   4 strings math.parser math.intervals combinators math.bitwise
   5 nmake db db.tuples db.types classes words shuffle arrays
   6 destructors continuations db.tuples.private prettyprint ;
   7 IN: db.queries
   8
   9 GENERIC: where ( specs obj -- )
  10
  11 SINGLETON: retryable
  12 : make-retryable ( obj -- obj' )
  13     dup sequence? [
  14         [ make-retryable ] map
  15     ] [
  16         retryable >>type
  17         10 >>retries
  18     ] if ;
  19
  20 : maybe-make-retryable ( statement -- statement )
  21     dup in-params>> [ generator-bind? ] contains?
  22     [ make-retryable ] when ;
  23
  24 : regenerate-params ( statement -- statement )
  25     dup
  26     [ bind-params>> ] [ in-params>> ] bi
  27     [
  28         dup generator-bind? [
  29             generator-singleton>> eval-generator >>value
  30         ] [
  31             drop
  32         ] if
  33     ] 2map >>bind-params ;
  34
  35 M: retryable execute-statement* ( statement type -- )
  36     drop [ retries>> ] [
  37         [
  38             nip
  39             [ query-results dispose t ]
  40             [ ]
  41             [ regenerate-params bind-statement* f ] cleanup
  42         ] curry
  43     ] bi attempt-all drop ;
  44
  45 : sql-props ( class -- columns table )
  46     [ db-columns ] [ db-table ] bi ;
  47
  48 : query-make ( class quot -- statements )
  49     #! query, input, outputs, secondary queries
  50     over unparse "table" set
  51     [ sql-props ] dip
  52     [ 0 sql-counter rot with-variable ] curry
  53     { "" { } { } { } } nmake
  54     [ <simple-statement> maybe-make-retryable ] dip
  55     [ [ 1array ] dip append ] unless-empty ; inline
  56
  57 : where-primary-key% ( specs -- )
  58     " where " 0%
  59     find-primary-key [
  60         " and " 0%
  61     ] [
  62         dup column-name>> 0% " = " 0% bind%
  63     ] interleave ;
  64
  65 M: db <update-tuple-statement> ( class -- statement )
  66     [
  67         "update " 0% 0%
  68         " set " 0%
  69         dup remove-id
  70         [ ", " 0% ] [ dup column-name>> 0% " = " 0% bind% ] interleave
  71         where-primary-key%
  72     ] query-make ;
  73
  74 M: random-id-generator eval-generator ( singleton -- obj )
  75     drop
  76     system-random-generator get [
  77         63 [ random-bits ] keep 1- set-bit
  78     ] with-random ;
  79
  80 : interval-comparison ( ? str -- str )
  81     "from" = " >" " <" ? swap [ "= " append ] when ;
  82
  83 : (infinite-interval?) ( interval -- ?1 ?2 )
  84     [ from>> ] [ to>> ] bi
  85     [ first fp-infinity? ] bi@ ;
  86
  87 : double-infinite-interval? ( obj -- ? )
  88     dup interval? [ (infinite-interval?) and ] [ drop f ] if ;
  89
  90 : infinite-interval? ( obj -- ? )
  91     dup interval? [ (infinite-interval?) or ] [ drop f ] if ;
  92
  93 : where-interval ( spec obj from/to -- )
  94     over first fp-infinity? [
  95         3drop
  96     ] [
  97         pick column-name>> 0%
  98         [ first2 ] dip interval-comparison 0%
  99         bind#
 100     ] if ;
 101
 102 : in-parens ( quot -- )
 103     "(" 0% call ")" 0% ; inline
 104
 105 M: interval where ( spec obj -- )
 106     [
 107         [ from>> "from" where-interval ] [
 108             nip infinite-interval? [ " and " 0% ] unless
 109         ] [ to>> "to" where-interval ] 2tri
 110     ] in-parens ;
 111
 112 M: sequence where ( spec obj -- )
 113     [
 114         [ " or " 0% ] [ dupd where ] interleave drop
 115     ] in-parens ;
 116
 117 M: NULL where ( spec obj -- )
 118     drop column-name>> 0% " is NULL" 0% ;
 119
 120 : object-where ( spec obj -- )
 121     over column-name>> 0% " = " 0% bind# ;
 122
 123 M: object where ( spec obj -- ) object-where ;
 124
 125 M: integer where ( spec obj -- ) object-where ;
 126
 127 M: string where ( spec obj -- ) object-where ;
 128
 129 : filter-slots ( tuple specs -- specs' )
 130     [
 131         slot-name>> swap get-slot-named
 132         dup double-infinite-interval? [ drop f ] when
 133     ] with filter ;
 134
 135 : many-where ( tuple seq -- )
 136     " where " 0% [
 137         " and " 0%
 138     ] [
 139         2dup slot-name>> swap get-slot-named where
 140     ] interleave drop ;
 141
 142 : where-clause ( tuple specs -- )
 143     dupd filter-slots [ drop ] [ many-where ] if-empty ;
 144
 145 M: db <delete-tuples-statement> ( tuple table -- sql )
 146     [
 147         "delete from " 0% 0%
 148         where-clause
 149     ] query-make ;
 150
 151 ERROR: all-slots-ignored class ;
 152
 153 M: db <select-by-slots-statement> ( tuple class -- statement )
 154     [
 155         "select " 0%
 156         [ dupd filter-ignores ] dip
 157         over empty? [ all-slots-ignored ] when
 158         over
 159         [ ", " 0% ]
 160         [ dup column-name>> 0% 2, ] interleave
 161         " from " 0% 0%
 162         where-clause
 163     ] query-make ;
 164
 165 : do-group ( tuple groups -- )
 166     dup string? [ 1array ] when
 167     [ ", " join " group by " glue ] curry change-sql drop ;
 168
 169 : do-order ( tuple order -- )
 170     dup string? [ 1array ] when
 171     [ ", " join " order by " glue ] curry change-sql drop ;
 172
 173 : do-offset ( tuple n -- )
 174     [ number>string " offset " glue ] curry change-sql drop ;
 175
 176 : do-limit ( tuple n -- )
 177     [ number>string " limit " glue ] curry change-sql drop ;
 178
 179 : make-query* ( tuple query -- tuple' )
 180     dupd
 181     {
 182         [ group>> [ drop ] [ do-group ] if-empty ]
 183         [ order>> [ drop ] [ do-order ] if-empty ]
 184         [ limit>> [ do-limit ] [ drop ] if* ]
 185         [ offset>> [ do-offset ] [ drop ] if* ]
 186     } 2cleave ;
 187
 188 M: db query>statement ( query -- tuple )
 189     [ tuple>> dup class ] keep
 190     [ <select-by-slots-statement> ] dip make-query* ;
 191
 192 ! select ID, NAME, SCORE from EXAM limit 1 offset 3
 193
 194 M: db <count-statement> ( query -- statement )
 195     [ tuple>> dup class ] keep
 196     [ [ "select count(*) from " 0% 0% where-clause ] query-make ]
 197     dip make-query* ;
 198
 199 : create-index ( index-name table-name columns -- )
 200     [
 201         [ [ "create index " % % ] dip " on " % % ] dip "(" %
 202         "," join % ")" %
 203     ] "" make sql-command ;
 204
 205 : drop-index ( index-name -- )
 206     [ "drop index " % % ] "" make sql-command ;