basis/db/sqlite/lib/lib.factor

   1 ! Copyright (C) 2008 Chris Double, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.data arrays assocs kernel math math.parser
   4 namespaces sequences db.sqlite.ffi db combinators
   5 continuations db.types calendar.format serialize
   6 io.streams.byte-array byte-arrays io.encodings.binary
   7 io.backend db.errors present urls io.encodings.utf8
   8 io.encodings.string accessors shuffle io db.private ;
   9 IN: db.sqlite.lib
  10
  11 ERROR: sqlite-error < db-error n string ;
  12 ERROR: sqlite-sql-error < sql-error n string ;
  13
  14 : throw-sqlite-error ( n -- * )
  15     dup sqlite-error-messages nth sqlite-error ;
  16
  17 : sqlite-statement-error ( -- * )
  18     SQLITE_ERROR
  19     db-connection get handle>> sqlite3_errmsg sqlite-sql-error ;
  20
  21 : sqlite-check-result ( n -- )
  22     {
  23         { SQLITE_OK [ ] }
  24         { SQLITE_ERROR [ sqlite-statement-error ] }
  25         [ throw-sqlite-error ]
  26     } case ;
  27
  28 : sqlite-open ( path -- db )
  29     normalize-path
  30     { void* } [ sqlite3_open sqlite-check-result ] [ ]
  31     with-out-parameters ;
  32
  33 : sqlite-close ( db -- )
  34     sqlite3_close sqlite-check-result ;
  35
  36 : sqlite-prepare ( db sql -- handle )
  37     utf8 encode dup length
  38     { void* void* }
  39     [ sqlite3_prepare_v2 sqlite-check-result ] [ drop ]
  40     with-out-parameters ;
  41
  42 : sqlite-bind-parameter-index ( handle name -- index )
  43     sqlite3_bind_parameter_index ;
  44
  45 : parameter-index ( handle name text -- handle name text )
  46     [ dupd sqlite-bind-parameter-index ] dip ;
  47
  48 : sqlite-bind-text ( handle index text -- )
  49     utf8 encode dup length SQLITE_TRANSIENT
  50     sqlite3_bind_text sqlite-check-result ;
  51
  52 : sqlite-bind-int ( handle i n -- )
  53     sqlite3_bind_int sqlite-check-result ;
  54
  55 : sqlite-bind-int64 ( handle i n -- )
  56     sqlite3_bind_int64 sqlite-check-result ;
  57
  58 : sqlite-bind-uint64 ( handle i n -- )
  59     sqlite3-bind-uint64 sqlite-check-result ;
  60
  61 : sqlite-bind-double ( handle i x -- )
  62     sqlite3_bind_double sqlite-check-result ;
  63
  64 : sqlite-bind-null ( handle i -- )
  65     sqlite3_bind_null sqlite-check-result ;
  66
  67 : sqlite-bind-blob ( handle i byte-array -- )
  68     dup length SQLITE_TRANSIENT
  69     sqlite3_bind_blob sqlite-check-result ;
  70
  71 : sqlite-bind-text-by-name ( handle name text -- )
  72     parameter-index sqlite-bind-text ;
  73
  74 : sqlite-bind-int-by-name ( handle name int -- )
  75     parameter-index sqlite-bind-int ;
  76
  77 : sqlite-bind-int64-by-name ( handle name int64 -- )
  78     parameter-index sqlite-bind-int64 ;
  79
  80 : sqlite-bind-uint64-by-name ( handle name int64 -- )
  81     parameter-index sqlite-bind-uint64 ;
  82
  83 : sqlite-bind-boolean-by-name ( handle name obj -- )
  84     >boolean 1 0 ? parameter-index sqlite-bind-int ;
  85
  86 : sqlite-bind-double-by-name ( handle name double -- )
  87     parameter-index sqlite-bind-double ;
  88
  89 : sqlite-bind-blob-by-name ( handle name blob -- )
  90     parameter-index sqlite-bind-blob ;
  91
  92 : sqlite-bind-null-by-name ( handle name obj -- )
  93     parameter-index drop sqlite-bind-null ;
  94
  95 : (sqlite-bind-type) ( handle key value type -- )
  96     dup array? [ first ] when
  97     {
  98         { INTEGER [ sqlite-bind-int-by-name ] }
  99         { BIG-INTEGER [ sqlite-bind-int64-by-name ] }
 100         { SIGNED-BIG-INTEGER [ sqlite-bind-int64-by-name ] }
 101         { UNSIGNED-BIG-INTEGER [ sqlite-bind-uint64-by-name ] }
 102         { BOOLEAN [ sqlite-bind-boolean-by-name ] }
 103         { TEXT [ sqlite-bind-text-by-name ] }
 104         { VARCHAR [ sqlite-bind-text-by-name ] }
 105         { DOUBLE [ sqlite-bind-double-by-name ] }
 106         { DATE [ timestamp>ymd sqlite-bind-text-by-name ] }
 107         { TIME [ timestamp>hms sqlite-bind-text-by-name ] }
 108         { DATETIME [ timestamp>ymdhms sqlite-bind-text-by-name ] }
 109         { TIMESTAMP [ timestamp>ymdhms sqlite-bind-text-by-name ] }
 110         { BLOB [ sqlite-bind-blob-by-name ] }
 111         { FACTOR-BLOB [ object>bytes sqlite-bind-blob-by-name ] }
 112         { URL [ present sqlite-bind-text-by-name ] }
 113         { +db-assigned-id+ [ sqlite-bind-int-by-name ] }
 114         { +random-id+ [ sqlite-bind-int64-by-name ] }
 115         { NULL [ sqlite-bind-null-by-name ] }
 116         [ no-sql-type ]
 117     } case ;
 118
 119 : sqlite-bind-type ( handle key value type -- )
 120     #! null and empty values need to be set by sqlite-bind-null-by-name
 121     over [
 122         NULL = [ 2drop NULL NULL ] when
 123     ] [
 124         drop NULL
 125     ] if* (sqlite-bind-type) ;
 126
 127 : sqlite-finalize ( handle -- ) sqlite3_finalize sqlite-check-result ;
 128 : sqlite-reset ( handle -- ) sqlite3_reset sqlite-check-result ;
 129 : sqlite-clear-bindings ( handle -- )
 130     sqlite3_clear_bindings sqlite-check-result ;
 131 : sqlite-#columns ( query -- int ) sqlite3_column_count ;
 132 : sqlite-column ( handle index -- string ) sqlite3_column_text ;
 133 : sqlite-column-name ( handle index -- string ) sqlite3_column_name ;
 134 : sqlite-column-type ( handle index -- string ) sqlite3_column_type ;
 135
 136 : sqlite-column-blob ( handle index -- byte-array/f )
 137     [ sqlite3_column_bytes ] 2keep
 138     pick zero? [
 139         3drop f
 140     ] [
 141         sqlite3_column_blob swap memory>byte-array
 142     ] if ;
 143
 144 : sqlite-column-typed ( handle index type -- obj )
 145     dup array? [ first ] when
 146     {
 147         { +db-assigned-id+ [ sqlite3_column_int64  ] }
 148         { +random-id+ [ sqlite3-column-uint64 ] }
 149         { INTEGER [ sqlite3_column_int ] }
 150         { BIG-INTEGER [ sqlite3_column_int64 ] }
 151         { SIGNED-BIG-INTEGER [ sqlite3_column_int64 ] }
 152         { UNSIGNED-BIG-INTEGER [ sqlite3-column-uint64 ] }
 153         { BOOLEAN [ sqlite3_column_int 1 = ] }
 154         { DOUBLE [ sqlite3_column_double ] }
 155         { TEXT [ sqlite3_column_text ] }
 156         { VARCHAR [ sqlite3_column_text ] }
 157         { DATE [ sqlite3_column_text dup [ ymd>timestamp ] when ] }
 158         { TIME [ sqlite3_column_text dup [ hms>timestamp ] when ] }
 159         { TIMESTAMP [ sqlite3_column_text dup [ ymdhms>timestamp ] when ] }
 160         { DATETIME [ sqlite3_column_text dup [ ymdhms>timestamp ] when ] }
 161         { BLOB [ sqlite-column-blob ] }
 162         { URL [ sqlite3_column_text dup [ >url ] when ] }
 163         { FACTOR-BLOB [ sqlite-column-blob dup [ bytes>object ] when ] }
 164         [ no-sql-type ]
 165     } case ;
 166
 167 : sqlite-row ( handle -- seq )
 168     dup sqlite-#columns [ sqlite-column ] with map ;
 169
 170 : sqlite-step-has-more-rows? ( prepared -- ? )
 171     {
 172         { SQLITE_ROW [ t ] }
 173         { SQLITE_DONE [ f ] }
 174         [ sqlite-check-result f ]
 175     } case ;
 176
 177 : sqlite-next ( prepared -- ? )
 178     sqlite3_step sqlite-step-has-more-rows? ;