basis/db/sqlite/sqlite.factor

   1 ! Copyright (C) 2005, 2008 Chris Double, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien arrays assocs classes compiler db hashtables
   4 io.files kernel math math.parser namespaces prettyprint
   5 sequences strings classes.tuple alien.c-types continuations
   6 db.sqlite.lib db.sqlite.ffi db.tuples words db.types combinators
   7 math.intervals io nmake accessors vectors math.ranges random
   8 math.bitwise db.queries destructors db.tuples.private ;
   9 IN: db.sqlite
  10
  11 TUPLE: sqlite-db < db path ;
  12
  13 M: sqlite-db make-db* ( path db -- db )
  14     swap >>path ;
  15
  16 M: sqlite-db db-open ( db -- db )
  17     dup path>> sqlite-open >>handle ;
  18
  19 M: sqlite-db db-close ( handle -- ) sqlite-close ;
  20 M: sqlite-db dispose ( db -- ) db-dispose ;
  21
  22 TUPLE: sqlite-statement < statement ;
  23
  24 TUPLE: sqlite-result-set < result-set has-more? ;
  25
  26 M: sqlite-db <simple-statement> ( str in out -- obj )
  27     <prepared-statement> ;
  28
  29 M: sqlite-db <prepared-statement> ( str in out -- obj )
  30     sqlite-statement new-statement ;
  31
  32 : sqlite-maybe-prepare ( statement -- statement )
  33     dup handle>> [
  34         db get handle>> over sql>> sqlite-prepare
  35         >>handle
  36     ] unless ;
  37
  38 M: sqlite-statement dispose ( statement -- )
  39     handle>>
  40     [ [ sqlite3_reset drop ] keep sqlite-finalize ] when* ;
  41
  42 M: sqlite-result-set dispose ( result-set -- )
  43     f >>handle drop ;
  44
  45 : reset-bindings ( statement -- )
  46     sqlite-maybe-prepare
  47     handle>> [ sqlite3_reset drop ] [ sqlite3_clear_bindings drop ] bi ;
  48
  49 M: sqlite-statement low-level-bind ( statement -- )
  50     [ bind-params>> ] [ handle>> ] bi
  51     [ swap [ key>> ] [ value>> ] [ type>> ] tri sqlite-bind-type ] curry each ;
  52
  53 M: sqlite-statement bind-statement* ( statement -- )
  54     sqlite-maybe-prepare
  55     dup bound?>> [ dup reset-bindings ] when
  56     low-level-bind ;
  57
  58 GENERIC: sqlite-bind-conversion ( tuple obj -- array )
  59
  60 TUPLE: sqlite-low-level-binding < low-level-binding key type ;
  61 : <sqlite-low-level-binding> ( key value type -- obj )
  62     sqlite-low-level-binding new
  63         swap >>type
  64         swap >>value
  65         swap >>key ;
  66
  67 M: sql-spec sqlite-bind-conversion ( tuple spec -- array )
  68     [ column-name>> ":" prepend ]
  69     [ slot-name>> rot get-slot-named ]
  70     [ type>> ] tri <sqlite-low-level-binding> ;
  71
  72 M: literal-bind sqlite-bind-conversion ( tuple literal-bind -- array )
  73     nip [ key>> ] [ value>> ] [ type>> ] tri
  74     <sqlite-low-level-binding> ;
  75
  76 M: generator-bind sqlite-bind-conversion ( tuple generate-bind -- array )
  77     tuck
  78     [ generator-singleton>> eval-generator tuck ] [ slot-name>> ] bi
  79     rot set-slot-named
  80     >r [ key>> ] [ type>> ] bi r> swap <sqlite-low-level-binding> ;
  81
  82 M: sqlite-statement bind-tuple ( tuple statement -- )
  83     [
  84         in-params>> [ sqlite-bind-conversion ] with map
  85     ] keep bind-statement ;
  86
  87 : last-insert-id ( -- id )
  88     db get handle>> sqlite3_last_insert_rowid
  89     dup zero? [ "last-id failed" throw ] when ;
  90
  91 M: sqlite-db insert-tuple* ( tuple statement -- )
  92     execute-statement last-insert-id swap set-primary-key ;
  93
  94 M: sqlite-result-set #columns ( result-set -- n )
  95     handle>> sqlite-#columns ;
  96
  97 M: sqlite-result-set row-column ( result-set n -- obj )
  98     [ handle>> ] [ sqlite-column ] bi* ;
  99
 100 M: sqlite-result-set row-column-typed ( result-set n -- obj )
 101     dup pick out-params>> nth type>>
 102     >r >r handle>> r> r> sqlite-column-typed ;
 103
 104 M: sqlite-result-set advance-row ( result-set -- )
 105     dup handle>> sqlite-next >>has-more? drop ;
 106
 107 M: sqlite-result-set more-rows? ( result-set -- ? )
 108     has-more?>> ;
 109
 110 M: sqlite-statement query-results ( query -- result-set )
 111     sqlite-maybe-prepare
 112     dup handle>> sqlite-result-set new-result-set
 113     dup advance-row ;
 114
 115 M: sqlite-db create-sql-statement ( class -- statement )
 116     [
 117         "create table " 0% 0%
 118         "(" 0% [ ", " 0% ] [
 119             dup column-name>> 0%
 120             " " 0%
 121             dup type>> lookup-create-type 0%
 122             modifiers 0%
 123         ] interleave ");" 0%
 124     ] query-make ;
 125
 126 M: sqlite-db drop-sql-statement ( class -- statement )
 127     [ "drop table " 0% 0% ";" 0% drop ] query-make ;
 128
 129 M: sqlite-db <insert-db-assigned-statement> ( tuple -- statement )
 130     [
 131         "insert into " 0% 0%
 132         "(" 0%
 133         remove-db-assigned-id
 134         dup [ ", " 0% ] [ column-name>> 0% ] interleave
 135         ") values(" 0%
 136         [ ", " 0% ] [
 137             dup type>> +random-id+ = [
 138                 [ slot-name>> ]
 139                 [
 140                     column-name>> ":" prepend dup 0%
 141                     random-id-generator
 142                 ] [ type>> ] tri <generator-bind> 1,
 143             ] [
 144                 bind%
 145             ] if
 146         ] interleave
 147         ");" 0%
 148     ] query-make ;
 149
 150 M: sqlite-db <insert-user-assigned-statement> ( tuple -- statement )
 151     <insert-db-assigned-statement> ;
 152
 153 M: sqlite-db bind# ( spec obj -- )
 154     >r
 155     [ column-name>> ":" swap next-sql-counter 3append dup 0% ]
 156     [ type>> ] bi
 157     r> <literal-bind> 1, ;
 158
 159 M: sqlite-db bind% ( spec -- )
 160     dup 1, column-name>> ":" prepend 0% ;
 161
 162 M: sqlite-db persistent-table ( -- assoc )
 163     H{
 164         { +db-assigned-id+ { "integer primary key" "integer primary key" "primary key" } }
 165         { +user-assigned-id+ { f f "primary key" } }
 166         { +random-id+ { "integer primary key" "integer primary key" "primary key" } }
 167         { INTEGER { "integer" "integer" "primary key" } }
 168         { BIG-INTEGER { "bigint" "bigint" } }
 169         { SIGNED-BIG-INTEGER { "bigint" "bigint" } }
 170         { UNSIGNED-BIG-INTEGER { "bigint" "bigint" } }
 171         { TEXT { "text" "text" } }
 172         { VARCHAR { "text" "text" } }
 173         { DATE { "date" "date" } }
 174         { TIME { "time" "time" } }
 175         { DATETIME { "datetime" "datetime" } }
 176         { TIMESTAMP { "timestamp" "timestamp" } }
 177         { DOUBLE { "real" "real" } }
 178         { BLOB { "blob" "blob" } }
 179         { FACTOR-BLOB { "blob" "blob" } }
 180         { URL { "text" "text" } }
 181         { +autoincrement+ { f f "autoincrement" } }
 182         { +unique+ { f f "unique" } }
 183         { +default+ { f f "default" } }
 184         { +null+ { f f "null" } }
 185         { +not-null+ { f f "not null" } }
 186         { system-random-generator { f f f } }
 187         { secure-random-generator { f f f } }
 188         { random-generator { f f f } }
 189     } ;
 190
 191 M: sqlite-db compound ( str seq -- str' )
 192     over {
 193         { "default" [ first number>string join-space ] }
 194         [ 2drop ]
 195     } case ;