basis/db/tuples/tuples-tests.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: io.files kernel tools.test db db.tuples classes
   4 db.types continuations namespaces math math.ranges
   5 prettyprint calendar sequences db.sqlite math.intervals
   6 db.postgresql accessors random math.bitwise
   7 math.ranges strings urls fry db.tuples.private ;
   8 IN: db.tuples.tests
   9
  10 : test-sqlite ( quot -- )
  11     [ ] swap '[
  12         "tuples-test.db" temp-file sqlite-db _ with-db
  13     ] unit-test ;
  14
  15 : test-postgresql ( quot -- )
  16     [ ] swap '[
  17         { "localhost" "postgres" "foob" "factor-test" }
  18         postgresql-db _ with-db
  19     ] unit-test ;
  20
  21 TUPLE: person the-id the-name the-number the-real
  22 ts date time blob factor-blob url ;
  23
  24 : <person> ( name age real ts date time blob factor-blob url -- person )
  25     person new
  26         swap >>url
  27         swap >>factor-blob
  28         swap >>blob
  29         swap >>time
  30         swap >>date
  31         swap >>ts
  32         swap >>the-real
  33         swap >>the-number
  34         swap >>the-name ;
  35
  36 : <user-assigned-person> ( id name age real ts date time blob factor-blob url -- person )
  37     <person>
  38         swap >>the-id ;
  39
  40 SYMBOL: person1
  41 SYMBOL: person2
  42 SYMBOL: person3
  43 SYMBOL: person4
  44
  45 : test-tuples ( -- )
  46     [ ] [ person recreate-table ] unit-test
  47     [ ] [ person ensure-table ] unit-test
  48     [ ] [ person drop-table ] unit-test
  49     [ ] [ person create-table ] unit-test
  50     [ person create-table ] must-fail
  51     [ ] [ person ensure-table ] unit-test
  52
  53     [ ] [ person1 get insert-tuple ] unit-test
  54
  55     [ 1 ] [ person1 get the-id>> ] unit-test
  56
  57     [ ] [ person1 get 200 >>the-number drop ] unit-test
  58
  59     [ ] [ person1 get update-tuple ] unit-test
  60
  61     [ T{ person f 1 "billy" 200 3.14 } ]
  62     [ T{ person f 1 } select-tuple ] unit-test
  63     [ ] [ person2 get insert-tuple ] unit-test
  64     [
  65         {
  66             T{ person f 1 "billy" 200 3.14 }
  67             T{ person f 2 "johnny" 10 3.14 }
  68         }
  69     ] [ T{ person f f f f 3.14 } select-tuples ] unit-test
  70     [
  71         {
  72             T{ person f 1 "billy" 200 3.14 }
  73             T{ person f 2 "johnny" 10 3.14 }
  74         }
  75     ] [ T{ person f } select-tuples ] unit-test
  76
  77     [
  78         {
  79             T{ person f 2 "johnny" 10 3.14 }
  80         }
  81     ] [ T{ person f f f 10 3.14 } select-tuples ] unit-test
  82
  83
  84     [ ] [ person1 get delete-tuples ] unit-test
  85     [ f ] [ T{ person f 1 } select-tuple ] unit-test
  86
  87     [ ] [ person3 get insert-tuple ] unit-test
  88
  89     [
  90         T{
  91             person
  92             f
  93             3
  94             "teddy"
  95             10
  96             3.14
  97             T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
  98             T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
  99             T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 100             B{ 115 116 111 114 101 105 110 97 98 108 111 98 }
 101         }
 102     ] [ T{ person f 3 } select-tuple ] unit-test
 103
 104     [ ] [ person4 get insert-tuple ] unit-test
 105     [
 106         T{
 107             person
 108             f
 109             4
 110             "eddie"
 111             10
 112             3.14
 113             T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
 114             T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
 115             T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 116             f
 117             H{ { 1 2 } { 3 4 } { 5 "lol" } }
 118             URL" http://www.google.com/search?hl=en&q=trailer+park+boys&btnG=Google+Search"
 119         }
 120     ] [ T{ person f 4 } select-tuple ] unit-test
 121
 122     [ ] [ person drop-table ] unit-test ;
 123
 124 : db-assigned-person-schema ( -- )
 125     person "PERSON"
 126     {
 127         { "the-id" "ID" +db-assigned-id+ }
 128         { "the-name" "NAME" { VARCHAR 256 } +not-null+ }
 129         { "the-number" "AGE" INTEGER { +default+ 0 } }
 130         { "the-real" "REAL" DOUBLE { +default+ 0.3 } }
 131         { "ts" "TS" TIMESTAMP }
 132         { "date" "D" DATE }
 133         { "time" "T" TIME }
 134         { "blob" "B" BLOB }
 135         { "factor-blob" "FB" FACTOR-BLOB }
 136         { "url" "U" URL }
 137     } define-persistent
 138     "billy" 10 3.14 f f f f f f <person> person1 set
 139     "johnny" 10 3.14 f f f f f f <person> person2 set
 140     "teddy" 10 3.14
 141         T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
 142         T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
 143         T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 144         B{ 115 116 111 114 101 105 110 97 98 108 111 98 } f f <person> person3 set
 145     "eddie" 10 3.14
 146         T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
 147         T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
 148         T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 149         f H{ { 1 2 } { 3 4 } { 5 "lol" } } URL" http://www.google.com/search?hl=en&q=trailer+park+boys&btnG=Google+Search"  <person> person4 set ;
 150
 151 : user-assigned-person-schema ( -- )
 152     person "PERSON"
 153     {
 154         { "the-id" "ID" INTEGER +user-assigned-id+ }
 155         { "the-name" "NAME" { VARCHAR 256 } +not-null+ }
 156         { "the-number" "AGE" INTEGER { +default+ 0 } }
 157         { "the-real" "REAL" DOUBLE { +default+ 0.3 } }
 158         { "ts" "TS" TIMESTAMP }
 159         { "date" "D" DATE }
 160         { "time" "T" TIME }
 161         { "blob" "B" BLOB }
 162         { "factor-blob" "FB" FACTOR-BLOB }
 163         { "url" "U" URL }
 164     } define-persistent
 165     1 "billy" 10 3.14 f f f f f f <user-assigned-person> person1 set
 166     2 "johnny" 10 3.14 f f f f f f <user-assigned-person> person2 set
 167     3 "teddy" 10 3.14
 168         T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
 169         T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
 170         T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 171         B{ 115 116 111 114 101 105 110 97 98 108 111 98 }
 172         f f <user-assigned-person> person3 set
 173     4 "eddie" 10 3.14
 174         T{ timestamp f 2008 3 5 16 24 11 T{ duration f 0 0 0 0 0 0 } }
 175         T{ timestamp f 2008 11 22 0 0 0 T{ duration f 0 0 0 0 0 0 } }
 176         T{ timestamp f 0 0 0 12 34 56 T{ duration f 0 0 0 0 0 0 } }
 177         f H{ { 1 2 } { 3 4 } { 5 "lol" } } URL" http://www.google.com/search?hl=en&q=trailer+park+boys&btnG=Google+Search" <user-assigned-person> person4 set ;
 178
 179 TUPLE: paste n summary author channel mode contents timestamp annotations ;
 180 TUPLE: annotation n paste-id summary author mode contents ;
 181
 182 : db-assigned-paste-schema ( -- )
 183     paste "PASTE"
 184     {
 185         { "n" "ID" +db-assigned-id+ }
 186         { "summary" "SUMMARY" TEXT }
 187         { "author" "AUTHOR" TEXT }
 188         { "channel" "CHANNEL" TEXT }
 189         { "mode" "MODE" TEXT }
 190         { "contents" "CONTENTS" TEXT }
 191         { "timestamp" "DATE" TIMESTAMP }
 192         { "annotations" { +has-many+ annotation } }
 193     } define-persistent
 194
 195     annotation "ANNOTATION"
 196     {
 197         { "n" "ID" +db-assigned-id+ }
 198         { "paste-id" "PASTE_ID" INTEGER { +foreign-id+ paste "n" } }
 199         { "summary" "SUMMARY" TEXT }
 200         { "author" "AUTHOR" TEXT }
 201         { "mode" "MODE" TEXT }
 202         { "contents" "CONTENTS" TEXT }
 203     } define-persistent ;
 204
 205 : test-paste-schema ( -- )
 206     [ ] [ db-assigned-paste-schema ] unit-test
 207     [ ] [ paste ensure-table ] unit-test
 208     [ ] [ annotation ensure-table ] unit-test
 209     [ ] [ annotation drop-table ] unit-test
 210     [ ] [ paste drop-table ] unit-test
 211     [ ] [ paste create-table ] unit-test
 212     [ ] [ annotation create-table ] unit-test
 213
 214     [ ] [
 215         paste new
 216             "summary1" >>summary
 217             "erg" >>author
 218             "#lol" >>channel
 219             "contents1" >>contents
 220             now >>timestamp
 221         insert-tuple
 222     ] unit-test
 223
 224     [ ] [
 225         annotation new
 226             1 >>paste-id
 227             "annotation1" >>summary
 228             "erg" >>author
 229             "annotation contents" >>contents
 230         insert-tuple
 231     ] unit-test
 232
 233     [ ] [
 234     ] unit-test
 235     ;
 236
 237 [ test-paste-schema ] test-sqlite
 238 [ test-paste-schema ] test-postgresql
 239
 240 : test-repeated-insert
 241     [ ] [ person ensure-table ] unit-test
 242     [ ] [ person1 get insert-tuple ] unit-test
 243     [ person1 get insert-tuple ] must-fail ;
 244
 245 TUPLE: serialize-me id data ;
 246
 247 : test-serialize ( -- )
 248     serialize-me "SERIALIZED"
 249     {
 250         { "id" "ID" +db-assigned-id+ }
 251         { "data" "DATA" FACTOR-BLOB }
 252     } define-persistent
 253     [ serialize-me drop-table ] [ drop ] recover
 254     [ ] [ serialize-me create-table ] unit-test
 255
 256     [ ] [ T{ serialize-me f f H{ { 1 2 } } } insert-tuple ] unit-test
 257     [
 258         { T{ serialize-me f 1 H{ { 1 2 } } } }
 259     ] [ T{ serialize-me f 1 } select-tuples ] unit-test ;
 260
 261 TUPLE: exam id name score ;
 262
 263 : random-exam ( -- exam )
 264         f
 265         6 [ CHAR: a CHAR: z [a,b] random ] replicate >string
 266         100 random
 267     exam boa ;
 268
 269 : test-intervals ( -- )
 270     [
 271         exam "EXAM"
 272         {
 273             { "idd" "ID" +db-assigned-id+ }
 274             { "named" "NAME" TEXT }
 275             { "score" "SCORE" INTEGER }
 276         } define-persistent
 277     ] [
 278         seq>> { "idd" "named" } =
 279     ] must-fail-with
 280
 281     exam "EXAM"
 282     {
 283         { "id" "ID" +db-assigned-id+ }
 284         { "name" "NAME" TEXT }
 285         { "score" "SCORE" INTEGER }
 286     } define-persistent
 287     [ exam drop-table ] [ drop ] recover
 288     [ ] [ exam create-table ] unit-test
 289
 290     [ ] [ T{ exam f f "Kyle" 100 } insert-tuple ] unit-test
 291     [ ] [ T{ exam f f "Stan" 80 } insert-tuple ] unit-test
 292     [ ] [ T{ exam f f "Kenny" 60 } insert-tuple ] unit-test
 293     [ ] [ T{ exam f f "Cartman" 41 } insert-tuple ] unit-test
 294
 295     [
 296         {
 297             T{ exam f 3 "Kenny" 60 }
 298             T{ exam f 4 "Cartman" 41 }
 299         }
 300     ] [
 301         T{ exam f f f T{ interval f { 0 t } { 70 t } } } select-tuples
 302     ] unit-test
 303
 304     [
 305         { }
 306     ] [
 307         T{ exam f T{ interval f { 3 f } { 4 f } } f } select-tuples
 308     ] unit-test
 309     [
 310         {
 311             T{ exam f 4 "Cartman" 41 }
 312         }
 313     ] [
 314         T{ exam f T{ interval f { 3 f } { 4 t } } f } select-tuples
 315     ] unit-test
 316     [
 317         {
 318             T{ exam f 3 "Kenny" 60 }
 319         }
 320     ] [
 321         T{ exam f T{ interval f { 3 t } { 4 f } } f } select-tuples
 322     ] unit-test
 323     [
 324         {
 325             T{ exam f 3 "Kenny" 60 }
 326             T{ exam f 4 "Cartman" 41 }
 327         }
 328     ] [
 329         T{ exam f T{ interval f { 3 t } { 4 t } } f } select-tuples
 330     ] unit-test
 331
 332     [
 333         {
 334             T{ exam f 1 "Kyle" 100 }
 335             T{ exam f 2 "Stan" 80 }
 336         }
 337     ] [
 338         T{ exam f f { "Stan" "Kyle" } } select-tuples
 339     ] unit-test
 340
 341     [
 342         {
 343             T{ exam f 1 "Kyle" 100 }
 344             T{ exam f 2 "Stan" 80 }
 345             T{ exam f 3 "Kenny" 60 }
 346         }
 347     ] [
 348         T{ exam f T{ range f 1 3 1 } } select-tuples
 349     ] unit-test
 350
 351     [
 352         {
 353             T{ exam f 2 "Stan" 80 }
 354             T{ exam f 3 "Kenny" 60 }
 355             T{ exam f 4 "Cartman" 41 }
 356         }
 357     ] [
 358         T{ exam f T{ interval f { 2 t } { 1.0/0.0 f } } } select-tuples
 359     ] unit-test
 360
 361     [
 362         {
 363             T{ exam f 1 "Kyle" 100 }
 364         }
 365     ] [
 366         T{ exam f T{ interval f { -1.0/0.0 t } { 2 f } } } select-tuples
 367     ] unit-test
 368
 369     [
 370         {
 371             T{ exam f 1 "Kyle" 100 }
 372             T{ exam f 2 "Stan" 80 }
 373             T{ exam f 3 "Kenny" 60 }
 374             T{ exam f 4 "Cartman" 41 }
 375         }
 376     ] [
 377         T{ exam f T{ interval f { -1.0/0.0 t } { 1/0. f } } } select-tuples
 378     ] unit-test
 379
 380     [
 381         {
 382             T{ exam f 1 "Kyle" 100 }
 383             T{ exam f 2 "Stan" 80 }
 384             T{ exam f 3 "Kenny" 60 }
 385             T{ exam f 4 "Cartman" 41 }
 386         }
 387     ] [
 388         T{ exam } select-tuples
 389     ] unit-test
 390
 391     [ 4 ] [ T{ exam } count-tuples ] unit-test ;
 392
 393 TUPLE: bignum-test id m n o ;
 394 : <bignum-test> ( m n o -- obj )
 395     bignum-test new
 396         swap >>o
 397         swap >>n
 398         swap >>m ;
 399
 400 : test-bignum
 401     bignum-test "BIGNUM_TEST"
 402     {
 403         { "id" "ID" +db-assigned-id+ }
 404         { "m" "M" BIG-INTEGER }
 405         { "n" "N" UNSIGNED-BIG-INTEGER }
 406         { "o" "O" SIGNED-BIG-INTEGER }
 407     } define-persistent
 408     [ bignum-test drop-table ] ignore-errors
 409     [ ] [ bignum-test ensure-table ] unit-test
 410     [ ] [ 63 2^ 1- dup dup <bignum-test> insert-tuple ] unit-test ;
 411
 412     ! sqlite only
 413     ! [ T{ bignum-test f 1
 414         ! -9223372036854775808 9223372036854775808 -9223372036854775808 } ]
 415     ! [ T{ bignum-test f 1 } select-tuple ] unit-test ;
 416
 417 TUPLE: secret n message ;
 418 C: <secret> secret
 419
 420 : test-random-id
 421     secret "SECRET"
 422     {
 423         { "n" "ID" +random-id+ system-random-generator }
 424         { "message" "MESSAGE" TEXT }
 425     } define-persistent
 426
 427     [ ] [ secret recreate-table ] unit-test
 428
 429     [ t ] [ f "kilroy was here" <secret> [ insert-tuple ] keep n>> integer? ] unit-test
 430
 431     [ ] [ f "kilroy was here2" <secret> insert-tuple ] unit-test
 432
 433     [ ] [ f "kilroy was here3" <secret> insert-tuple ] unit-test
 434
 435     [ t ] [
 436         T{ secret } select-tuples
 437         first message>> "kilroy was here" head?
 438     ] unit-test
 439
 440     [ t ] [
 441         T{ secret } select-tuples length 3 =
 442     ] unit-test ;
 443
 444 [ db-assigned-person-schema test-tuples ] test-sqlite
 445 [ user-assigned-person-schema test-tuples ] test-sqlite
 446 [ user-assigned-person-schema test-repeated-insert ] test-sqlite
 447 [ test-bignum ] test-sqlite
 448 [ test-serialize ] test-sqlite
 449 [ test-intervals ] test-sqlite
 450 [ test-random-id ] test-sqlite
 451
 452 [ db-assigned-person-schema test-tuples ] test-postgresql
 453 [ user-assigned-person-schema test-tuples ] test-postgresql
 454 [ user-assigned-person-schema test-repeated-insert ] test-postgresql
 455 [ test-bignum ] test-postgresql
 456 [ test-serialize ] test-postgresql
 457 [ test-intervals ] test-postgresql
 458 [ test-random-id ] test-postgresql
 459
 460 TUPLE: does-not-persist ;
 461
 462 [
 463     [ does-not-persist create-sql-statement ]
 464     [ class \ not-persistent = ] must-fail-with
 465 ] test-sqlite
 466
 467 [
 468     [ does-not-persist create-sql-statement ]
 469     [ class \ not-persistent = ] must-fail-with
 470 ] test-postgresql
 471
 472
 473 TUPLE: suparclass id a ;
 474
 475 suparclass f {
 476     { "id" "ID" +db-assigned-id+ }
 477     { "a" "A" INTEGER }
 478 } define-persistent
 479
 480 TUPLE: subbclass < suparclass b ;
 481
 482 subbclass "SUBCLASS" {
 483     { "b" "B" TEXT }
 484 } define-persistent
 485
 486 TUPLE: fubbclass < subbclass ;
 487
 488 fubbclass "FUBCLASS" { } define-persistent
 489
 490 : test-db-inheritance ( -- )
 491     [ ] [ subbclass ensure-table ] unit-test
 492     [ ] [ fubbclass ensure-table ] unit-test
 493
 494     [ ] [
 495         subbclass new 5 >>a "hi" >>b dup insert-tuple id>> "id" set
 496     ] unit-test
 497
 498     [ t "hi" 5 ] [
 499         subbclass new "id" get >>id select-tuple
 500         [ subbclass? ] [ b>> ] [ a>> ] tri
 501     ] unit-test
 502
 503     [ ] [ fubbclass new 0 >>a "hi" >>b insert-tuple ] unit-test
 504
 505     [ t ] [ fubbclass new select-tuples [ fubbclass? ] all? ] unit-test ;
 506
 507 [ test-db-inheritance ] test-sqlite
 508 [ test-db-inheritance ] test-postgresql
 509
 510
 511 TUPLE: string-encoding-test id string ;
 512
 513 string-encoding-test "STRING_ENCODING_TEST" {
 514     { "id" "ID" +db-assigned-id+ }
 515     { "string" "STRING" TEXT }
 516 } define-persistent
 517
 518 : test-string-encoding ( -- )
 519     [ ] [ string-encoding-test ensure-table ] unit-test
 520
 521     [ ] [
 522         string-encoding-test new
 523             "\u{copyright-sign}\u{bengali-letter-cha}" >>string
 524         [ insert-tuple ] [ id>> "id" set ] bi
 525     ] unit-test
 526
 527     [ "\u{copyright-sign}\u{bengali-letter-cha}" ] [
 528         string-encoding-test new "id" get >>id select-tuple string>>
 529     ] unit-test ;
 530
 531 [ test-string-encoding ] test-sqlite
 532 [ test-string-encoding ] test-postgresql
 533
 534 ! Don't comment these out. These words must infer
 535 \ bind-tuple must-infer
 536 \ insert-tuple must-infer
 537 \ update-tuple must-infer
 538 \ delete-tuples must-infer
 539 \ select-tuple must-infer
 540 \ define-persistent must-infer
 541 \ ensure-table must-infer
 542 \ create-table must-infer
 543 \ drop-table must-infer
 544
 545 : test-queries ( -- )
 546     [ ] [ exam ensure-table ] unit-test
 547     [ ] [ 1000 [ random-exam insert-tuple ] times ] unit-test
 548     [ 5 ] [
 549         <query>
 550         T{ exam { score T{ interval { from { 0 t } } { to { 100 t } } } } }
 551             >>tuple
 552         5 >>limit select-tuples length
 553     ] unit-test ;
 554
 555 TUPLE: compound-foo a b c ;
 556
 557 compound-foo "COMPOUND_FOO"
 558 {
 559     { "a" "A" INTEGER +user-assigned-id+ }
 560     { "b" "B" INTEGER +user-assigned-id+ }
 561     { "c" "C" INTEGER }
 562 } define-persistent
 563
 564 : test-compound-primary-key ( -- )
 565     [ ] [ compound-foo ensure-table ] unit-test
 566     [ ] [ compound-foo drop-table ] unit-test
 567     [ ] [ compound-foo create-table ] unit-test
 568     [ ] [ 1 2 3 compound-foo boa insert-tuple ] unit-test
 569     [ 1 2 3 compound-foo boa insert-tuple ] must-fail
 570     [ ] [ 2 3 4 compound-foo boa insert-tuple ] unit-test
 571     [ T{ compound-foo { a 2 } { b 3 } { c 4 } } ]
 572     [ compound-foo new 4 >>c select-tuple ] unit-test ;
 573
 574 [ test-compound-primary-key ] test-sqlite
 575 [ test-compound-primary-key ] test-postgresql
 576
 577 : test-sqlite-db ( -- )
 578     "tuples-test.db" temp-file sqlite-db make-db db-open db set ;
 579
 580 : test-postgresql-db ( -- )
 581     { "localhost" "postgres" "foob" "factor-test" } postgresql-db
 582     make-db db-open db set ;