basis/debugger/debugger.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: slots arrays definitions generic hashtables summary io kernel
   4 math namespaces make prettyprint prettyprint.config sequences assocs
   5 sequences.private strings io.styles io.pathnames vectors words system
   6 splitting math.parser classes.mixin classes.tuple continuations
   7 continuations.private combinators generic.math classes.builtin classes
   8 compiler.units generic.standard generic.single vocabs init
   9 kernel.private io.encodings accessors math.order destructors
  10 source-files parser classes.tuple.parser effects.parser lexer
  11 generic.parser strings.parser vocabs.loader vocabs.parser see
  12 source-files.errors ;
  13 IN: debugger
  14
  15 GENERIC: error. ( error -- )
  16 GENERIC: error-help ( error -- topic )
  17
  18 M: object error. . ;
  19
  20 M: object error-help drop f ;
  21
  22 M: tuple error-help class ;
  23
  24 M: string error. print ;
  25
  26 : :s ( -- )
  27     error-continuation get data>> stack. ;
  28
  29 : :r ( -- )
  30     error-continuation get retain>> stack. ;
  31
  32 : :c ( -- )
  33     error-continuation get call>> callstack. ;
  34
  35 : :get ( variable -- value )
  36     error-continuation get name>> assoc-stack ;
  37
  38 : :res ( n -- * )
  39     1 - restarts get-global nth f restarts set-global restart ;
  40
  41 : :1 ( -- * ) 1 :res ;
  42 : :2 ( -- * ) 2 :res ;
  43 : :3 ( -- * ) 3 :res ;
  44
  45 : restart. ( restart n -- )
  46     [
  47         1 + dup 3 <= [ ":" % # "    " % ] [ # " :res  " % ] if
  48         name>> %
  49     ] "" make print ;
  50
  51 : restarts. ( -- )
  52     restarts get [
  53         nl
  54         "The following restarts are available:" print
  55         nl
  56         [ restart. ] each-index
  57     ] unless-empty ;
  58
  59 : print-error ( error -- )
  60     [ error. flush ] curry
  61     [ global [ "Error in print-error!" print drop ] bind ]
  62     recover ;
  63
  64 : :error ( -- )
  65     error get print-error ;
  66
  67 : print-error-and-restarts ( error -- )
  68     print-error
  69     restarts.
  70     nl
  71     "Type :help for debugging help." print flush ;
  72
  73 : try ( quot -- )
  74     [ print-error-and-restarts ] recover ; inline
  75
  76 : expired-error. ( obj -- )
  77     "Object did not survive image save/load: " write third . ;
  78
  79 : io-error. ( error -- )
  80     "I/O error #" write third . ;
  81
  82 : type-check-error. ( obj -- )
  83     "Type check error" print
  84     "Object: " write dup fourth short.
  85     "Object type: " write dup fourth class .
  86     "Expected type: " write third type>class . ;
  87
  88 : divide-by-zero-error. ( obj -- )
  89     "Division by zero" print drop ;
  90
  91 HOOK: signal-error. os ( obj -- )
  92
  93 : array-size-error. ( obj -- )
  94     "Invalid array size: " write dup third .
  95     "Maximum: " write fourth 1 - . ;
  96
  97 : c-string-error. ( obj -- )
  98     "Cannot convert to C string: " write third . ;
  99
 100 : ffi-error. ( obj -- )
 101     "FFI error" print drop ;
 102
 103 : heap-scan-error. ( obj -- )
 104     "Cannot do next-object outside begin/end-scan" print drop ;
 105
 106 : undefined-symbol-error. ( obj -- )
 107     "The image refers to a library or symbol that was not found at load time"
 108     print drop ;
 109
 110 : stack-underflow. ( obj name -- )
 111     write " stack underflow" print drop ;
 112
 113 : stack-overflow. ( obj name -- )
 114     write " stack overflow" print drop ;
 115
 116 : datastack-underflow. ( obj -- ) "Data" stack-underflow. ;
 117 : datastack-overflow. ( obj -- ) "Data" stack-overflow. ;
 118 : retainstack-underflow. ( obj -- ) "Retain" stack-underflow. ;
 119 : retainstack-overflow. ( obj -- ) "Retain" stack-overflow. ;
 120
 121 : memory-error. ( error -- )
 122     "Memory protection fault at address " write third .h ;
 123
 124 : primitive-error. ( error -- )
 125     "Unimplemented primitive" print drop ;
 126
 127 PREDICATE: vm-error < array
 128     {
 129         { [ dup empty? ] [ drop f ] }
 130         { [ dup first "kernel-error" = not ] [ drop f ] }
 131         [ second 0 15 between? ]
 132     } cond ;
 133
 134 : vm-errors ( error -- n errors )
 135     second {
 136         { 0  [ expired-error.          ] }
 137         { 1  [ io-error.               ] }
 138         { 2  [ primitive-error.        ] }
 139         { 3  [ type-check-error.       ] }
 140         { 4  [ divide-by-zero-error.   ] }
 141         { 5  [ signal-error.           ] }
 142         { 6  [ array-size-error.       ] }
 143         { 7  [ c-string-error.         ] }
 144         { 8  [ ffi-error.              ] }
 145         { 9  [ heap-scan-error.        ] }
 146         { 10 [ undefined-symbol-error. ] }
 147         { 11 [ datastack-underflow.    ] }
 148         { 12 [ datastack-overflow.     ] }
 149         { 13 [ retainstack-underflow.  ] }
 150         { 14 [ retainstack-overflow.   ] }
 151         { 15 [ memory-error.           ] }
 152     } ; inline
 153
 154 M: vm-error summary drop "VM error" ;
 155
 156 M: vm-error error. dup vm-errors case ;
 157
 158 M: vm-error error-help vm-errors at first ;
 159
 160 M: no-method summary
 161     drop "No suitable method" ;
 162
 163 M: no-method error.
 164     "Generic word " write
 165     dup generic>> pprint
 166     " does not define a method for the " write
 167     dup object>> class pprint
 168     " class." print
 169     "Dispatching on object: " write object>> short. ;
 170
 171 M: bad-slot-value summary drop "Bad store to specialized slot" ;
 172
 173 M: no-math-method summary
 174     drop "No suitable arithmetic method" ;
 175
 176 M: no-next-method summary
 177     drop "Executing call-next-method from least-specific method" ;
 178
 179 M: inconsistent-next-method summary
 180     drop "Executing call-next-method with inconsistent parameters" ;
 181
 182 M: check-method summary
 183     drop "Invalid parameters for create-method" ;
 184
 185 M: not-a-tuple summary
 186     drop "Not a tuple" ;
 187
 188 M: bad-superclass summary
 189     drop "Tuple classes can only inherit from other tuple classes" ;
 190
 191 M: no-initial-value summary
 192     drop "Initial value must be provided for slots specialized to this class" ;
 193
 194 M: bad-initial-value summary
 195     drop "Incompatible initial value" ;
 196
 197 M: no-cond summary
 198     drop "Fall-through in cond" ;
 199
 200 M: no-case summary
 201     drop "Fall-through in case" ;
 202
 203 M: slice-error summary
 204     drop "Cannot create slice" ;
 205
 206 M: bounds-error summary drop "Sequence index out of bounds" ;
 207
 208 M: condition error. error>> error. ;
 209
 210 M: condition summary error>> summary ;
 211
 212 M: condition error-help error>> error-help ;
 213
 214 M: assert summary drop "Assertion failed" ;
 215
 216 M: assert-sequence summary drop "Assertion failed" ;
 217
 218 M: assert-sequence error.
 219     standard-table-style [
 220         [ "=== Expected:" print expected>> stack. ]
 221         [ "=== Got:" print got>> stack. ] bi
 222     ] tabular-output ;
 223
 224 M: immutable summary drop "Sequence is immutable" ;
 225
 226 M: redefine-error error.
 227     "Re-definition of " write
 228     def>> . ;
 229
 230 M: undefined summary
 231     drop "Calling a deferred word before it has been defined" ;
 232
 233 M: no-compilation-unit error.
 234     "Attempting to define " write
 235     definition>> pprint
 236     " outside of a compilation unit" print ;
 237
 238 M: no-vocab summary
 239     drop "Vocabulary does not exist" ;
 240
 241 M: encode-error summary drop "Character encoding error" ;
 242
 243 M: decode-error summary drop "Character decoding error" ;
 244
 245 M: bad-create summary drop "Bad parameters to create" ;
 246
 247 M: attempt-all-error summary drop "Nothing to attempt" ;
 248
 249 M: already-disposed summary drop "Attempting to operate on disposed object" ;
 250
 251 M: no-current-vocab summary
 252     drop "Not in a vocabulary; IN: form required" ;
 253
 254 M: no-word-error summary
 255     name>>
 256     "No word named ``"
 257     "'' found in current vocabulary search path" surround ;
 258
 259 M: no-word-error error. summary print ;
 260
 261 M: no-word-in-vocab summary
 262     [ vocab>> ] [ word>> ] bi
 263     [ "No word named ``" % % "'' found in ``" % % "'' vocabulary" % ] "" make ;
 264
 265 M: no-word-in-vocab error. summary print ;
 266
 267 M: ambiguous-use-error summary
 268     words>> first name>>
 269     "More than one vocabulary defines a word named ``" "''" surround ;
 270
 271 M: ambiguous-use-error error. summary print ;
 272
 273 M: staging-violation summary
 274     drop
 275     "A parsing word cannot be used in the same file it is defined in." ;
 276
 277 M: bad-number summary
 278     drop "Bad number literal" ;
 279
 280 M: duplicate-slot-names summary
 281     drop "Duplicate slot names" ;
 282
 283 M: invalid-slot-name summary
 284     drop "Invalid slot name" ;
 285
 286 M: not-in-a-method-error summary
 287     drop "call-next-method can only be called in a method definition" ;
 288
 289 GENERIC: expected>string ( obj -- str )
 290
 291 M: f expected>string drop "end of input" ;
 292 M: word expected>string name>> ;
 293 M: string expected>string ;
 294
 295 M: unexpected error.
 296     "Expected " write
 297     dup want>> expected>string write
 298     " but got " write
 299     got>> expected>string print ;
 300
 301 M: lexer-error error.
 302     [ lexer-dump ] [ error>> error. ] bi ;
 303
 304 M: lexer-error summary
 305     error>> summary ;
 306
 307 M: lexer-error compute-restarts
 308     error>> compute-restarts ;
 309
 310 M: lexer-error error-help
 311     error>> error-help ;
 312
 313 M: bad-effect summary
 314     drop "Bad stack effect declaration" ;
 315
 316 M: bad-escape summary drop "Bad escape code" ;
 317
 318 M: bad-literal-tuple summary drop "Bad literal tuple" ;
 319
 320 M: check-mixin-class summary drop "Not a mixin class" ;
 321
 322 M: not-found-in-roots summary drop "Cannot resolve vocab: path" ;
 323
 324 M: wrong-values summary drop "Quotation called with wrong stack effect" ;
 325
 326 {
 327     { [ os windows? ] [ "debugger.windows" require ] }
 328     { [ os unix? ] [ "debugger.unix" require ] }
 329 } cond