basis/farkup/farkup.factor

   1 ! Copyright (C) 2008, 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: sequences kernel splitting lists fry accessors assocs math.order
   4 math combinators namespaces urls.encoding xml.syntax xmode.code2html
   5 xml.data arrays strings vectors xml.writer io.streams.string locals
   6 unicode.categories ;
   7 FROM: namespaces => set ;
   8 IN: farkup
   9
  10 SYMBOL: relative-link-prefix
  11 SYMBOL: disable-images?
  12 SYMBOL: link-no-follow?
  13 SYMBOL: line-breaks?
  14
  15 TUPLE: heading1 child ;
  16 TUPLE: heading2 child ;
  17 TUPLE: heading3 child ;
  18 TUPLE: heading4 child ;
  19 TUPLE: strong child ;
  20 TUPLE: emphasis child ;
  21 TUPLE: superscript child ;
  22 TUPLE: subscript child ;
  23 TUPLE: inline-code child ;
  24 TUPLE: paragraph child ;
  25 TUPLE: list-item child ;
  26 TUPLE: unordered-list child ;
  27 TUPLE: ordered-list child ;
  28 TUPLE: table child ;
  29 TUPLE: table-row child ;
  30 TUPLE: link href text ;
  31 TUPLE: image href text ;
  32 TUPLE: code mode string ;
  33 TUPLE: line ;
  34 TUPLE: line-break ;
  35
  36 : absolute-url? ( string -- ? )
  37     { "http://" "https://" "ftp://" } [ head? ] with any? ;
  38
  39 : simple-link-title ( string -- string' )
  40     dup absolute-url? [ "/" split1-last swap or ] unless ;
  41
  42 ! _foo*bar_baz*bing works like <i>foo*bar</i>baz<b>bing</b>
  43 ! I could support overlapping, but there's not a good use case for it.
  44
  45 DEFER: (parse-paragraph)
  46
  47 : parse-paragraph ( string -- seq )
  48     (parse-paragraph) list>array ;
  49
  50 : make-paragraph ( string -- paragraph )
  51     parse-paragraph paragraph boa ;
  52
  53 : cut-half-slice ( string i -- before after-slice )
  54     [ head ] [ 1 + short tail-slice ] 2bi ;
  55
  56 : find-cut ( string quot -- before after delimiter )
  57     dupd find
  58     [ [ cut-half-slice ] [ f ] if* ] dip ; inline
  59
  60 : parse-delimiter ( string delimiter class -- paragraph )
  61     [ '[ _ = ] find-cut drop ] dip
  62     '[ parse-paragraph _ new swap >>child ]
  63     [ (parse-paragraph) ] bi* cons ;
  64
  65 : delimiter-class ( delimiter -- class )
  66     H{
  67         { CHAR: * strong }
  68         { CHAR: _ emphasis }
  69         { CHAR: ^ superscript }
  70         { CHAR: ~ subscript }
  71         { CHAR: % inline-code }
  72     } at ;
  73
  74 : or-simple-title ( ... url title/f quot: ( ... title -- ... title' ) -- ... url title' )
  75     [ "" like dup simple-link-title ] if* ; inline
  76
  77 : parse-link ( string -- paragraph-list )
  78     rest-slice "]]" split1-slice [
  79         "|" split1
  80         [ "image:" ?head ] dip swap
  81         [ [ ] or-simple-title image boa ]
  82         [ [ parse-paragraph ] or-simple-title link boa ] if
  83     ] dip [ (parse-paragraph) cons ] [ 1list ] if* ;
  84
  85 : parse-big-link ( before after -- link rest )
  86     dup ?first CHAR: [ =
  87     [ parse-link ]
  88     [ [ CHAR: [ suffix ] [ (parse-paragraph) ] bi* ]
  89     if ;
  90
  91 : escape ( before after -- before' after' )
  92     [ nil ] [ unclip-slice swap [ suffix ] dip (parse-paragraph) ] if-empty ;
  93
  94 : (parse-paragraph) ( string -- list )
  95     [ nil ] [
  96         [ "*_^~%[\\" member? ] find-cut [
  97             {
  98                 { CHAR: [ [ parse-big-link ] }
  99                 { CHAR: \\ [ escape ] }
 100                 [ dup delimiter-class parse-delimiter ]
 101             } case cons
 102         ] [ drop "" like 1list ] if*
 103     ] if-empty ;
 104
 105 : look ( state i -- char ) swap first ?nth ;
 106
 107 : take-lines ( state char -- state' lines )
 108     dupd '[ ?first _ = not ] find drop
 109     [ cut-slice ] [ f ] if* swap ;
 110
 111 :: (take-until) ( state delimiter accum -- string/f state' )
 112     state empty? [ accum "\n" join f ] [
 113         state unclip-slice :> ( rest first )
 114         first delimiter split1 :> ( before after )
 115         before accum push
 116         after [
 117             accum "\n" join
 118             rest after prefix
 119         ] [
 120             rest delimiter accum (take-until)
 121         ] if
 122     ] if ;
 123
 124 : take-until ( state delimiter -- string state'/f )
 125     V{ } clone (take-until) ;
 126
 127 : count= ( string -- n )
 128     dup <reversed> [ [ CHAR: = = not ] find drop 0 or ] bi@ min ;
 129
 130 : trim= ( string -- string' )
 131     [ CHAR: = = ] trim ;
 132
 133 : make-heading ( string class -- heading )
 134     [ trim= parse-paragraph ] dip boa ; inline
 135
 136 : parse-heading ( state -- state' heading )
 137     unclip-slice dup count= {
 138         { 0 [ make-paragraph ] }
 139         { 1 [ heading1 make-heading ] }
 140         { 2 [ heading2 make-heading ] }
 141         { 3 [ heading3 make-heading ] }
 142         { 4 [ heading4 make-heading ] }
 143         [ drop heading4 make-heading ]
 144     } case ;
 145
 146 : trim-row ( seq -- seq' )
 147     rest
 148     dup last empty? [ but-last ] when ;
 149
 150 : coalesce ( rows -- rows' )
 151     V{ } clone [
 152         '[
 153             _ dup ?last ?last CHAR: \\ =
 154             [ [ pop "|" rot 3append ] keep ] when
 155             push
 156         ] each
 157     ] keep ;
 158
 159 : parse-table ( state -- state' table )
 160     CHAR: | take-lines [
 161         "|" split
 162         trim-row
 163         coalesce
 164         [ parse-paragraph ] map
 165         table-row boa
 166     ] map table boa ;
 167
 168 : parse-line ( state -- state' item )
 169     unclip-slice dup "___" =
 170     [ drop line new ] [ make-paragraph ] if ;
 171
 172 : parse-list ( state char class -- state' list )
 173     [
 174         take-lines
 175         [ rest parse-paragraph list-item boa ] map
 176     ] dip boa ; inline
 177
 178 : parse-ul ( state -- state' ul )
 179     CHAR: - unordered-list parse-list ;
 180
 181 : parse-ol ( state -- state' ul )
 182     CHAR: # ordered-list parse-list ;
 183
 184 : parse-code ( state -- state' item )
 185     dup 1 look CHAR: [ =
 186     [ unclip-slice make-paragraph ] [
 187         dup "{" take-until [
 188             [ nip rest ] dip
 189             "}]" take-until
 190             [ code boa ] dip swap
 191         ] [ drop unclip-slice make-paragraph ] if*
 192     ] if ;
 193
 194 : parse-item ( state -- state' item )
 195     dup 0 look {
 196         { CHAR: = [ parse-heading ] }
 197         { CHAR: | [ parse-table ] }
 198         { CHAR: _ [ parse-line ] }
 199         { CHAR: - [ parse-ul ] }
 200         { CHAR: # [ parse-ol ] }
 201         { CHAR: [ [ parse-code ] }
 202         { f [ rest-slice f ] }
 203         [ drop unclip-slice make-paragraph ]
 204     } case ;
 205
 206 : parse-farkup ( string -- farkup )
 207     string-lines [ dup empty? not ] [ parse-item ] produce nip sift ;
 208
 209 CONSTANT: invalid-url "javascript:alert('Invalid URL in farkup');"
 210
 211 : check-url ( href -- href' )
 212     {
 213         { [ dup empty? ] [ drop invalid-url ] }
 214         { [ dup [ 127 > ] any? ] [ drop invalid-url ] }
 215         { [ dup first "/\\" member? ] [ drop invalid-url ] }
 216         { [ CHAR: : over member? ] [ dup absolute-url? [ drop invalid-url ] unless ] }
 217         [ relative-link-prefix get prepend "" like url-encode ]
 218     } cond ;
 219
 220 : render-code ( string mode -- xml )
 221     [ string-lines ] dip htmlize-lines
 222     [XML <pre><-></pre> XML] ;
 223
 224 GENERIC: (write-farkup) ( farkup -- xml )
 225
 226 : farkup-inside ( farkup name -- xml )
 227     <simple-name> swap T{ attrs } swap
 228     child>> (write-farkup) 1array <tag> ;
 229
 230 M: heading1 (write-farkup) "h1" farkup-inside ;
 231 M: heading2 (write-farkup) "h2" farkup-inside ;
 232 M: heading3 (write-farkup) "h3" farkup-inside ;
 233 M: heading4 (write-farkup) "h4" farkup-inside ;
 234 M: strong (write-farkup) "strong" farkup-inside ;
 235 M: emphasis (write-farkup) "em" farkup-inside ;
 236 M: superscript (write-farkup) "sup" farkup-inside ;
 237 M: subscript (write-farkup) "sub" farkup-inside ;
 238 M: inline-code (write-farkup) "code" farkup-inside ;
 239 M: list-item (write-farkup) "li" farkup-inside ;
 240 M: unordered-list (write-farkup) "ul" farkup-inside ;
 241 M: ordered-list (write-farkup) "ol" farkup-inside ;
 242 M: paragraph (write-farkup) "p" farkup-inside ;
 243 M: table (write-farkup) "table" farkup-inside ;
 244
 245 : write-link ( href text -- xml )
 246     [ check-url link-no-follow? get "nofollow" and ] dip
 247     [XML <a href=<-> rel=<->><-></a> XML] ;
 248
 249 : write-image-link ( href text -- xml )
 250     disable-images? get [
 251         2drop
 252         [XML <strong>Images are not allowed</strong> XML]
 253     ] [
 254         [ check-url ] [ f like ] bi*
 255         [XML <img src=<-> alt=<->/> XML]
 256     ] if ;
 257
 258 : open-link ( link -- href text )
 259     [ href>> ] [ text>> (write-farkup) ] bi ;
 260
 261 M: link (write-farkup)
 262     open-link write-link ;
 263
 264 M: image (write-farkup)
 265     open-link write-image-link ;
 266
 267 M: code (write-farkup)
 268     [ string>> ] [ mode>> ] bi render-code ;
 269
 270 M: line (write-farkup)
 271     drop [XML <hr/> XML] ;
 272
 273 M: line-break (write-farkup)
 274     drop [XML <br/> XML] ;
 275
 276 M: table-row (write-farkup)
 277     child>>
 278     [ (write-farkup) [XML <td><-></td> XML] ] map
 279     [XML <tr><-></tr> XML] ;
 280
 281 M: string (write-farkup) ;
 282
 283 M: array (write-farkup) [ (write-farkup) ] map ;
 284
 285 : farkup>xml ( string -- xml )
 286     parse-farkup (write-farkup) ;
 287
 288 : write-farkup ( string -- )
 289     farkup>xml write-xml ;
 290
 291 : convert-farkup ( string -- string' )
 292     [ write-farkup ] with-string-writer ;