basis/formatting/formatting.factor

   1 ! Copyright (C) 2008 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: accessors arrays assocs calendar combinators
   4 combinators.smart fry generalizations io io.streams.string
   5 kernel macros math math.functions math.parser namespaces
   6 peg.ebnf present prettyprint quotations sequences strings
   7 unicode.case unicode.categories vectors ;
   8 FROM: math.parser.private => format-float ;
   9 IN: formatting
  10
  11 <PRIVATE
  12
  13 : compose-all ( seq -- quot )
  14     [ ] [ compose ] reduce ; inline
  15
  16 : fix-sign ( string -- string )
  17     dup CHAR: 0 swap index 0 =
  18       [ dup 0 swap [ [ CHAR: 0 = not ] keep digit? and ] find-from
  19          [ dup 1 - rot dup [ nth ] dip swap
  20             {
  21                { CHAR: - [ [ 1 - ] dip remove-nth "-" prepend ] }
  22                { CHAR: + [ [ 1 - ] dip remove-nth "+" prepend ] }
  23                [ drop swap drop ]
  24             } case
  25          ] [ drop ] if
  26       ] when ;
  27
  28 : >digits ( string -- digits )
  29     [ 0 ] [ string>number ] if-empty ;
  30
  31 : format-simple ( x digits string -- string )
  32     [ [ >float ] [ number>string ] bi* "%." ] dip
  33     surround format-float ;
  34
  35 : format-scientific ( x digits -- string ) "e" format-simple ;
  36
  37 : format-decimal ( x digits -- string ) "f" format-simple ;
  38
  39 ERROR: unknown-printf-directive ;
  40
  41 EBNF: parse-printf
  42
  43 zero      = "0"                  => [[ CHAR: 0 ]]
  44 char      = "'" (.)              => [[ second ]]
  45
  46 pad-char  = (zero|char)?         => [[ CHAR: \s or ]]
  47 pad-align = ("-")?               => [[ \ pad-tail \ pad-head ? ]]
  48 pad-width = ([0-9])*             => [[ >digits ]]
  49 pad       = pad-align pad-char pad-width => [[ <reversed> >quotation dup first 0 = [ drop [ ] ] when ]]
  50
  51 sign      = ("+")?               => [[ [ dup CHAR: - swap index [ "+" prepend ] unless ] [ ] ? ]]
  52
  53 width_    = "." ([0-9])*         => [[ second >digits '[ _ short head ] ]]
  54 width     = (width_)?            => [[ [ ] or ]]
  55
  56 digits_   = "." ([0-9])*         => [[ second >digits ]]
  57 digits    = (digits_)?           => [[ 6 or ]]
  58
  59 fmt-%     = "%"                  => [[ "%" ]]
  60 fmt-c     = "c"                  => [[ [ 1string ] ]]
  61 fmt-C     = "C"                  => [[ [ 1string >upper ] ]]
  62 fmt-s     = "s"                  => [[ [ present ] ]]
  63 fmt-S     = "S"                  => [[ [ present >upper ] ]]
  64 fmt-u     = "u"                  => [[ [ unparse ] ]]
  65 fmt-d     = "d"                  => [[ [ >integer number>string ] ]]
  66 fmt-e     = digits "e"           => [[ first '[ _ format-scientific ] ]]
  67 fmt-E     = digits "E"           => [[ first '[ _ format-scientific >upper ] ]]
  68 fmt-f     = digits "f"           => [[ first '[ _ format-decimal ] ]]
  69 fmt-x     = "x"                  => [[ [ >hex ] ]]
  70 fmt-X     = "X"                  => [[ [ >hex >upper ] ]]
  71 unknown   = (.)*                 => [[ unknown-printf-directive ]]
  72
  73 strings_  = fmt-c|fmt-C|fmt-s|fmt-S|fmt-u
  74 strings   = pad width strings_   => [[ <reversed> compose-all ]]
  75
  76 numbers_  = fmt-d|fmt-e|fmt-E|fmt-f|fmt-x|fmt-X
  77 numbers   = sign pad numbers_    => [[ unclip-last prefix compose-all [ fix-sign ] append ]]
  78
  79 types     = strings|numbers
  80
  81 lists     = "[%" types ", %]"    => [[ second '[ _ map ", " join "{ " prepend " }" append ] ]]
  82
  83 assocs    = "[%" types ": %" types " %]" => [[ [ second ] [ fourth ] bi '[ unzip [ _ map ] dip _ map zip [ ":" join ] map ", " join "{ " prepend " }" append ] ]]
  84
  85 formats   = "%" (types|fmt-%|lists|assocs|unknown) => [[ second ]]
  86
  87 plain-text = (!("%").)+          => [[ >string ]]
  88
  89 text      = (formats|plain-text)* => [[ ]]
  90
  91 ;EBNF
  92
  93 PRIVATE>
  94
  95 MACRO: printf ( format-string -- )
  96     parse-printf [ [ callable? ] count ] keep [
  97         dup string? [ 1quotation ] [ [ 1 - ] dip ] if
  98         over [ ndip ] 2curry
  99     ] map nip [ compose-all ] [ length ] bi '[
 100         @ output-stream get [ stream-write ] curry _ napply
 101     ] ;
 102
 103 : sprintf ( format-string -- result )
 104     [ printf ] with-string-writer ; inline
 105
 106 : vprintf ( seq format-string -- )
 107     parse-printf output-stream get '[
 108         dup string? [
 109             [ unclip-slice ] dip call( x -- y )
 110         ] unless _ stream-write
 111     ] each drop ;
 112
 113 : vsprintf ( seq format-string -- result )
 114     [ vprintf ] with-string-writer ; inline
 115
 116 <PRIVATE
 117
 118 : pad-00 ( n -- string ) number>string 2 CHAR: 0 pad-head ; inline
 119
 120 : pad-000 ( n -- string ) number>string 3 CHAR: 0 pad-head ; inline
 121
 122 : >time ( timestamp -- string )
 123     [ hour>> ] [ minute>> ] [ second>> floor ] tri 3array
 124     [ pad-00 ] map ":" join ; inline
 125
 126 : >date ( timestamp -- string )
 127     [ month>> ] [ day>> ] [ year>> ] tri 3array
 128     [ pad-00 ] map "/" join ; inline
 129
 130 : >datetime ( timestamp -- string )
 131     [
 132        {
 133           [ day-of-week day-abbreviation3 ]
 134           [ month>> month-abbreviation ]
 135           [ day>> pad-00 ]
 136           [ >time ]
 137           [ year>> number>string ]
 138        } cleave
 139     ] output>array " " join ; inline
 140
 141 : (week-of-year) ( timestamp day -- n )
 142     [ dup clone 1 >>month 1 >>day day-of-week dup ] dip > [ 7 swap - ] when
 143     [ day-of-year ] dip 2dup < [ 0 2nip ] [ - 7 / 1 + >fixnum ] if ;
 144
 145 : week-of-year-sunday ( timestamp -- n ) 0 (week-of-year) ; inline
 146
 147 : week-of-year-monday ( timestamp -- n ) 1 (week-of-year) ; inline
 148
 149 EBNF: parse-strftime
 150
 151 fmt-%     = "%"                  => [[ "%" ]]
 152 fmt-a     = "a"                  => [[ [ day-of-week day-abbreviation3 ] ]]
 153 fmt-A     = "A"                  => [[ [ day-of-week day-name ] ]]
 154 fmt-b     = "b"                  => [[ [ month>> month-abbreviation ] ]]
 155 fmt-B     = "B"                  => [[ [ month>> month-name ] ]]
 156 fmt-c     = "c"                  => [[ [ >datetime ] ]]
 157 fmt-d     = "d"                  => [[ [ day>> pad-00 ] ]]
 158 fmt-H     = "H"                  => [[ [ hour>> pad-00 ] ]]
 159 fmt-I     = "I"                  => [[ [ hour>> dup 12 > [ 12 - ] when pad-00 ] ]]
 160 fmt-j     = "j"                  => [[ [ day-of-year pad-000 ] ]]
 161 fmt-m     = "m"                  => [[ [ month>> pad-00 ] ]]
 162 fmt-M     = "M"                  => [[ [ minute>> pad-00 ] ]]
 163 fmt-p     = "p"                  => [[ [ hour>> 12 < "AM" "PM" ? ] ]]
 164 fmt-S     = "S"                  => [[ [ second>> floor pad-00 ] ]]
 165 fmt-U     = "U"                  => [[ [ week-of-year-sunday pad-00 ] ]]
 166 fmt-w     = "w"                  => [[ [ day-of-week number>string ] ]]
 167 fmt-W     = "W"                  => [[ [ week-of-year-monday pad-00 ] ]]
 168 fmt-x     = "x"                  => [[ [ >date ] ]]
 169 fmt-X     = "X"                  => [[ [ >time ] ]]
 170 fmt-y     = "y"                  => [[ [ year>> 100 mod pad-00 ] ]]
 171 fmt-Y     = "Y"                  => [[ [ year>> number>string ] ]]
 172 fmt-Z     = "Z"                  => [[ [ "Not yet implemented" throw ] ]]
 173 unknown   = (.)*                 => [[ "Unknown directive" throw ]]
 174
 175 formats_  = fmt-%|fmt-a|fmt-A|fmt-b|fmt-B|fmt-c|fmt-d|fmt-H|fmt-I|
 176             fmt-j|fmt-m|fmt-M|fmt-p|fmt-S|fmt-U|fmt-w|fmt-W|fmt-x|
 177             fmt-X|fmt-y|fmt-Y|fmt-Z|unknown
 178
 179 formats   = "%" (formats_)       => [[ second ]]
 180
 181 plain-text = (!("%").)+          => [[ >string ]]
 182
 183 text      = (formats|plain-text)* => [[ ]]
 184
 185 ;EBNF
 186
 187 PRIVATE>
 188
 189 MACRO: strftime ( format-string -- )
 190     parse-strftime [
 191         dup string? [
 192             '[ _ swap push-all ]
 193         ] [
 194             '[ over @ swap push-all ]
 195         ] if
 196     ] map '[
 197         SBUF" " clone [ _ cleave drop ] keep "" like
 198     ] ;