basis/formatting/formatting.factor

   1 ! Copyright (C) 2008 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: accessors arrays assocs calendar combinators fry kernel
   4 generalizations io io.streams.string macros math math.functions
   5 math.parser peg.ebnf quotations sequences splitting strings
   6 unicode.categories unicode.case vectors combinators.smart
   7 present ;
   8 FROM: math.parser.private => format-float ;
   9 IN: formatting
  10
  11 <PRIVATE
  12
  13 : compose-all ( seq -- quot )
  14     [ ] [ compose ] reduce ; inline
  15
  16 : fix-sign ( string -- string )
  17     dup CHAR: 0 swap index 0 =
  18       [ dup 0 swap [ [ CHAR: 0 = not ] keep digit? and ] find-from
  19          [ dup 1 - rot dup [ nth ] dip swap
  20             {
  21                { CHAR: - [ [ 1 - ] dip remove-nth "-" prepend ] }
  22                { CHAR: + [ [ 1 - ] dip remove-nth "+" prepend ] }
  23                [ drop swap drop ]
  24             } case
  25          ] [ drop ] if
  26       ] when ;
  27
  28 : >digits ( string -- digits )
  29     [ 0 ] [ string>number ] if-empty ;
  30
  31 : format-simple ( x digits string -- string )
  32     [ [ >float ] [ number>string ] bi* "%." ] dip
  33     surround format-float ;
  34
  35 : format-scientific ( x digits -- string ) "e" format-simple ;
  36
  37 : format-decimal ( x digits -- string ) "f" format-simple ;
  38
  39 ERROR: unknown-printf-directive ;
  40
  41 EBNF: parse-printf
  42
  43 zero      = "0"                  => [[ CHAR: 0 ]]
  44 char      = "'" (.)              => [[ second ]]
  45
  46 pad-char  = (zero|char)?         => [[ CHAR: \s or ]]
  47 pad-align = ("-")?               => [[ \ pad-tail \ pad-head ? ]]
  48 pad-width = ([0-9])*             => [[ >digits ]]
  49 pad       = pad-align pad-char pad-width => [[ <reversed> >quotation dup first 0 = [ drop [ ] ] when ]]
  50
  51 sign      = ("+")?               => [[ [ dup CHAR: - swap index [ "+" prepend ] unless ] [ ] ? ]]
  52
  53 width_    = "." ([0-9])*         => [[ second >digits '[ _ short head ] ]]
  54 width     = (width_)?            => [[ [ ] or ]]
  55
  56 digits_   = "." ([0-9])*         => [[ second >digits ]]
  57 digits    = (digits_)?           => [[ 6 or ]]
  58
  59 fmt-%     = "%"                  => [[ [ "%" ] ]]
  60 fmt-c     = "c"                  => [[ [ 1string ] ]]
  61 fmt-C     = "C"                  => [[ [ 1string >upper ] ]]
  62 fmt-s     = "s"                  => [[ [ present ] ]]
  63 fmt-S     = "S"                  => [[ [ present >upper ] ]]
  64 fmt-d     = "d"                  => [[ [ >integer number>string ] ]]
  65 fmt-e     = digits "e"           => [[ first '[ _ format-scientific ] ]]
  66 fmt-E     = digits "E"           => [[ first '[ _ format-scientific >upper ] ]]
  67 fmt-f     = digits "f"           => [[ first '[ _ format-decimal ] ]]
  68 fmt-x     = "x"                  => [[ [ >hex ] ]]
  69 fmt-X     = "X"                  => [[ [ >hex >upper ] ]]
  70 unknown   = (.)*                 => [[ unknown-printf-directive ]]
  71
  72 strings_  = fmt-c|fmt-C|fmt-s|fmt-S
  73 strings   = pad width strings_   => [[ <reversed> compose-all ]]
  74
  75 numbers_  = fmt-d|fmt-e|fmt-E|fmt-f|fmt-x|fmt-X
  76 numbers   = sign pad numbers_    => [[ unclip-last prefix compose-all [ fix-sign ] append ]]
  77
  78 types     = strings|numbers
  79
  80 lists     = "[%" types ", %]"    => [[ second '[ _ map ", " join "{ " prepend " }" append ] ]]
  81
  82 assocs    = "[%" types ": %" types " %]" => [[ [ second ] [ fourth ] bi '[ unzip [ _ map ] dip _ map zip [ ":" join ] map ", " join "{ " prepend " }" append ] ]]
  83
  84 formats   = "%" (types|fmt-%|lists|assocs|unknown) => [[ second '[ _ dip ] ]]
  85
  86 plain-text = (!("%").)+          => [[ >string '[ _ swap ] ]]
  87
  88 text      = (formats|plain-text)* => [[ <reversed> [ [ [ push ] keep ] append ] map ]]
  89
  90 ;EBNF
  91
  92 PRIVATE>
  93
  94 MACRO: printf ( format-string -- )
  95     parse-printf [ length ] keep compose-all
  96     '[ _ <vector> @ <reversed> [ write ] each ] ;
  97
  98 : sprintf ( format-string -- result )
  99     [ printf ] with-string-writer ; inline
 100
 101 : vprintf ( seq format-string -- )
 102     parse-printf reverse! [
 103         first dup string?
 104         [ '[ _ write ] ] [ '[ unclip-slice @ write ] ] if
 105     ] map concat call( x -- x ) drop ;
 106
 107 : vsprintf ( seq format-string -- result )
 108     [ vprintf ] with-string-writer ; inline
 109
 110 <PRIVATE
 111
 112 : pad-00 ( n -- string ) number>string 2 CHAR: 0 pad-head ; inline
 113
 114 : pad-000 ( n -- string ) number>string 3 CHAR: 0 pad-head ; inline
 115
 116 : >time ( timestamp -- string )
 117     [ hour>> ] [ minute>> ] [ second>> floor ] tri 3array
 118     [ pad-00 ] map ":" join ; inline
 119
 120 : >date ( timestamp -- string )
 121     [ month>> ] [ day>> ] [ year>> ] tri 3array
 122     [ pad-00 ] map "/" join ; inline
 123
 124 : >datetime ( timestamp -- string )
 125     [
 126        {
 127           [ day-of-week day-abbreviation3 ]
 128           [ month>> month-abbreviation ]
 129           [ day>> pad-00 ]
 130           [ >time ]
 131           [ year>> number>string ]
 132        } cleave
 133     ] output>array " " join ; inline
 134
 135 : (week-of-year) ( timestamp day -- n )
 136     [ dup clone 1 >>month 1 >>day day-of-week dup ] dip > [ 7 swap - ] when
 137     [ day-of-year ] dip 2dup < [ 0 2nip ] [ - 7 / 1 + >fixnum ] if ;
 138
 139 : week-of-year-sunday ( timestamp -- n ) 0 (week-of-year) ; inline
 140
 141 : week-of-year-monday ( timestamp -- n ) 1 (week-of-year) ; inline
 142
 143 EBNF: parse-strftime
 144
 145 fmt-%     = "%"                  => [[ [ "%" ] ]]
 146 fmt-a     = "a"                  => [[ [ dup day-of-week day-abbreviation3 ] ]]
 147 fmt-A     = "A"                  => [[ [ dup day-of-week day-name ] ]]
 148 fmt-b     = "b"                  => [[ [ dup month>> month-abbreviation ] ]]
 149 fmt-B     = "B"                  => [[ [ dup month>> month-name ] ]]
 150 fmt-c     = "c"                  => [[ [ dup >datetime ] ]]
 151 fmt-d     = "d"                  => [[ [ dup day>> pad-00 ] ]]
 152 fmt-H     = "H"                  => [[ [ dup hour>> pad-00 ] ]]
 153 fmt-I     = "I"                  => [[ [ dup hour>> dup 12 > [ 12 - ] when pad-00 ] ]]
 154 fmt-j     = "j"                  => [[ [ dup day-of-year pad-000 ] ]]
 155 fmt-m     = "m"                  => [[ [ dup month>> pad-00 ] ]]
 156 fmt-M     = "M"                  => [[ [ dup minute>> pad-00 ] ]]
 157 fmt-p     = "p"                  => [[ [ dup hour>> 12 < "AM" "PM" ? ] ]]
 158 fmt-S     = "S"                  => [[ [ dup second>> floor pad-00 ] ]]
 159 fmt-U     = "U"                  => [[ [ dup week-of-year-sunday pad-00 ] ]]
 160 fmt-w     = "w"                  => [[ [ dup day-of-week number>string ] ]]
 161 fmt-W     = "W"                  => [[ [ dup week-of-year-monday pad-00 ] ]]
 162 fmt-x     = "x"                  => [[ [ dup >date ] ]]
 163 fmt-X     = "X"                  => [[ [ dup >time ] ]]
 164 fmt-y     = "y"                  => [[ [ dup year>> 100 mod pad-00 ] ]]
 165 fmt-Y     = "Y"                  => [[ [ dup year>> number>string ] ]]
 166 fmt-Z     = "Z"                  => [[ [ "Not yet implemented" throw ] ]]
 167 unknown   = (.)*                 => [[ "Unknown directive" throw ]]
 168
 169 formats_  = fmt-%|fmt-a|fmt-A|fmt-b|fmt-B|fmt-c|fmt-d|fmt-H|fmt-I|
 170             fmt-j|fmt-m|fmt-M|fmt-p|fmt-S|fmt-U|fmt-w|fmt-W|fmt-x|
 171             fmt-X|fmt-y|fmt-Y|fmt-Z|unknown
 172
 173 formats   = "%" (formats_)       => [[ second '[ _ dip ] ]]
 174
 175 plain-text = (!("%").)+          => [[ >string '[ _ swap ] ]]
 176
 177 text      = (formats|plain-text)* => [[ reverse [ [ [ push ] keep ] append ] map ]]
 178
 179 ;EBNF
 180
 181 PRIVATE>
 182
 183 MACRO: strftime ( format-string -- )
 184     parse-strftime [ length ] keep [ ] join
 185     '[ _ <vector> @ reverse concat nip ] ;