basis/functors/functors.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.mixin classes.parser classes.singleton
   4 classes.tuple classes.tuple.parser combinators effects effects.parser
   5 fry generic generic.parser generic.standard interpolate
   6 io.streams.string kernel lexer locals.parser locals.rewrite.closures
   7 locals.types make namespaces parser quotations sequences vocabs.parser
   8 words words.symbol ;
   9 IN: functors
  10
  11 ! This is a hack
  12
  13 <PRIVATE
  14
  15 : scan-param ( -- obj ) scan-object literalize ;
  16
  17 : define* ( word def -- ) over set-word define ;
  18
  19 : define-declared* ( word def effect -- ) pick set-word define-declared ;
  20
  21 : define-simple-generic* ( word effect -- ) over set-word define-simple-generic ;
  22
  23 TUPLE: fake-call-next-method ;
  24
  25 TUPLE: fake-quotation seq ;
  26
  27 GENERIC: >fake-quotations ( quot -- fake )
  28
  29 M: callable >fake-quotations
  30     >array >fake-quotations fake-quotation boa ;
  31
  32 M: array >fake-quotations [ >fake-quotations ] { } map-as ;
  33
  34 M: object >fake-quotations ;
  35
  36 GENERIC: (fake-quotations>) ( fake -- )
  37
  38 : fake-quotations> ( fake -- quot )
  39     [ (fake-quotations>) ] [ ] make ;
  40
  41 M: fake-quotation (fake-quotations>)
  42     [ seq>> [ (fake-quotations>) ] each ] [ ] make , ;
  43
  44 M: array (fake-quotations>)
  45     [ [ (fake-quotations>) ] each ] { } make , ;
  46
  47 M: fake-call-next-method (fake-quotations>)
  48     drop method-body get literalize , \ (call-next-method) , ;
  49
  50 M: object (fake-quotations>) , ;
  51
  52 : parse-definition* ( accum -- accum )
  53     parse-definition >fake-quotations parsed
  54     [ fake-quotations> first ] over push-all ;
  55
  56 : parse-declared* ( accum -- accum )
  57     complete-effect
  58     [ parse-definition* ] dip
  59     parsed ;
  60
  61 SYNTAX: `TUPLE:
  62     scan-param parsed
  63     scan {
  64         { ";" [ tuple parsed f parsed ] }
  65         { "<" [ scan-param parsed [ parse-tuple-slots ] { } make parsed ] }
  66         [
  67             [ tuple parsed ] dip
  68             [ parse-slot-name [ parse-tuple-slots ] when ] { }
  69             make parsed
  70         ]
  71     } case
  72     \ define-tuple-class parsed ;
  73
  74 SYNTAX: `SINGLETON:
  75     scan-param parsed
  76     \ define-singleton-class parsed ;
  77
  78 SYNTAX: `MIXIN:
  79     scan-param parsed
  80     \ define-mixin-class parsed ;
  81
  82 SYNTAX: `M:
  83     scan-param parsed
  84     scan-param parsed
  85     [ create-method-in dup method-body set ] over push-all
  86     parse-definition*
  87     \ define* parsed ;
  88
  89 SYNTAX: `C:
  90     scan-param parsed
  91     scan-param parsed
  92     complete-effect
  93     [ [ [ boa ] curry ] over push-all ] dip parsed
  94     \ define-declared* parsed ;
  95
  96 SYNTAX: `:
  97     scan-param parsed
  98     parse-declared*
  99     \ define-declared* parsed ;
 100
 101 SYNTAX: `SYMBOL:
 102     scan-param parsed
 103     \ define-symbol parsed ;
 104
 105 SYNTAX: `SYNTAX:
 106     scan-param parsed
 107     parse-definition*
 108     \ define-syntax parsed ;
 109
 110 SYNTAX: `INSTANCE:
 111     scan-param parsed
 112     scan-param parsed
 113     \ add-mixin-instance parsed ;
 114
 115 SYNTAX: `GENERIC:
 116     scan-param parsed
 117     complete-effect parsed
 118     \ define-simple-generic* parsed ;
 119
 120 SYNTAX: `inline [ word make-inline ] over push-all ;
 121
 122 SYNTAX: `call-next-method T{ fake-call-next-method } parsed ;
 123
 124 : (INTERPOLATE) ( accum quot -- accum )
 125     [ scan interpolate-locals ] dip
 126     '[ _ with-string-writer @ ] parsed ;
 127
 128 PRIVATE>
 129
 130 SYNTAX: IS [ dup search [ ] [ no-word ] ?if ] (INTERPOLATE) ;
 131
 132 SYNTAX: DEFERS [ current-vocab create ] (INTERPOLATE) ;
 133
 134 SYNTAX: DEFINES [ create-in ] (INTERPOLATE) ;
 135
 136 SYNTAX: DEFINES-CLASS [ create-class-in ] (INTERPOLATE) ;
 137
 138 DEFER: ;FUNCTOR delimiter
 139
 140 <PRIVATE
 141
 142 : functor-words ( -- assoc )
 143     H{
 144         { "TUPLE:" POSTPONE: `TUPLE: }
 145         { "SINGLETON:" POSTPONE: `SINGLETON: }
 146         { "MIXIN:" POSTPONE: `MIXIN: }
 147         { "M:" POSTPONE: `M: }
 148         { "C:" POSTPONE: `C: }
 149         { ":" POSTPONE: `: }
 150         { "GENERIC:" POSTPONE: `GENERIC: }
 151         { "INSTANCE:" POSTPONE: `INSTANCE: }
 152         { "SYNTAX:" POSTPONE: `SYNTAX: }
 153         { "SYMBOL:" POSTPONE: `SYMBOL: }
 154         { "inline" POSTPONE: `inline }
 155         { "call-next-method" POSTPONE: `call-next-method }
 156     } ;
 157
 158 : push-functor-words ( -- )
 159     functor-words use-words ;
 160
 161 : pop-functor-words ( -- )
 162     functor-words unuse-words ;
 163
 164 : parse-functor-body ( -- form )
 165     push-functor-words
 166     "WHERE" parse-bindings*
 167     [ \ ;FUNCTOR parse-until >quotation ] ((parse-lambda)) <let*> 1quotation
 168     pop-functor-words ;
 169
 170 : (FUNCTOR:) ( -- word def effect )
 171     CREATE-WORD [ parse-functor-body ] parse-locals-definition ;
 172
 173 PRIVATE>
 174
 175 SYNTAX: FUNCTOR: (FUNCTOR:) define-declared ;