basis/functors/functors.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.mixin classes.parser
   4 classes.tuple classes.tuple.parser combinators effects
   5 effects.parser fry generic generic.parser generic.standard
   6 interpolate io.streams.string kernel lexer locals.parser
   7 locals.rewrite.closures locals.types make macros namespaces
   8 parser quotations sequences vocabs.parser words words.symbol ;
   9 IN: functors
  10
  11 ! This is a hack
  12
  13 <PRIVATE
  14
  15 : scan-param ( -- obj ) scan-object literalize ;
  16
  17 : define* ( word def -- ) over set-word define ;
  18
  19 : define-declared* ( word def effect -- ) pick set-word define-declared ;
  20
  21 : define-simple-generic* ( word effect -- ) over set-word define-simple-generic ;
  22
  23 TUPLE: fake-call-next-method ;
  24
  25 TUPLE: fake-quotation seq ;
  26
  27 GENERIC: >fake-quotations ( quot -- fake )
  28
  29 M: callable >fake-quotations
  30     >array >fake-quotations fake-quotation boa ;
  31
  32 M: array >fake-quotations [ >fake-quotations ] { } map-as ;
  33
  34 M: object >fake-quotations ;
  35
  36 GENERIC: (fake-quotations>) ( fake -- )
  37
  38 : fake-quotations> ( fake -- quot )
  39     [ (fake-quotations>) ] [ ] make ;
  40
  41 M: fake-quotation (fake-quotations>)
  42     [ seq>> [ (fake-quotations>) ] each ] [ ] make , ;
  43
  44 M: array (fake-quotations>)
  45     [ [ (fake-quotations>) ] each ] { } make , ;
  46
  47 M: fake-call-next-method (fake-quotations>)
  48     drop method-body get literalize , \ (call-next-method) , ;
  49
  50 M: object (fake-quotations>) , ;
  51
  52 : parse-definition* ( accum -- accum )
  53     parse-definition >fake-quotations parsed
  54     [ fake-quotations> first ] over push-all ;
  55
  56 : parse-declared* ( accum -- accum )
  57     complete-effect
  58     [ parse-definition* ] dip
  59     parsed ;
  60
  61 : DEFINE* ( accum -- accum ) \ define-declared* parsed ;
  62
  63 SYNTAX: `TUPLE:
  64     scan-param parsed
  65     scan {
  66         { ";" [ tuple parsed f parsed ] }
  67         { "<" [ scan-param parsed [ parse-tuple-slots ] { } make parsed ] }
  68         [
  69             [ tuple parsed ] dip
  70             [ parse-slot-name [ parse-tuple-slots ] when ] { }
  71             make parsed
  72         ]
  73     } case
  74     \ define-tuple-class parsed ;
  75
  76 SYNTAX: `M:
  77     scan-param parsed
  78     scan-param parsed
  79     [ create-method-in dup method-body set ] over push-all
  80     parse-definition*
  81     \ define* parsed ;
  82
  83 SYNTAX: `C:
  84     scan-param parsed
  85     scan-param parsed
  86     complete-effect
  87     [ [ [ boa ] curry ] over push-all ] dip parsed
  88     \ define-declared* parsed ;
  89
  90 SYNTAX: `:
  91     scan-param parsed
  92     parse-declared*
  93     \ define-declared* parsed ;
  94
  95 SYNTAX: `SYMBOL:
  96     scan-param parsed
  97     \ define-symbol parsed ;
  98
  99 SYNTAX: `SYNTAX:
 100     scan-param parsed
 101     parse-definition*
 102     \ define-syntax parsed ;
 103
 104 SYNTAX: `INSTANCE:
 105     scan-param parsed
 106     scan-param parsed
 107     \ add-mixin-instance parsed ;
 108
 109 SYNTAX: `GENERIC:
 110     scan-param parsed
 111     complete-effect parsed
 112     \ define-simple-generic* parsed ;
 113
 114 SYNTAX: `MACRO:
 115     scan-param parsed
 116     parse-declared*
 117     \ define-macro parsed ;
 118
 119 SYNTAX: `inline [ word make-inline ] over push-all ;
 120
 121 SYNTAX: `call-next-method T{ fake-call-next-method } parsed ;
 122
 123 : (INTERPOLATE) ( accum quot -- accum )
 124     [ scan interpolate-locals ] dip
 125     '[ _ with-string-writer @ ] parsed ;
 126
 127 PRIVATE>
 128
 129 SYNTAX: IS [ dup search [ ] [ no-word ] ?if ] (INTERPOLATE) ;
 130
 131 SYNTAX: DEFINES [ create-in ] (INTERPOLATE) ;
 132
 133 SYNTAX: DEFINES-CLASS [ create-class-in ] (INTERPOLATE) ;
 134
 135 DEFER: ;FUNCTOR delimiter
 136
 137 <PRIVATE
 138
 139 : functor-words ( -- assoc )
 140     H{
 141         { "TUPLE:" POSTPONE: `TUPLE: }
 142         { "M:" POSTPONE: `M: }
 143         { "C:" POSTPONE: `C: }
 144         { ":" POSTPONE: `: }
 145         { "GENERIC:" POSTPONE: `GENERIC: }
 146         { "INSTANCE:" POSTPONE: `INSTANCE: }
 147         { "SYNTAX:" POSTPONE: `SYNTAX: }
 148         { "SYMBOL:" POSTPONE: `SYMBOL: }
 149         { "inline" POSTPONE: `inline }
 150         { "MACRO:" POSTPONE: `MACRO: }
 151         { "call-next-method" POSTPONE: `call-next-method }
 152     } ;
 153
 154 : push-functor-words ( -- )
 155     functor-words use get push ;
 156
 157 : pop-functor-words ( -- )
 158     functor-words use get delq ;
 159
 160 : parse-functor-body ( -- form )
 161     push-functor-words
 162     "WHERE" parse-bindings*
 163     [ \ ;FUNCTOR parse-until >quotation ] ((parse-lambda)) <let*> 1quotation
 164     pop-functor-words ;
 165
 166 : (FUNCTOR:) ( -- word def effect )
 167     CREATE-WORD [ parse-functor-body ] parse-locals-definition ;
 168
 169 PRIVATE>
 170
 171 SYNTAX: FUNCTOR: (FUNCTOR:) define-declared ;