basis/functors/functors.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.mixin classes.parser
   4 classes.tuple classes.tuple.parser combinators effects
   5 effects.parser fry generic generic.parser generic.standard
   6 interpolate io.streams.string kernel lexer locals.parser
   7 locals.rewrite.closures locals.types make macros namespaces
   8 parser quotations sequences vocabs.parser words words.symbol ;
   9 IN: functors
  10
  11 ! This is a hack
  12
  13 <PRIVATE
  14
  15 : scan-param ( -- obj ) scan-object literalize ;
  16
  17 : define* ( word def -- ) over set-word define ;
  18
  19 : define-declared* ( word def effect -- ) pick set-word define-declared ;
  20
  21 : define-simple-generic* ( word effect -- ) over set-word define-simple-generic ;
  22
  23 TUPLE: fake-call-next-method ;
  24
  25 TUPLE: fake-quotation seq ;
  26
  27 GENERIC: >fake-quotations ( quot -- fake )
  28
  29 M: callable >fake-quotations
  30     >array >fake-quotations fake-quotation boa ;
  31
  32 M: array >fake-quotations [ >fake-quotations ] { } map-as ;
  33
  34 M: object >fake-quotations ;
  35
  36 GENERIC: (fake-quotations>) ( fake -- )
  37
  38 : fake-quotations> ( fake -- quot )
  39     [ (fake-quotations>) ] [ ] make ;
  40
  41 M: fake-quotation (fake-quotations>)
  42     [ seq>> [ (fake-quotations>) ] each ] [ ] make , ;
  43
  44 M: array (fake-quotations>)
  45     [ [ (fake-quotations>) ] each ] { } make , ;
  46
  47 M: fake-call-next-method (fake-quotations>)
  48     drop method-body get literalize , \ (call-next-method) , ;
  49
  50 M: object (fake-quotations>) , ;
  51
  52 : parse-definition* ( accum -- accum )
  53     parse-definition >fake-quotations parsed
  54     [ fake-quotations> first ] over push-all ;
  55
  56 : parse-declared* ( accum -- accum )
  57     complete-effect
  58     [ parse-definition* ] dip
  59     parsed ;
  60
  61 SYNTAX: `TUPLE:
  62     scan-param parsed
  63     scan {
  64         { ";" [ tuple parsed f parsed ] }
  65         { "<" [ scan-param parsed [ parse-tuple-slots ] { } make parsed ] }
  66         [
  67             [ tuple parsed ] dip
  68             [ parse-slot-name [ parse-tuple-slots ] when ] { }
  69             make parsed
  70         ]
  71     } case
  72     \ define-tuple-class parsed ;
  73
  74 SYNTAX: `M:
  75     scan-param parsed
  76     scan-param parsed
  77     [ create-method-in dup method-body set ] over push-all
  78     parse-definition*
  79     \ define* parsed ;
  80
  81 SYNTAX: `C:
  82     scan-param parsed
  83     scan-param parsed
  84     complete-effect
  85     [ [ [ boa ] curry ] over push-all ] dip parsed
  86     \ define-declared* parsed ;
  87
  88 SYNTAX: `:
  89     scan-param parsed
  90     parse-declared*
  91     \ define-declared* parsed ;
  92
  93 SYNTAX: `SYMBOL:
  94     scan-param parsed
  95     \ define-symbol parsed ;
  96
  97 SYNTAX: `SYNTAX:
  98     scan-param parsed
  99     parse-definition*
 100     \ define-syntax parsed ;
 101
 102 SYNTAX: `INSTANCE:
 103     scan-param parsed
 104     scan-param parsed
 105     \ add-mixin-instance parsed ;
 106
 107 SYNTAX: `GENERIC:
 108     scan-param parsed
 109     complete-effect parsed
 110     \ define-simple-generic* parsed ;
 111
 112 SYNTAX: `MACRO:
 113     scan-param parsed
 114     parse-declared*
 115     \ define-macro parsed ;
 116
 117 SYNTAX: `inline [ word make-inline ] over push-all ;
 118
 119 SYNTAX: `call-next-method T{ fake-call-next-method } parsed ;
 120
 121 : (INTERPOLATE) ( accum quot -- accum )
 122     [ scan interpolate-locals ] dip
 123     '[ _ with-string-writer @ ] parsed ;
 124
 125 PRIVATE>
 126
 127 SYNTAX: IS [ dup search [ ] [ no-word ] ?if ] (INTERPOLATE) ;
 128
 129 SYNTAX: DEFINES [ create-in ] (INTERPOLATE) ;
 130
 131 SYNTAX: DEFINES-CLASS [ create-class-in ] (INTERPOLATE) ;
 132
 133 DEFER: ;FUNCTOR delimiter
 134
 135 <PRIVATE
 136
 137 : functor-words ( -- assoc )
 138     H{
 139         { "TUPLE:" POSTPONE: `TUPLE: }
 140         { "M:" POSTPONE: `M: }
 141         { "C:" POSTPONE: `C: }
 142         { ":" POSTPONE: `: }
 143         { "GENERIC:" POSTPONE: `GENERIC: }
 144         { "INSTANCE:" POSTPONE: `INSTANCE: }
 145         { "SYNTAX:" POSTPONE: `SYNTAX: }
 146         { "SYMBOL:" POSTPONE: `SYMBOL: }
 147         { "inline" POSTPONE: `inline }
 148         { "MACRO:" POSTPONE: `MACRO: }
 149         { "call-next-method" POSTPONE: `call-next-method }
 150     } ;
 151
 152 : push-functor-words ( -- )
 153     functor-words use-words ;
 154
 155 : pop-functor-words ( -- )
 156     functor-words unuse-words ;
 157
 158 : parse-functor-body ( -- form )
 159     push-functor-words
 160     "WHERE" parse-bindings*
 161     [ \ ;FUNCTOR parse-until >quotation ] ((parse-lambda)) <let*> 1quotation
 162     pop-functor-words ;
 163
 164 : (FUNCTOR:) ( -- word def effect )
 165     CREATE-WORD [ parse-functor-body ] parse-locals-definition ;
 166
 167 PRIVATE>
 168
 169 SYNTAX: FUNCTOR: (FUNCTOR:) define-declared ;