basis/functors/functors.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.mixin classes.parser
   4 classes.tuple classes.tuple.parser combinators effects
   5 effects.parser fry generic generic.parser generic.standard
   6 interpolate io.streams.string kernel lexer locals.parser
   7 locals.rewrite.closures locals.types make namespaces parser
   8 quotations sequences vocabs.parser words words.symbol ;
   9 IN: functors
  10
  11 ! This is a hack
  12
  13 <PRIVATE
  14
  15 : scan-param ( -- obj ) scan-object literalize ;
  16
  17 : define* ( word def -- ) over set-word define ;
  18
  19 : define-declared* ( word def effect -- ) pick set-word define-declared ;
  20
  21 : define-simple-generic* ( word effect -- ) over set-word define-simple-generic ;
  22
  23 TUPLE: fake-call-next-method ;
  24
  25 TUPLE: fake-quotation seq ;
  26
  27 GENERIC: >fake-quotations ( quot -- fake )
  28
  29 M: callable >fake-quotations
  30     >array >fake-quotations fake-quotation boa ;
  31
  32 M: array >fake-quotations [ >fake-quotations ] { } map-as ;
  33
  34 M: object >fake-quotations ;
  35
  36 GENERIC: (fake-quotations>) ( fake -- )
  37
  38 : fake-quotations> ( fake -- quot )
  39     [ (fake-quotations>) ] [ ] make ;
  40
  41 M: fake-quotation (fake-quotations>)
  42     [ seq>> [ (fake-quotations>) ] each ] [ ] make , ;
  43
  44 M: array (fake-quotations>)
  45     [ [ (fake-quotations>) ] each ] { } make , ;
  46
  47 M: fake-call-next-method (fake-quotations>)
  48     drop method-body get literalize , \ (call-next-method) , ;
  49
  50 M: object (fake-quotations>) , ;
  51
  52 : parse-definition* ( accum -- accum )
  53     parse-definition >fake-quotations parsed
  54     [ fake-quotations> first ] over push-all ;
  55
  56 : parse-declared* ( accum -- accum )
  57     complete-effect
  58     [ parse-definition* ] dip
  59     parsed ;
  60
  61 : DEFINE* ( accum -- accum ) \ define-declared* parsed ;
  62
  63 SYNTAX: `TUPLE:
  64     scan-param parsed
  65     scan {
  66         { ";" [ tuple parsed f parsed ] }
  67         { "<" [ scan-param parsed [ parse-tuple-slots ] { } make parsed ] }
  68         [
  69             [ tuple parsed ] dip
  70             [ parse-slot-name [ parse-tuple-slots ] when ] { }
  71             make parsed
  72         ]
  73     } case
  74     \ define-tuple-class parsed ;
  75
  76 SYNTAX: `M:
  77     scan-param parsed
  78     scan-param parsed
  79     [ create-method-in dup method-body set ] over push-all
  80     parse-definition*
  81     \ define* parsed ;
  82
  83 SYNTAX: `C:
  84     scan-param parsed
  85     scan-param parsed
  86     complete-effect
  87     [ [ [ boa ] curry ] over push-all ] dip parsed
  88     \ define-declared* parsed ;
  89
  90 SYNTAX: `:
  91     scan-param parsed
  92     parse-declared*
  93     \ define-declared* parsed ;
  94
  95 SYNTAX: `SYMBOL:
  96     scan-param parsed
  97     \ define-symbol parsed ;
  98
  99 SYNTAX: `SYNTAX:
 100     scan-param parsed
 101     parse-definition*
 102     \ define-syntax parsed ;
 103
 104 SYNTAX: `INSTANCE:
 105     scan-param parsed
 106     scan-param parsed
 107     \ add-mixin-instance parsed ;
 108
 109 SYNTAX: `GENERIC:
 110     scan-param parsed
 111     complete-effect parsed
 112     \ define-simple-generic* parsed ;
 113
 114 SYNTAX: `inline [ word make-inline ] over push-all ;
 115
 116 SYNTAX: `call-next-method T{ fake-call-next-method } parsed ;
 117
 118 : (INTERPOLATE) ( accum quot -- accum )
 119     [ scan interpolate-locals ] dip
 120     '[ _ with-string-writer @ ] parsed ;
 121
 122 PRIVATE>
 123
 124 SYNTAX: IS [ dup search [ ] [ no-word ] ?if ] (INTERPOLATE) ;
 125
 126 SYNTAX: DEFINES [ create-in ] (INTERPOLATE) ;
 127
 128 SYNTAX: DEFINES-CLASS [ create-class-in ] (INTERPOLATE) ;
 129
 130 DEFER: ;FUNCTOR delimiter
 131
 132 <PRIVATE
 133
 134 : functor-words ( -- assoc )
 135     H{
 136         { "TUPLE:" POSTPONE: `TUPLE: }
 137         { "M:" POSTPONE: `M: }
 138         { "C:" POSTPONE: `C: }
 139         { ":" POSTPONE: `: }
 140         { "GENERIC:" POSTPONE: `GENERIC: }
 141         { "INSTANCE:" POSTPONE: `INSTANCE: }
 142         { "SYNTAX:" POSTPONE: `SYNTAX: }
 143         { "SYMBOL:" POSTPONE: `SYMBOL: }
 144         { "inline" POSTPONE: `inline }
 145         { "call-next-method" POSTPONE: `call-next-method }
 146     } ;
 147
 148 : push-functor-words ( -- )
 149     functor-words use get push ;
 150
 151 : pop-functor-words ( -- )
 152     functor-words use get delq ;
 153
 154 : parse-functor-body ( -- form )
 155     push-functor-words
 156     "WHERE" parse-bindings*
 157     [ \ ;FUNCTOR parse-until >quotation ] ((parse-lambda)) <let*> 1quotation
 158     pop-functor-words ;
 159
 160 : (FUNCTOR:) ( -- word def effect )
 161     CREATE-WORD [ parse-functor-body ] parse-locals-definition ;
 162
 163 PRIVATE>
 164
 165 SYNTAX: FUNCTOR: (FUNCTOR:) define-declared ;