basis/furnace/auth/auth.factor

   1 ! Copyright (c) 2008 Slava Pestov\r
   2 ! See http://factorcode.org/license.txt for BSD license.\r
   3 USING: accessors assocs namespaces kernel sequences sets\r
   4 destructors combinators fry logging\r
   5 io.encodings.utf8 io.encodings.string io.binary random\r
   6 checksums checksums.sha2\r
   7 html.forms\r
   8 http.server\r
   9 http.server.filters\r
  10 http.server.dispatchers\r
  11 furnace\r
  12 furnace.actions\r
  13 furnace.redirection\r
  14 furnace.boilerplate\r
  15 furnace.auth.providers\r
  16 furnace.auth.providers.db ;\r
  17 IN: furnace.auth\r
  18 \r
  19 SYMBOL: logged-in-user\r
  20 \r
  21 : logged-in? ( -- ? )\r
  22     logged-in-user get >boolean ;\r
  23 \r
  24 : username ( -- string/f )\r
  25     logged-in-user get dup [ username>> ] when ;\r
  26 \r
  27 GENERIC: init-user-profile ( responder -- )\r
  28 \r
  29 M: object init-user-profile drop ;\r
  30 \r
  31 M: dispatcher init-user-profile\r
  32     default>> init-user-profile ;\r
  33 \r
  34 M: filter-responder init-user-profile\r
  35     responder>> init-user-profile ;\r
  36 \r
  37 : profile ( -- assoc ) logged-in-user get profile>> ;\r
  38 \r
  39 : user-changed ( -- )\r
  40     logged-in-user get t >>changed? drop ;\r
  41 \r
  42 : uget ( key -- value )\r
  43     profile at ;\r
  44 \r
  45 : uset ( value key -- )\r
  46     profile set-at\r
  47     user-changed ;\r
  48 \r
  49 : uchange ( quot key -- )\r
  50     profile swap change-at\r
  51     user-changed ; inline\r
  52 \r
  53 SYMBOL: capabilities\r
  54 \r
  55 V{ } clone capabilities set-global\r
  56 \r
  57 : define-capability ( word -- ) capabilities get adjoin ;\r
  58 \r
  59 TUPLE: realm < dispatcher name users checksum secure ;\r
  60 \r
  61 GENERIC: login-required* ( description capabilities realm -- response )\r
  62 \r
  63 GENERIC: init-realm ( realm -- )\r
  64 \r
  65 GENERIC: logged-in-username ( realm -- username )\r
  66 \r
  67 : login-required ( description capabilities -- * )\r
  68     realm get login-required* exit-with ;\r
  69 \r
  70 : new-realm ( responder name class -- realm )\r
  71     new-dispatcher\r
  72         swap >>name\r
  73         swap >>default\r
  74         users-in-db >>users\r
  75         sha-256 >>checksum\r
  76         t >>secure ; inline\r
  77 \r
  78 : users ( -- provider )\r
  79     realm get users>> ;\r
  80 \r
  81 TUPLE: user-saver user ;\r
  82 \r
  83 C: <user-saver> user-saver\r
  84 \r
  85 M: user-saver dispose\r
  86     user>> dup changed?>> [ users update-user ] [ drop ] if ;\r
  87 \r
  88 : save-user-after ( user -- )\r
  89     <user-saver> &dispose drop ;\r
  90 \r
  91 : init-user ( user -- )\r
  92     [ [ logged-in-user set ] [ save-user-after ] bi ] when* ;\r
  93 \r
  94 \ init-user DEBUG add-input-logging\r
  95 \r
  96 M: realm call-responder* ( path responder -- response )\r
  97     dup realm set\r
  98     logged-in? [\r
  99         dup init-realm\r
 100         dup logged-in-username\r
 101         dup [ users get-user ] when\r
 102         init-user\r
 103     ] unless\r
 104     call-next-method ;\r
 105 \r
 106 : encode-password ( string salt -- bytes )\r
 107     [ utf8 encode ] [ 4 >be ] bi* append\r
 108     realm get checksum>> checksum-bytes ;\r
 109 \r
 110 : >>encoded-password ( user string -- user )\r
 111     32 random-bits [ encode-password ] keep\r
 112     [ >>password ] [ >>salt ] bi* ; inline\r
 113 \r
 114 : valid-login? ( password user -- ? )\r
 115     [ salt>> encode-password ] [ password>> ] bi = ;\r
 116 \r
 117 : check-login ( password username -- user/f )\r
 118     users get-user dup [ [ valid-login? ] keep and ] [ 2drop f ] if ;\r
 119 \r
 120 : if-secure-realm ( quot -- )\r
 121     realm get secure>> [ if-secure ] [ call ] if ; inline\r
 122 \r
 123 TUPLE: secure-realm-only < filter-responder ;\r
 124 \r
 125 C: <secure-realm-only> secure-realm-only\r
 126 \r
 127 M: secure-realm-only call-responder*\r
 128     '[ , , call-next-method ] if-secure-realm ;\r
 129 \r
 130 TUPLE: protected < filter-responder description capabilities ;\r
 131 \r
 132 : <protected> ( responder -- protected )\r
 133     protected new\r
 134         swap >>responder ;\r
 135 \r
 136 : have-capabilities? ( capabilities -- ? )\r
 137     realm get secure>> secure-connection? not and [ drop f ] [\r
 138         logged-in-user get {\r
 139             { [ dup not ] [ 2drop f ] }\r
 140             { [ dup deleted>> 1 = ] [ 2drop f ] }\r
 141             [ capabilities>> subset? ]\r
 142         } cond\r
 143     ] if ;\r
 144 \r
 145 M: protected call-responder* ( path responder -- response )\r
 146     dup protected set\r
 147     dup capabilities>> have-capabilities?\r
 148     [ call-next-method ] [\r
 149         [ drop ] [ [ description>> ] [ capabilities>> ] bi ] bi*\r
 150         realm get login-required*\r
 151     ] if ;\r
 152 \r
 153 : <auth-boilerplate> ( responder -- responder' )\r
 154     <boilerplate> { realm "boilerplate" } >>template ;\r
 155 \r
 156 : password-mismatch ( -- * )\r
 157     "passwords do not match" validation-error\r
 158     validation-failed ;\r
 159 \r
 160 : same-password-twice ( -- )\r
 161     "new-password" value "verify-password" value =\r
 162     [ password-mismatch ] unless ;\r
 163 \r
 164 : user-exists ( -- * )\r
 165     "username taken" validation-error\r
 166     validation-failed ;\r