basis/game/input/dinput/dinput.factor

   1 USING: accessors alien alien.c-types alien.strings arrays
   2 assocs byte-arrays combinators combinators.short-circuit
   3 continuations game.input game.input.dinput.keys-array
   4 io.encodings.utf16 io.encodings.utf16n kernel locals math
   5 math.bitwise math.rectangles namespaces parser sequences
   6 shuffle specialized-arrays ui.backend.windows vectors
   7 windows.com windows.directx.dinput
   8 windows.directx.dinput.constants .errors windows.kernel32
   9 windows.messages .ole32 windows.user32 classes.struct
  10 alien.data ;
  11 SPECIALIZED-ARRAY: DIDEVICEOBJECTDATA
  12 IN: game.input.dinput
  13
  14 CONSTANT: MOUSE-BUFFER-SIZE 16
  15
  16 SINGLETON: dinput-game-input-backend
  17
  18 dinput-game-input-backend game-input-backend set-global
  19
  20 SYMBOLS: +dinput+ +keyboard-device+ +keyboard-state+
  21     +controller-devices+ +controller-guids+
  22     +device-change-window+ +device-change-handle+
  23     +mouse-device+ +mouse-state+ +mouse-buffer+ ;
  24
  25 : create-dinput ( -- )
  26     f GetModuleHandle DIRECTINPUT_VERSION IDirectInput8W-iid
  27     f <void*> [ f DirectInput8Create ole32-error ] keep *void*
  28     +dinput+ set-global ;
  29
  30 : delete-dinput ( -- )
  31     +dinput+ [ com-release f ] change-global ;
  32
  33 : device-for-guid ( guid -- device )
  34     +dinput+ get swap f <void*>
  35     [ f IDirectInput8W::CreateDevice ole32-error ] keep *void* ;
  36
  37 : set-coop-level ( device -- )
  38     +device-change-window+ get DISCL_BACKGROUND DISCL_NONEXCLUSIVE bitor
  39     IDirectInputDevice8W::SetCooperativeLevel ole32-error ;
  40
  41 : set-data-format ( device format-symbol -- )
  42     get IDirectInputDevice8W::SetDataFormat ole32-error ;
  43
  44 : <buffer-size-diprop> ( size -- DIPROPDWORD )
  45     DIPROPDWORD <struct> [
  46         diph>>
  47         DIPROPDWORD heap-size  >>dwSize
  48         DIPROPHEADER heap-size >>dwHeaderSize
  49         0           >>dwObj
  50         DIPH_DEVICE >>dwHow
  51         drop
  52     ] keep swap >>dwData ;
  53
  54 : set-buffer-size ( device size -- )
  55     DIPROP_BUFFERSIZE swap <buffer-size-diprop>
  56     IDirectInputDevice8W::SetProperty ole32-error ;
  57
  58 : configure-keyboard ( keyboard -- )
  59     [ c_dfDIKeyboard_HID set-data-format ] [ set-coop-level ] bi ;
  60 : configure-mouse ( mouse -- )
  61     [ c_dfDIMouse2 set-data-format ]
  62     [ MOUSE-BUFFER-SIZE set-buffer-size ]
  63     [ set-coop-level ] tri ;
  64 : configure-controller ( controller -- )
  65     [ c_dfDIJoystick2 set-data-format ] [ set-coop-level ] bi ;
  66
  67 : find-keyboard ( -- )
  68     GUID_SysKeyboard device-for-guid
  69     [ configure-keyboard ]
  70     [ +keyboard-device+ set-global ] bi
  71     256 <byte-array> 256 <keys-array> keyboard-state boa
  72     +keyboard-state+ set-global ;
  73
  74 : find-mouse ( -- )
  75     GUID_SysMouse device-for-guid
  76     [ configure-mouse ] [ +mouse-device+ set-global ] bi
  77     0 0 0 0 8 f <array> mouse-state boa +mouse-state+ set-global
  78     MOUSE-BUFFER-SIZE <DIDEVICEOBJECTDATA-array> +mouse-buffer+ set-global ;
  79
  80 : device-info ( device -- DIDEVICEIMAGEINFOW )
  81     DIDEVICEINSTANCEW <struct>
  82         DIDEVICEINSTANCEW heap-size >>dwSize
  83     [ IDirectInputDevice8W::GetDeviceInfo ole32-error ] keep ; inline
  84 : device-caps ( device -- DIDEVCAPS )
  85     DIDEVCAPS <struct>
  86         DIDEVCAPS heap-size >>dwSize
  87     [ IDirectInputDevice8W::GetCapabilities ole32-error ] keep ; inline
  88
  89 : device-guid ( device -- guid )
  90     device-info guidInstance>> ; inline
  91
  92 : device-attached? ( device -- ? )
  93     +dinput+ get swap device-guid
  94     IDirectInput8W::GetDeviceStatus S_OK = ;
  95
  96 : find-device-axes-callback ( -- alien )
  97     [ ! ( lpddoi pvRef -- BOOL )
  98         [ DIDEVICEOBJECTINSTANCEW memory>struct ] dip
  99         +controller-devices+ get at
 100         swap guidType>> {
 101             { [ dup GUID_XAxis = ] [ drop 0.0 >>x ] }
 102             { [ dup GUID_YAxis = ] [ drop 0.0 >>y ] }
 103             { [ dup GUID_ZAxis = ] [ drop 0.0 >>z ] }
 104             { [ dup GUID_RxAxis = ] [ drop 0.0 >>rx ] }
 105             { [ dup GUID_RyAxis = ] [ drop 0.0 >>ry ] }
 106             { [ dup GUID_RzAxis = ] [ drop 0.0 >>rz ] }
 107             { [ dup GUID_Slider = ] [ drop 0.0 >>slider ] }
 108             [ drop ]
 109         } cond drop
 110         DIENUM_CONTINUE
 111     ] LPDIENUMDEVICEOBJECTSCALLBACKW ;
 112
 113 : find-device-axes ( device controller-state -- controller-state )
 114     swap [ +controller-devices+ get set-at ] 2keep
 115     find-device-axes-callback over DIDFT_AXIS
 116     IDirectInputDevice8W::EnumObjects ole32-error ;
 117
 118 : controller-state-template ( device -- controller-state )
 119     controller-state new
 120     over device-caps
 121     [ dwButtons>> f <array> >>buttons ]
 122     [ dwPOVs>> zero? f pov-neutral ? >>pov ] bi
 123     find-device-axes ;
 124
 125 : device-known? ( guid -- ? )
 126     +controller-guids+ get key? ; inline
 127
 128 : (add-controller) ( guid -- )
 129     device-for-guid {
 130         [ configure-controller ]
 131         [ controller-state-template ]
 132         [ dup device-guid clone +controller-guids+ get set-at ]
 133         [ +controller-devices+ get set-at ]
 134     } cleave ;
 135
 136 : add-controller ( guid -- )
 137     dup device-known? [ drop ] [ (add-controller) ] if ;
 138
 139 : remove-controller ( device -- )
 140     [ +controller-devices+ get delete-at ]
 141     [ device-guid +controller-guids+ get delete-at ]
 142     [ com-release ] tri ;
 143
 144 : find-controller-callback ( -- alien )
 145     [ ! ( lpddi pvRef -- BOOL )
 146         drop DIDEVICEINSTANCEW memory>struct guidInstance>> add-controller
 147         DIENUM_CONTINUE
 148     ] LPDIENUMDEVICESCALLBACKW ; inline
 149
 150 : find-controllers ( -- )
 151     +dinput+ get DI8DEVCLASS_GAMECTRL find-controller-callback
 152     f DIEDFL_ATTACHEDONLY IDirectInput8W::EnumDevices ole32-error ;
 153
 154 : set-up-controllers ( -- )
 155     4 <vector> +controller-devices+ set-global
 156     4 <vector> +controller-guids+ set-global
 157     find-controllers ;
 158
 159 : find-and-remove-detached-devices ( -- )
 160     +controller-devices+ get keys
 161     [ device-attached? not ] filter
 162     [ remove-controller ] each ;
 163
 164 : ?device-interface ( dbt-broadcast-hdr -- ? )
 165     dup dbch_devicetype>> DBT_DEVTYP_DEVICEINTERFACE =
 166     [ >c-ptr DEV_BROADCAST_DEVICEW memory>struct ]
 167     [ drop f ] if ; inline
 168
 169 : device-arrived ( dbt-broadcast-hdr -- )
 170     ?device-interface [ find-controllers ] when ; inline
 171
 172 : device-removed ( dbt-broadcast-hdr -- )
 173     ?device-interface [ find-and-remove-detached-devices ] when ; inline
 174
 175 : <DEV_BROADCAST_HDR> ( wParam -- struct )
 176     <alien> DEV_BROADCAST_HDR memory>struct ;
 177
 178 : handle-wm-devicechange ( hWnd uMsg wParam lParam -- )
 179     [ 2drop ] 2dip swap {
 180         { [ dup DBT_DEVICEARRIVAL = ]         [ drop <DEV_BROADCAST_HDR> device-arrived ] }
 181         { [ dup DBT_DEVICEREMOVECOMPLETE = ]  [ drop <DEV_BROADCAST_HDR> device-removed ] }
 182         [ 2drop ]
 183     } cond ;
 184
 185 TUPLE: window-rect < rect window-loc ;
 186 : <zero-window-rect> ( -- window-rect )
 187     window-rect new
 188     { 0 0 } >>window-loc
 189     { 0 0 } >>loc
 190     { 0 0 } >>dim ;
 191
 192 : (device-notification-filter) ( -- DEV_BROADCAST_DEVICEW )
 193     DEV_BROADCAST_DEVICEW <struct>
 194         DEV_BROADCAST_DEVICEW heap-size >>dbcc_size
 195         DBT_DEVTYP_DEVICEINTERFACE >>dbcc_devicetype ;
 196
 197 : create-device-change-window ( -- )
 198     <zero-window-rect> WS_OVERLAPPEDWINDOW 0 create-window
 199     [
 200         (device-notification-filter)
 201         DEVICE_NOTIFY_WINDOW_HANDLE DEVICE_NOTIFY_ALL_INTERFACE_CLASSES bitor
 202         RegisterDeviceNotification
 203         +device-change-handle+ set-global
 204     ]
 205     [ +device-change-window+ set-global ] bi ;
 206
 207 : close-device-change-window ( -- )
 208     +device-change-handle+ [ UnregisterDeviceNotification drop f ] change-global
 209     +device-change-window+ [ DestroyWindow win32-error=0/f f ] change-global ;
 210
 211 : add-wm-devicechange ( -- )
 212     [ 4dup handle-wm-devicechange DefWindowProc ]
 213     WM_DEVICECHANGE add-wm-handler ;
 214
 215 : remove-wm-devicechange ( -- )
 216     WM_DEVICECHANGE wm-handlers get-global delete-at ;
 217
 218 : release-controllers ( -- )
 219     +controller-devices+ [ [ drop com-release ] assoc-each f ] change-global
 220     f +controller-guids+ set-global ;
 221
 222 : release-keyboard ( -- )
 223     +keyboard-device+ [ com-release f ] change-global
 224     f +keyboard-state+ set-global ;
 225
 226 : release-mouse ( -- )
 227     +mouse-device+ [ com-release f ] change-global
 228     f +mouse-state+ set-global ;
 229
 230 M: dinput-game-input-backend (open-game-input)
 231     create-dinput
 232     create-device-change-window
 233     find-keyboard
 234     find-mouse
 235     set-up-controllers
 236     add-wm-devicechange ;
 237
 238 M: dinput-game-input-backend (close-game-input)
 239     remove-wm-devicechange
 240     release-controllers
 241     release-mouse
 242     release-keyboard
 243     close-device-change-window
 244     delete-dinput ;
 245
 246 M: dinput-game-input-backend (reset-game-input)
 247     global [
 248         {
 249             +dinput+ +keyboard-device+ +keyboard-state+
 250             +controller-devices+ +controller-guids+
 251             +device-change-window+ +device-change-handle+
 252         } [ off ] each
 253     ] bind ;
 254
 255 M: dinput-game-input-backend get-controllers
 256     +controller-devices+ get
 257     [ drop controller boa ] { } assoc>map ;
 258
 259 M: dinput-game-input-backend product-string
 260     handle>> device-info tszProductName>>
 261     utf16n alien>string ;
 262
 263 M: dinput-game-input-backend product-id
 264     handle>> device-info guidProduct>> ;
 265 M: dinput-game-input-backend instance-id
 266     handle>> device-guid ;
 267
 268 :: with-acquisition ( device acquired-quot succeeded-quot failed-quot -- result/f )
 269     device { [ ] [ IDirectInputDevice8W::Acquire succeeded? ] } 1&& [
 270         device acquired-quot call
 271         succeeded-quot call
 272     ] failed-quot if ; inline
 273
 274 CONSTANT: pov-values
 275     {
 276         pov-up pov-up-right pov-right pov-down-right
 277         pov-down pov-down-left pov-left pov-up-left
 278     }
 279
 280 : >axis ( long -- float )
 281     32767 - 32767.0 /f ; inline
 282 : >slider ( long -- float )
 283     65535.0 /f ; inline
 284 : >pov ( long -- symbol )
 285     dup HEX: FFFF bitand HEX: FFFF =
 286     [ drop pov-neutral ]
 287     [ 2750 + 4500 /i pov-values nth ] if ; inline
 288
 289 : (fill-if) ( controller-state DIJOYSTATE2 ? quot -- )
 290     [ drop ] compose [ 2drop ] if ; inline
 291
 292 : fill-controller-state ( controller-state DIJOYSTATE2 -- controller-state )
 293     {
 294         [ over x>> [ lX>> >axis >>x ] (fill-if) ]
 295         [ over y>> [ lY>> >axis >>y ] (fill-if) ]
 296         [ over z>> [ lZ>> >axis >>z ] (fill-if) ]
 297         [ over rx>> [ lRx>> >axis >>rx ] (fill-if) ]
 298         [ over ry>> [ lRy>> >axis >>ry ] (fill-if) ]
 299         [ over rz>> [ lRz>> >axis >>rz ] (fill-if) ]
 300         [ over slider>> [ rglSlider>> first >slider >>slider ] (fill-if) ]
 301         [ over pov>> [ rgdwPOV>> first >pov >>pov ] (fill-if) ]
 302         [ rgbButtons>> over buttons>> length <keys-array> >>buttons ]
 303     } 2cleave ;
 304
 305 : read-device-buffer ( device buffer count -- buffer count' )
 306     [ DIDEVICEOBJECTDATA heap-size ] 2dip <uint>
 307     [ 0 IDirectInputDevice8W::GetDeviceData ole32-error ] 2keep *uint ;
 308
 309 : (fill-mouse-state) ( state DIDEVICEOBJECTDATA -- state )
 310     [ dwData>> 32 >signed ] [ dwOfs>> ] bi {
 311         { DIMOFS_X [ [ + ] curry change-dx ] }
 312         { DIMOFS_Y [ [ + ] curry change-dy ] }
 313         { DIMOFS_Z [ [ + ] curry change-scroll-dy ] }
 314         [ [ c-bool> ] [ DIMOFS_BUTTON0 - ] bi* rot [ buttons>> set-nth ] keep ]
 315     } case ;
 316
 317 : fill-mouse-state ( buffer count -- state )
 318     [ +mouse-state+ get ] 2dip swap [ nth (fill-mouse-state) ] curry each ;
 319
 320 : get-device-state ( device DIJOYSTATE2 -- )
 321     [ dup IDirectInputDevice8W::Poll ole32-error ] dip
 322     [ byte-length ] keep
 323     IDirectInputDevice8W::GetDeviceState ole32-error ;
 324
 325 : (read-controller) ( handle template -- state )
 326     swap [ DIJOYSTATE2 <struct> [ get-device-state ] keep ]
 327     [ fill-controller-state ] [ drop f ] with-acquisition ;
 328
 329 M: dinput-game-input-backend read-controller
 330     handle>> dup +controller-devices+ get at
 331     [ (read-controller) ] [ drop f ] if* ;
 332
 333 M: dinput-game-input-backend calibrate-controller
 334     handle>> f 0 IDirectInputDevice8W::RunControlPanel ole32-error ;
 335
 336 M: dinput-game-input-backend read-keyboard
 337     +keyboard-device+ get
 338     [ +keyboard-state+ get [ keys>> underlying>> get-device-state ] keep ]
 339     [ ] [ f ] with-acquisition ;
 340
 341 M: dinput-game-input-backend read-mouse
 342     +mouse-device+ get [ +mouse-buffer+ get MOUSE-BUFFER-SIZE read-device-buffer ]
 343     [ fill-mouse-state ] [ f ] with-acquisition ;
 344
 345 M: dinput-game-input-backend reset-mouse
 346     +mouse-device+ get [ f MOUSE-BUFFER-SIZE read-device-buffer ]
 347     [ 2drop ] [ ] with-acquisition
 348     +mouse-state+ get
 349         0 >>dx
 350         0 >>dy
 351         0 >>scroll-dx
 352         0 >>scroll-dy
 353         drop ;