basis/grouping/grouping-docs.factor

   1 USING: help.markup help.syntax sequences strings ;
   2 IN: grouping
   3
   4 ARTICLE: "grouping" "Groups and clumps"
   5 "Splitting a sequence into disjoint, fixed-length subsequences:"
   6 { $subsection group }
   7 "A virtual sequence for splitting a sequence into disjoint, fixed-length subsequences:"
   8 { $subsection groups }
   9 { $subsection <groups> }
  10 { $subsection <sliced-groups> }
  11 "Splitting a sequence into overlapping, fixed-length subsequences:"
  12 { $subsection clump }
  13 "A virtual sequence for splitting a sequence into overlapping, fixed-length subsequences:"
  14 { $subsection clumps }
  15 { $subsection <clumps> }
  16 { $subsection <sliced-clumps> }
  17 "The difference can be summarized as the following:"
  18 { $list
  19     { "With groups, the subsequences form the original sequence when concatenated:"
  20         { $unchecked-example "dup n groups concat sequence= ." "t" }
  21     }
  22     { "With clumps, collecting the first element of each subsequence but the last one, together with the last subseqence, yields the original sequence:"
  23         { $unchecked-example "dup n clumps unclip-last [ [ first ] map ] dip append sequence= ." "t" }
  24     }
  25 } ;
  26
  27 ABOUT: "grouping"
  28
  29 HELP: groups
  30 { $class-description "Instances are virtual sequences whose elements are disjoint fixed-length subsequences of an underlying sequence. Groups are mutable and resizable if the underlying sequence is mutable and resizable, respectively."
  31 $nl
  32 "New groups are created by calling " { $link <groups> } " and " { $link <sliced-groups> } "." }
  33 { $see-also group } ;
  34
  35 HELP: group
  36 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "array" "a sequence of sequences" } }
  37 { $description "Splits the sequence into disjoint groups of " { $snippet "n" } " elements and collects the groups into a new array." }
  38 { $notes "If the sequence length is not a multiple of " { $snippet "n" } ", the final subsequence in the list will be shorter than " { $snippet "n" } " elements." }
  39 { $examples
  40     { $example "USING: grouping prettyprint ;" "{ 3 1 3 3 7 } 2 group ." "{ { 3 1 } { 3 3 } { 7 } }" }
  41 } ;
  42
  43 HELP: <groups>
  44 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "groups" groups } }
  45 { $description "Outputs a virtual sequence whose elements are disjoint subsequences of " { $snippet "n" } " elements from the underlying sequence." }
  46 { $examples
  47     { $example
  48         "USING: arrays kernel prettyprint sequences grouping ;"
  49         "9 >array 3 <groups> dup reverse-here concat >array ." "{ 6 7 8 3 4 5 0 1 2 }"
  50     }
  51 } ;
  52
  53 HELP: <sliced-groups>
  54 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "groups" groups } }
  55 { $description "Outputs a virtual sequence whose elements are overlapping subsequences of " { $snippet "n" } " elements from the underlying sequence." }
  56 { $examples
  57     { $example
  58         "USING: arrays kernel prettyprint sequences grouping ;"
  59         "9 >array 3 <sliced-groups>"
  60         "dup [ reverse-here ] each concat >array ."
  61         "{ 2 1 0 5 4 3 8 7 6 }"
  62     }
  63 } ;
  64
  65 HELP: clumps
  66 { $class-description "Instances are virtual sequences whose elements are overlapping fixed-length subsequences o an underlying sequence. Clumps are mutable and resizable if the underlying sequence is mutable and resizable, respectively."
  67 $nl
  68 "New clumps are created by calling " { $link <clumps> } " and " { $link <sliced-clumps> } "." } ;
  69
  70 HELP: clump
  71 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "array" "a sequence of sequences" } }
  72 { $description "Splits the sequence into overlapping clumps of " { $snippet "n" } " elements and collects the clumps into a new array." }
  73 { $errors "Throws an error if " { $snippet "n" } " is smaller than the length of the sequence." }
  74 { $examples
  75     { $example "USING: grouping prettyprint ;" "{ 3 1 3 3 7 } 2 clump ." "{ { 3 1 } { 1 3 } { 3 3 } { 3 7 } }" }
  76 } ;
  77
  78 HELP: <clumps>
  79 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "clumps" clumps } }
  80 { $description "Outputs a virtual sequence whose elements are overlapping subsequences of " { $snippet "n" } " elements from the underlying sequence." }
  81 { $examples
  82     "Running averages:"
  83     { $example
  84         "USING: grouping sequences math prettyprint kernel ;"
  85         "IN: scratchpad"
  86         ": share-price"
  87         "    { 13/50 51/100 13/50 1/10 4/5 17/20 33/50 3/25 19/100 3/100 } ;"
  88         ""
  89         "share-price 4 <clumps> [ [ sum ] [ length ] bi / ] map ."
  90         "{ 113/400 167/400 201/400 241/400 243/400 91/200 1/4 }"
  91     }
  92 } ;
  93
  94 HELP: <sliced-clumps>
  95 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "clumps" clumps } }
  96 { $description "Outputs a virtual sequence whose elements are overlapping slices of " { $snippet "n" } " elements from the underlying sequence." } ;
  97
  98 { clumps groups } related-words
  99
 100 { clump group } related-words
 101
 102 { <clumps> <groups> } related-words
 103
 104 { <sliced-clumps> <sliced-groups> } related-words