basis/grouping/grouping-docs.factor

   1 USING: help.markup help.syntax sequences strings ;
   2 IN: grouping
   3
   4 ARTICLE: "grouping" "Groups and clumps"
   5 "Splitting a sequence into disjoint, fixed-length subsequences:"
   6 { $subsection group }
   7 "A virtual sequence for splitting a sequence into disjoint, fixed-length subsequences:"
   8 { $subsection groups }
   9 { $subsection <groups> }
  10 { $subsection <sliced-groups> }
  11 "Splitting a sequence into overlapping, fixed-length subsequences:"
  12 { $subsection clump }
  13 "A virtual sequence for splitting a sequence into overlapping, fixed-length subsequences:"
  14 { $subsection clumps }
  15 { $subsection <clumps> }
  16 { $subsection <sliced-clumps> }
  17 "The difference can be summarized as the following:"
  18 { $list
  19     { "With groups, the subsequences form the original sequence when concatenated:"
  20         { $unchecked-example
  21             "USING: grouping ;"
  22             "{ 1 2 3 4 } dup" "2 <groups> concat sequence= ." "t"
  23         }
  24     }
  25     { "With clumps, collecting the first element of each subsequence but the last one, together with the last subseqence, yields the original sequence:"
  26         { $unchecked-example
  27             "USING: grouping ;"
  28             "{ 1 2 3 4 } dup" "2 <clumps> unclip-last [ [ first ] map ] dip append sequence= ." "t"
  29         }
  30     }
  31 }
  32 "A combinator built using clumps:"
  33 { $subsection monotonic? }
  34 "Testing how elements are related:"
  35 { $subsection all-eq? }
  36 { $subsection all-equal? } ;
  37
  38 ABOUT: "grouping"
  39
  40 HELP: groups
  41 { $class-description "Instances are virtual sequences whose elements are disjoint fixed-length subsequences of an underlying sequence. Groups are mutable and resizable if the underlying sequence is mutable and resizable, respectively."
  42 $nl
  43 "New groups are created by calling " { $link <groups> } " and " { $link <sliced-groups> } "." } ;
  44
  45 HELP: group
  46 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "array" "a sequence of sequences" } }
  47 { $description "Splits the sequence into disjoint groups of " { $snippet "n" } " elements and collects the groups into a new array." }
  48 { $notes "If the sequence length is not a multiple of " { $snippet "n" } ", the final subsequence in the list will be shorter than " { $snippet "n" } " elements." }
  49 { $examples
  50     { $example "USING: grouping prettyprint ;" "{ 3 1 3 3 7 } 2 group ." "{ { 3 1 } { 3 3 } { 7 } }" }
  51 } ;
  52
  53 HELP: <groups>
  54 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "groups" groups } }
  55 { $description "Outputs a virtual sequence whose elements are disjoint subsequences of " { $snippet "n" } " elements from the underlying sequence." }
  56 { $examples
  57     { $example
  58         "USING: arrays kernel prettyprint sequences grouping ;"
  59         "9 >array 3 <groups> dup reverse-here concat >array ." "{ 6 7 8 3 4 5 0 1 2 }"
  60     }
  61     { $example
  62         "USING: kernel prettyprint sequences grouping ;"
  63         "{ 1 2 3 4 5 6 } 3 <groups> first ."
  64         "{ 1 2 3 }"
  65     }
  66 } ;
  67
  68 HELP: <sliced-groups>
  69 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "groups" groups } }
  70 { $description "Outputs a virtual sequence whose elements are slices of disjoint subsequences of " { $snippet "n" } " elements from the underlying sequence." }
  71 { $examples
  72     { $example
  73         "USING: arrays kernel prettyprint sequences grouping ;"
  74         "9 >array 3 <sliced-groups>"
  75         "dup [ reverse-here ] each concat >array ."
  76         "{ 2 1 0 5 4 3 8 7 6 }"
  77     }
  78     { $example
  79         "USING: kernel prettyprint sequences grouping ;"
  80         "{ 1 2 3 4 5 6 } 3 <sliced-groups> second ."
  81         "T{ slice { from 3 } { to 6 } { seq { 1 2 3 4 5 6 } } }"
  82     }
  83 } ;
  84
  85 HELP: clumps
  86 { $class-description "Instances are virtual sequences whose elements are overlapping fixed-length subsequences o an underlying sequence. Clumps are mutable and resizable if the underlying sequence is mutable and resizable, respectively."
  87 $nl
  88 "New clumps are created by calling " { $link <clumps> } " and " { $link <sliced-clumps> } "." } ;
  89
  90 HELP: clump
  91 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "array" "a sequence of sequences" } }
  92 { $description "Splits the sequence into overlapping clumps of " { $snippet "n" } " elements and collects the clumps into a new array." }
  93 { $errors "Throws an error if " { $snippet "n" } " is smaller than the length of the sequence." }
  94 { $examples
  95     { $example "USING: grouping prettyprint ;" "{ 3 1 3 3 7 } 2 clump ." "{ { 3 1 } { 1 3 } { 3 3 } { 3 7 } }" }
  96 } ;
  97
  98 HELP: <clumps>
  99 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "clumps" clumps } }
 100 { $description "Outputs a virtual sequence whose elements are overlapping subsequences of " { $snippet "n" } " elements from the underlying sequence." }
 101 { $examples
 102     "Running averages:"
 103     { $example
 104         "USING: grouping sequences math prettyprint kernel ;"
 105         "IN: scratchpad"
 106         "CONSTANT: share-price { 13/50 51/100 13/50 1/10 4/5 17/20 33/50 3/25 19/100 3/100 }"
 107         ""
 108         "share-price 4 <clumps> [ [ sum ] [ length ] bi / ] map ."
 109         "{ 113/400 167/400 201/400 241/400 243/400 91/200 1/4 }"
 110     }
 111     { $example
 112         "USING: kernel sequences grouping prettyprint ;"
 113         "{ 1 2 3 4 5 6 } 3 <clumps> second ."
 114         "{ 2 3 4 }"
 115     }
 116 } ;
 117
 118 HELP: <sliced-clumps>
 119 { $values { "seq" "a sequence" } { "n" "a non-negative integer" } { "clumps" clumps } }
 120 { $description "Outputs a virtual sequence whose elements are overlapping slices of " { $snippet "n" } " elements from the underlying sequence." }
 121 { $examples
 122     { $example
 123         "USING: kernel sequences grouping prettyprint ;"
 124         "{ 1 2 3 4 5 6 } 3 <sliced-clumps> second ."
 125         "T{ slice { from 1 } { to 4 } { seq { 1 2 3 4 5 6 } } }"
 126     }
 127 } ;
 128
 129 { clumps groups } related-words
 130
 131 { clump group } related-words
 132
 133 { <clumps> <groups> } related-words
 134
 135 { <sliced-clumps> <sliced-groups> } related-words
 136
 137 HELP: monotonic?
 138 { $values { "seq" sequence } { "quot" { $quotation "( elt elt -- ? )" } } { "?" "a boolean" } }
 139 { $description "Applies the relation to successive pairs of elements in the sequence, testing for a truth value. The relation should be a transitive relation, such as a total order or an equality relation." }
 140 { $examples
 141     "Testing if a sequence is non-decreasing:"
 142     { $example "USING: grouping math prettyprint ;" "{ 1 1 2 } [ <= ] monotonic? ." "t" }
 143     "Testing if a sequence is decreasing:"
 144     { $example "USING: grouping math prettyprint ;" "{ 9 8 6 7 } [ < ] monotonic? ." "f" }
 145 } ;
 146
 147 HELP: all-equal?
 148 { $values { "seq" sequence } { "?" "a boolean" } }
 149 { $description "Tests if all elements in the sequence are equal. Yields true with an empty sequence." } ;
 150
 151 HELP: all-eq?
 152 { $values { "seq" sequence } { "?" "a boolean" } }
 153 { $description "Tests if all elements in the sequence are the same identical object. Yields true with an empty sequence." } ;
 154
 155 { monotonic? all-eq? all-equal? } related-words