basis/grouping/grouping.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators fry kernel math math.order
   4 sequences sequences.private ;
   5 IN: grouping
   6
   7 ERROR: groups-error seq n ;
   8
   9 <PRIVATE
  10
  11 GENERIC: group@ ( n groups -- from to seq )
  12
  13 TUPLE: chunking { seq read-only } { n read-only } ;
  14
  15 INSTANCE: chunking sequence
  16
  17 M: chunking nth group@ <slice> ; inline
  18
  19 M: chunking nth-unsafe group@ <slice-unsafe> ; inline
  20
  21 M: chunking set-nth group@ <slice> 0 swap copy ;
  22
  23 M: chunking like drop { } like ; inline
  24
  25 : check-groups ( seq n -- seq n )
  26     dup 0 <= [ groups-error ] when ; inline
  27
  28 : new-groups ( seq n class -- groups )
  29     [ check-groups ] dip boa ; inline
  30
  31 PRIVATE>
  32
  33 TUPLE: groups < chunking ;
  34
  35 M: groups length
  36     [ seq>> length ] [ n>> ] bi [ + 1 - ] keep /i ; inline
  37
  38 M: groups set-length
  39     [ n>> * ] [ seq>> ] bi set-length ; inline
  40
  41 M: groups group@
  42     [ n>> [ * dup ] keep + ] [ seq>> ] bi [ length min ] keep ; inline
  43
  44 : <groups> ( seq n -- groups )
  45     groups new-groups ; inline
  46
  47 TUPLE: clumps < chunking ;
  48
  49 M: clumps length
  50     dup seq>> length [ drop 0 ] [
  51         swap [ 1 + ] [ n>> ] bi* [-]
  52     ] if-zero ; inline
  53
  54 M: clumps set-length
  55     [ n>> + 1 - ] [ seq>> ] bi set-length ; inline
  56
  57 M: clumps group@
  58     [ n>> over + ] [ seq>> ] bi ; inline
  59
  60 : <clumps> ( seq n -- clumps )
  61     clumps new-groups ; inline
  62
  63 <PRIVATE
  64
  65 : map-like ( seq n quot -- seq )
  66     2keep drop '[ _ like ] map ; inline
  67
  68 PRIVATE>
  69
  70 : group ( seq n -- array ) [ <groups> ] map-like ; inline
  71
  72 : clump ( seq n -- array ) [ <clumps> ] map-like ; inline
  73
  74 : monotonic? ( seq quot: ( elt1 elt2 -- ? ) -- ? )
  75     over length dup 2 < [ 3drop t ] [
  76         2 = [
  77             [ first2-unsafe ] dip call
  78         ] [
  79             [ [ first-unsafe 1 ] [ (setup-each) ] bi ] dip
  80             '[ @ _ keep swap ] (all-integers?) nip
  81         ] if
  82     ] if ; inline
  83
  84 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
  85
  86 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
  87
  88 TUPLE: circular-slice
  89     { from integer read-only }
  90     { to integer read-only }
  91     { seq read-only } ;
  92
  93 INSTANCE: circular-slice virtual-sequence
  94
  95 M: circular-slice equal? over circular-slice? [ sequence= ] [ 2drop f ] if ;
  96
  97 M: circular-slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
  98
  99 M: circular-slice length [ to>> ] [ from>> ] bi - ; inline
 100
 101 M: circular-slice virtual-exemplar seq>> ; inline
 102
 103 M: circular-slice virtual@
 104     [ from>> + ] [ seq>> ] bi [ length rem ] keep ; inline
 105
 106 C: <circular-slice> circular-slice
 107
 108 TUPLE: circular-clumps
 109     { seq read-only }
 110     { n read-only } ;
 111
 112 INSTANCE: circular-clumps sequence
 113
 114 M: circular-clumps length
 115     seq>> length ; inline
 116
 117 M: circular-clumps nth
 118     [ n>> over + ] [ seq>> ] bi <circular-slice> ; inline
 119
 120 : <circular-clumps> ( seq n -- clumps )
 121     circular-clumps new-groups ; inline
 122
 123 : circular-clump ( seq n -- array )
 124     [ <circular-clumps> ] map-like ; inline