basis/hash-sets/numbers/numbers.factor

   1 ! Copyright (C) 2013 John Benediktsson
   2 ! See https://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors hash-sets hash-sets.wrapped kernel math
   5 math.hashcodes parser sequences vocabs.loader ;
   6
   7 IN: hash-sets.numbers
   8
   9 <PRIVATE
  10
  11 TUPLE: number-wrapper
  12     { underlying number read-only } ;
  13
  14 C: <number-wrapper> number-wrapper
  15
  16 M: number-wrapper equal?
  17     over number-wrapper?
  18     [ [ underlying>> ] bi@ number= ]
  19     [ 2drop f ] if ; inline
  20
  21 M: number-wrapper hashcode*
  22     nip underlying>> number-hashcode ; inline
  23
  24 PRIVATE>
  25
  26 TUPLE: number-hash-set < wrapped-hash-set ;
  27
  28 : <number-hash-set> ( n -- shash-set )
  29     <hash-set> number-hash-set boa ; inline
  30
  31 M: number-hash-set wrap-key drop <number-wrapper> ;
  32
  33 M: number-hash-set clone
  34     underlying>> clone number-hash-set boa ; inline
  35
  36 : >number-hash-set ( members -- shash-set )
  37     [ <number-wrapper> ] map >hash-set number-hash-set boa ;
  38
  39 SYNTAX: NHS{ \ } [ >number-hash-set ] parse-literal ;
  40
  41 { "hash-sets.numbers" "prettyprint" } "hash-sets.numbers.prettyprint" require-when