basis/hashtables/sequences/sequences.factor

   1 ! Copyright (C) 2011 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors assocs combinators hashtables
   5 hashtables.wrapped kernel parser sequences vocabs.loader ;
   6
   7 IN: hashtables.sequences
   8
   9 ERROR: not-a-sequence object ;
  10
  11 TUPLE: sequence-wrapper < wrapped-key ;
  12
  13 C: <sequence-wrapper> sequence-wrapper
  14
  15 M: sequence-wrapper equal?
  16     over sequence-wrapper?
  17     [ [ underlying>> ] bi@ sequence= ]
  18     [ 2drop f ] if ; inline
  19
  20 M: sequence-wrapper hashcode*
  21     underlying>> [ sequence-hashcode ] recursive-hashcode ; inline
  22
  23 TUPLE: sequence-hashtable < wrapped-hashtable ;
  24
  25 : <sequence-hashtable> ( n -- shashtable )
  26     <hashtable> sequence-hashtable boa ; inline
  27
  28 M: sequence-hashtable wrap-key
  29     drop dup sequence? [ <sequence-wrapper> ] [ not-a-sequence ] if ;
  30
  31 M: sequence-hashtable clone
  32     underlying>> clone sequence-hashtable boa ; inline
  33
  34 : >sequence-hashtable ( assoc -- shashtable )
  35     [ assoc-size <sequence-hashtable> ] keep assoc-union! ;
  36
  37 M: sequence-hashtable new-assoc drop <sequence-hashtable> ;
  38
  39 SYNTAX: SH{ \ } [ >sequence-hashtable ] parse-literal ;
  40
  41 { "hashtables.sequences" "prettyprint" } "hashtables.sequences.prettyprint" require-when