basis/heaps/heaps-tests.factor

   1 ! Copyright 2007, 2008 Ryan Murphy, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math namespaces tools.test
   4 heaps heaps.private math.parser random assocs sequences sorting
   5 accessors math.order locals ;
   6 IN: heaps.tests
   7
   8 [ <min-heap> heap-pop ] must-fail
   9 [ <max-heap> heap-pop ] must-fail
  10
  11 { t } [ <min-heap> heap-empty? ] unit-test
  12 { f } [ <min-heap> 1 t pick heap-push heap-empty? ] unit-test
  13 { t } [ <max-heap> heap-empty? ] unit-test
  14 { f } [ <max-heap> 1 t pick heap-push heap-empty? ] unit-test
  15
  16 ! Binary Min Heap
  17 { 1 2 3 4 5 6 } [ 0 left 0 right 1 left 1 right 2 left 2 right ] unit-test
  18 { t } [ t 5 f <entry> t 3 f <entry> T{ min-heap } heap-compare ] unit-test
  19 { f } [ t 5 f <entry> t 3 f <entry> T{ max-heap } heap-compare ] unit-test
  20
  21 { t 2 } [ <min-heap> t 300 pick heap-push t 200 pick heap-push t 400 pick heap-push t 3 pick heap-push t 2 pick heap-push heap-pop ] unit-test
  22
  23 { t 1 } [ <min-heap> t 300 pick heap-push t 200 pick heap-push t 400 pick heap-push t 3 pick heap-push t 2 pick heap-push t 1 pick heap-push heap-pop ] unit-test
  24
  25 { t 400 } [ <max-heap> t 300 pick heap-push t 200 pick heap-push t 400 pick heap-push t 3 pick heap-push t 2 pick heap-push t 1 pick heap-push heap-pop ] unit-test
  26
  27 { 0 } [ <max-heap> heap-size ] unit-test
  28 { 1 } [ <max-heap> t 1 pick heap-push heap-size ] unit-test
  29
  30 DEFER: (assert-heap-invariant)
  31
  32 : ((assert-heap-invariant)) ( parent child heap heap-size -- )
  33     pick over < [
  34         [ [ heapdata-compare f assert= ] 2keep ] dip
  35         (assert-heap-invariant)
  36     ] [ 4drop ] if ;
  37
  38 : (assert-heap-invariant) ( n heap heap-size -- )
  39     [ dup left dup 1 + ] 2dip
  40     [ ((assert-heap-invariant)) ] 2curry bi-curry@ bi ;
  41
  42 : assert-heap-invariant ( heap -- )
  43     dup heap-empty? [ drop ]
  44     [ 0 swap dup heap-size (assert-heap-invariant) ] if ;
  45
  46 : heap-sort ( alist heap -- keys )
  47     [ heap-push-all ] keep dup assert-heap-invariant heap-pop-all ;
  48
  49 : random-alist ( n -- alist )
  50     <iota> [
  51         drop 32 random-bits dup number>string
  52     ] H{ } map>assoc >alist ;
  53
  54 :: test-heap-sort ( n heap reverse? -- ? )
  55     n random-alist
  56     [ sort-keys reverse? [ reverse ] when ] keep
  57     heap heap-sort = ;
  58
  59 : test-minheap-sort ( n -- ? )
  60     <min-heap> f test-heap-sort ;
  61
  62 : test-maxheap-sort ( n -- ? )
  63     <max-heap> t test-heap-sort ;
  64
  65 14 [
  66     [ t ] swap [ 2^ <min-heap> f test-heap-sort ] curry unit-test
  67 ] each-integer
  68
  69 14 [
  70     [ t ] swap [ 2^ <max-heap> t test-heap-sort ] curry unit-test
  71 ] each-integer
  72
  73 : test-entry-indices ( n -- ? )
  74     random-alist
  75     <min-heap> [ heap-push-all ] keep
  76     dup assert-heap-invariant
  77     data>> dup length <iota> swap [ index>> ] map sequence= ;
  78
  79 14 [
  80     [ t ] swap [ 2^ test-entry-indices ] curry unit-test
  81 ] each-integer
  82
  83 : delete-test ( n -- obj1 obj2 )
  84     [
  85         random-alist
  86         <min-heap> [ heap-push-all ] keep
  87         dup data>> clone swap
  88     ] keep 3 /i [ 2dup [ delete-random ] dip heap-delete ] times
  89     dup assert-heap-invariant
  90     data>>
  91     [ [ key>> ] map ] bi@
  92     [ natural-sort ] bi@ ;
  93
  94 11 [
  95     [ t ] swap [ 2^ delete-test sequence= ] curry unit-test
  96 ] each-integer
  97
  98 [| |
  99  <min-heap> :> heap
 100  t 1 heap heap-push* :> entry
 101  heap heap-pop 2drop
 102  t 2 heap heap-push
 103  entry heap heap-delete ] [ bad-heap-delete? ] must-fail-with
 104
 105 [| |
 106  <min-heap> :> heap
 107  t 1 heap heap-push* :> entry
 108  t 2 heap heap-push
 109  heap heap-pop 2drop
 110  entry heap heap-delete ] [ bad-heap-delete? ] must-fail-with
 111
 112 [| |
 113  <min-heap> :> heap
 114  t 1 heap heap-push* :> entry
 115  t 2 heap heap-push
 116  entry heap heap-delete
 117  entry heap heap-delete ] [ bad-heap-delete? ] must-fail-with
 118
 119 [| |
 120  <min-heap> :> heap
 121  t 0 heap heap-push
 122  t 1 heap heap-push* :> entry
 123  entry heap heap-delete
 124  entry heap heap-delete ] [ bad-heap-delete? ] must-fail-with