basis/heaps/heaps.factor

   1 ! Copyright (C) 2007, 2008 Ryan Murphy, Doug Coleman,
   2 ! Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors arrays assocs combinators fry growable kernel
   5 kernel.private math math.order math.private sequences
   6 sequences.private summary vectors ;
   7
   8 IN: heaps
   9
  10 GENERIC: heap-push* ( value key heap -- entry )
  11 GENERIC: heap-peek ( heap -- value key )
  12 GENERIC: heap-pop* ( heap -- )
  13 GENERIC: heap-pop ( heap -- value key )
  14 GENERIC: heap-delete ( entry heap -- )
  15 GENERIC: heap-empty? ( heap -- ? )
  16 GENERIC: heap-size ( heap -- n )
  17
  18 <PRIVATE
  19
  20 TUPLE: heap { data vector } ;
  21
  22 : <heap> ( class -- heap )
  23     [ V{ } clone ] dip boa ; inline
  24
  25 TUPLE: entry value key heap index ;
  26
  27 : <entry> ( value key heap -- entry )
  28     f entry boa ; inline
  29
  30 PRIVATE>
  31
  32 TUPLE: min-heap < heap ;
  33
  34 : <min-heap> ( -- min-heap ) min-heap <heap> ;
  35
  36 TUPLE: max-heap < heap ;
  37
  38 : <max-heap> ( -- max-heap ) max-heap <heap> ;
  39
  40 M: heap heap-empty? ( heap -- ? )
  41     data>> empty? ; inline
  42
  43 M: heap heap-size ( heap -- n )
  44     data>> length ; inline
  45
  46 <PRIVATE
  47
  48 : left ( n -- m )
  49     { fixnum } declare 1 fixnum-shift-fast 1 fixnum+fast ; inline
  50
  51 : right ( n -- m )
  52     { fixnum } declare 1 fixnum-shift-fast 2 fixnum+fast ; inline
  53
  54 : up ( n -- m )
  55     { fixnum } declare 1 fixnum-fast 2/ ; inline
  56
  57 : data-nth ( n heap -- entry )
  58     data>> nth-unsafe { entry } declare ; inline
  59
  60 : left-value ( n heap -- entry )
  61     [ left ] dip data-nth ; inline
  62
  63 : right-value ( n heap -- entry )
  64     [ right ] dip data-nth ; inline
  65
  66 : data-set-nth ( entry n heap -- )
  67     [ [ swap index<< ] 2keep ] dip
  68     data>> set-nth-unsafe ; inline
  69
  70 : data-push ( entry heap -- n )
  71     dup heap-size [
  72         swap
  73         [ data>> ensure 2drop ]
  74         [ data-set-nth ] 2bi
  75     ] keep ; inline
  76
  77 : data-first ( heap -- entry )
  78     data>> first ; inline
  79
  80 : data-exchange ( m n heap -- )
  81     [ '[ _ data-nth ] bi@ ]
  82     [ '[ _ data-set-nth ] bi@ ] 3bi ; inline
  83
  84 GENERIC: heap-compare ( entry1 entry2 heap -- ? )
  85
  86 : entry<=> ( entry1 entry2 -- <=> )
  87     { entry entry } declare [ key>> ] compare ; inline
  88
  89 M: min-heap heap-compare drop entry<=> +gt+ eq? ;
  90
  91 M: max-heap heap-compare drop entry<=> +lt+ eq? ;
  92
  93 : heap-bounds-check? ( m heap -- ? )
  94     heap-size >= ; inline
  95
  96 : left-bounds-check? ( m heap -- ? )
  97     [ left ] dip heap-bounds-check? ; inline
  98
  99 : right-bounds-check? ( m heap -- ? )
 100     [ right ] dip heap-bounds-check? ; inline
 101
 102 : continue? ( m n heap -- ? )
 103     [ data-nth nip ]
 104     [ nip data-nth ]
 105     [ 2nip ] 3tri heap-compare ; inline
 106
 107 DEFER: up-heap
 108
 109 : (up-heap) ( n heap -- )
 110     [ dup up ] dip
 111     3dup continue? [
 112         [ data-exchange ] [ up-heap ] 2bi
 113     ] [
 114         3drop
 115     ] if ; inline recursive
 116
 117 : up-heap ( n heap -- )
 118     over 0 > [ (up-heap) ] [ 2drop ] if ; inline recursive
 119
 120 : (child) ( m heap -- n )
 121     { [ drop ] [ left-value ] [ right-value ] [ nip ] } 2cleave
 122     heap-compare [ right ] [ left ] if ; inline
 123
 124 : child ( m heap -- n )
 125     2dup right-bounds-check?
 126     [ drop left ] [ (child) ] if ; inline
 127
 128 DEFER: down-heap
 129
 130 : (down-heap) ( m heap -- )
 131     [ drop ] [ child ] [ nip ] 2tri
 132     3dup continue? [
 133         3drop
 134     ] [
 135         [ data-exchange ] [ down-heap ] 2bi
 136     ] if ; inline recursive
 137
 138 : down-heap ( m heap -- )
 139     2dup left-bounds-check?
 140     [ 2drop ] [ (down-heap) ] if ; inline recursive
 141
 142 PRIVATE>
 143
 144 M: heap heap-push* ( value key heap -- entry )
 145     [ <entry> dup ] [ data-push ] [ up-heap ] tri ;
 146
 147 : heap-push ( value key heap -- ) heap-push* drop ;
 148
 149 : heap-push-all ( assoc heap -- )
 150     '[ swap _ heap-push ] assoc-each ;
 151
 152 : >entry< ( entry -- value key )
 153     [ value>> ] [ key>> ] bi ; inline
 154
 155 M: heap heap-peek ( heap -- value key )
 156     data-first >entry< ;
 157
 158 ERROR: bad-heap-delete ;
 159
 160 M: bad-heap-delete summary
 161     drop "Invalid entry passed to heap-delete" ;
 162
 163 : entry>index ( entry heap -- n )
 164     over heap>> eq? [ bad-heap-delete ] unless
 165     index>> { fixnum } declare ; inline
 166
 167 M: heap heap-delete ( entry heap -- )
 168     [ entry>index ] keep
 169     2dup heap-size 1 - = [
 170         nip data>> pop*
 171     ] [
 172         [ nip data>> pop ]
 173         [ data-set-nth ]
 174         [ down-heap ] 2tri
 175     ] if ;
 176
 177 M: heap heap-pop* ( heap -- )
 178     [ data-first ] keep heap-delete ;
 179
 180 M: heap heap-pop ( heap -- value key )
 181     [ data-first dup ] keep heap-delete >entry< ;
 182
 183 : heap-pop-all ( heap -- alist )
 184     [ dup heap-empty? not ]
 185     [ dup heap-pop swap 2array ]
 186     produce nip ;
 187
 188 ERROR: not-a-heap obj ;
 189
 190 : check-heap ( heap -- heap )
 191     dup heap? [ not-a-heap ] unless ; inline
 192
 193 : slurp-heap ( heap quot: ( elt -- ) -- )
 194     [ check-heap ] dip over heap-empty? [ 2drop ] [
 195         [ [ heap-pop drop ] dip call ] [ slurp-heap ] 2bi
 196     ] if ; inline recursive
 197
 198 : >min-heap ( assoc -- min-heap )
 199     <min-heap> [ heap-push-all ] keep ;
 200
 201 : >max-heap ( assoc -- min-heap )
 202     <max-heap> [ heap-push-all ] keep ;