basis/help/html/html.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs colors
   4 combinators.short-circuit debugger formatting help help.home
   5 help.topics help.vocabs html html.streams io.directories
   6 io.encodings.ascii io.encodings.binary io.encodings.utf8
   7 io.files io.files.temp io.pathnames kernel make math math.parser
   8 namespaces regexp sequences sequences.deep serialize sets
   9 sorting splitting strings system tools.completion vocabs
  10 vocabs.hierarchy words xml.data xml.syntax xml.traversal
  11 xml.writer ;
  12 FROM: io.encodings.ascii => ascii ;
  13 FROM: ascii => ascii? ;
  14 IN: help.html
  15
  16 : escape-char ( ch -- )
  17     dup ascii? [
  18         dup H{
  19             { CHAR: \" "__quo__" }
  20             { CHAR: * "__star__" }
  21             { CHAR: : "__colon__" }
  22             { CHAR: < "__lt__" }
  23             { CHAR: > "__gt__" }
  24             { CHAR: ? "__que__" }
  25             { CHAR: \\ "__back__" }
  26             { CHAR: | "__pipe__" }
  27             { CHAR: / "__slash__" }
  28             { CHAR: , "__comma__" }
  29             { CHAR: @ "__at__" }
  30             { CHAR: # "__hash__" }
  31             { CHAR: % "__percent__" }
  32         } at [ % ] [ , ] ?if
  33     ] [ number>string "__" "__" surround % ] if ;
  34
  35 : escape-filename ( string -- filename )
  36     [ [ escape-char ] each ] "" make ;
  37
  38 GENERIC: topic>filename* ( topic -- name prefix )
  39
  40 M: word topic>filename*
  41     dup vocabulary>> [
  42         [ name>> ] [ vocabulary>> ] bi 2array "word"
  43     ] [ drop f f ] if ;
  44
  45 M: link topic>filename* name>> dup [ "article" ] [ topic>filename* ] if ;
  46 M: word-link topic>filename* name>> topic>filename* ;
  47 M: vocab-spec topic>filename* vocab-name "vocab" ;
  48 M: vocab-tag topic>filename* name>> "tag" ;
  49 M: vocab-author topic>filename* name>> "author" ;
  50 M: f topic>filename* drop \ f topic>filename* ;
  51
  52 : topic>filename ( topic -- filename )
  53     topic>filename* [
  54         [
  55             % "-" %
  56             dup array?
  57             [ [ escape-filename ] map "," join ]
  58             [ escape-filename ]
  59             if % ".html" %
  60         ] "" make
  61     ] [ drop f ] if* ;
  62
  63 M: topic url-of topic>filename ;
  64
  65 M: pathname url-of
  66     string>> "resource:" ?head [
  67         "https://github.com/factor/factor/blob/master/"
  68         prepend
  69     ] [ drop f ] if ;
  70
  71 : help-stylesheet ( stylesheet -- xml )
  72     "vocab:help/html/stylesheet.css" ascii file-contents
  73     swap "\n" glue [XML <style><-></style> XML] ;
  74
  75 : help-meta ( -- xml )
  76     [XML <meta
  77             name="viewport"
  78             content="width=device-width, initial-scale=1"
  79             charset="utf-8"
  80         /> XML] ;
  81
  82 : help-navbar ( -- xml )
  83     "conventions" >link topic>filename
  84     [XML
  85         <div class="navbar">
  86             <div class="navrow">
  87                 <a href="https://factorcode.org">
  88                 <img src="favicon.ico" width="24" height="24" />
  89                 </a>
  90                 <a href="/">Handbook</a>
  91                 <a href=<->>Glossary</a>
  92                 <form method="get" action="/search" style="float: right;">
  93                     <input placeholder="Search" name="search" type="text"/>
  94                     <input type="submit" value="Go"/>
  95                 </form>
  96             </div>
  97         </div>
  98      XML] ;
  99
 100 : help-footer ( -- xml )
 101     version-info "\n" split1 drop
 102     [XML
 103         <div class="footer">
 104         <p>
 105         This documentation was generated offline from a
 106         <code>load-all</code> image.  If you want, you can also
 107         browse the documentation from within the <a
 108         href="article-ui-tools.html">UI developer tools</a>. See
 109         the <a href="https://factorcode.org">Factor website</a>
 110         for more information.
 111         </p>
 112         <p><-></p>
 113         </div>
 114     XML] ;
 115
 116 : bijective-base26 ( n -- name )
 117     [ dup 0 > ] [ 1 - 26 /mod CHAR: a + ] "" produce-as nip reverse! ;
 118
 119 : css-class ( style classes -- name )
 120     dup '[ drop _ assoc-size 1 + bijective-base26 ] cache ;
 121
 122 : fix-css-style ( style -- style' )
 123     R/ font-size: \d+pt;/ [
 124         "font-size: " ?head drop "pt;" ?tail drop
 125         string>number 2 -
 126         "font-size: %dpt;" sprintf
 127     ] re-replace-with
 128
 129     R/ padding: \d+px;/ [
 130         "padding: " ?head drop "px;" ?tail drop
 131         string>number dup even? [ 2 * 1 + ] [ 2 * ] if
 132         number>string "padding: " "px;" surround
 133     ] re-replace-with
 134
 135     R/ width: \d+px;/ [
 136        drop ""
 137     ] re-replace-with
 138
 139     R/ font-family: monospace;/ [
 140         " white-space: pre-wrap; line-height: 125%;" append
 141     ] re-replace-with
 142
 143     dup { "font-family: monospace;" "background-color:" } [ subsequence? ] with all? [
 144         " margin: 10px 0px;" append
 145     ] when
 146
 147     dup { "border:" "background-color:" } [ subsequence? ] with all? [
 148         " border-radius: 5px;" append
 149     ] when ;
 150
 151 : fix-help-header ( classes -- classes )
 152     dup [
 153         [ ".a" head? ] [ "#f4efd9;" subsequence? ] bi and
 154     ] find [
 155         "padding: 10px;" "padding: 0px;" replace
 156         "background-color: #f4efd9;" "background-color: white;" replace
 157         "}" ?tail drop
 158         " border-bottom: 1px dashed #ccc; width: 100%; padding-top: 15px; padding-bottom: 10px; }"
 159         append swap pick set-nth {
 160             ".a a { color: black; font-size: 24pt; line-height: 100%; }"
 161             ".a * a { color: #2a5db0; font-size: 12pt; }"
 162             ".a td { border: none; }"
 163             ".a tr:hover { background-color: white; }"
 164         } prepend
 165     ] [ drop ] if* ;
 166
 167 : dark-mode-css ( classes -- classes' )
 168     { "" "/* Dark mode */" "@media (prefers-color-scheme:dark) {" }
 169     swap [
 170         R/ {[^}]+}/ [
 171             "{" ?head drop "}" ?tail drop ";" split
 172             [ [ blank? ] trim ] map harvest [ ";" append ] map
 173             [ R/ (#[0-9a-fA-F]+|white|black);/ re-contains? ] filter
 174             [
 175                 R/ (#[0-9a-fA-F]+|white|black);/ [
 176                     >string H{
 177                         { "#000000;" "#bdc1c6;" }
 178                         { "#2a5db0;" "#8ab4f8;" }
 179                         { "#333333;" "#cccccc;" }
 180                         { "#373e48;" "#ffffff;" }
 181                         { "#8b4500;" "orange;" }
 182                         { "#e3e2db;" "#444444;" }
 183                         { "white;" "#202124;" }
 184                         { "black;" "white;" }
 185                     } ?at [
 186                         but-last parse-color inverse-color color>hex ";" append
 187                     ] unless
 188                 ] re-replace-with
 189             ] map " " join "{ " " }" surround
 190         ] re-replace-with "    " prepend
 191         dup "{  }" subsequence? [ drop f ] when
 192     ] map harvest append "}" suffix ;
 193
 194 : css-classes ( classes -- stylesheet )
 195     [
 196         [ fix-css-style " { " "}" surround ] [ "." prepend ] bi* prepend
 197     ] { } assoc>map fix-help-header dup dark-mode-css append join-lines ;
 198
 199 :: css-styles-to-classes ( body -- stylesheet body )
 200     H{ } clone :> classes
 201     body [
 202         dup xml-chunk? [
 203             seq>> [
 204                 dup {
 205                     [ tag? ]
 206                     [ "style" attr ]
 207                     [ "class" attr not ]
 208                 } 1&& [
 209                     [ clone [ V{ } like ] change-alist ] change-attrs
 210                     "style" over delete-at* drop classes css-class
 211                     "class" rot set-at
 212                 ] [ drop ] if
 213             ] deep-each
 214         ] [ drop ] if
 215     ] each classes sort-values css-classes body ;
 216
 217 : retina-image ( path -- path' )
 218     dup "@2x" subsequence? [ "." split1-last "@2x." glue ] unless ;
 219
 220 : ?copy-file ( from to -- )
 221     dup file-exists? [ 2drop ] [ copy-file ] if ;
 222
 223 : cache-images ( body -- body' )
 224     dup [
 225         dup xml-chunk? [
 226             seq>> [
 227                 T{ name { main "img" } } over tag-named? [
 228                     dup "src" attr
 229                     retina-image dup file-name
 230                     [ ?copy-file ] keep
 231                     "src" set-attr
 232                 ] [ drop ] if
 233             ] deep-each
 234         ] [ drop ] if
 235     ] each ;
 236
 237 : help>html ( topic -- xml )
 238     [ article-title " - Factor Documentation" append ]
 239     [
 240         [ print-topic ] with-html-writer
 241         css-styles-to-classes cache-images
 242         "resource:extra/websites/factorcode/favicon.ico" dup file-name ?copy-file
 243         [ help-stylesheet help-meta prepend help-navbar ] dip help-footer
 244         [XML <-><div class="page"><-><-></div> XML]
 245     ] bi simple-page ;
 246
 247 : generate-help-file ( topic -- )
 248     dup topic>filename utf8 [ help>html write-xml ] with-file-writer ;
 249
 250 : all-vocabs-really ( -- seq )
 251     all-disk-vocabs-recursive filter-vocabs
 252     [ vocab-name "scratchpad" = ] reject ;
 253
 254 : all-topics ( -- topics )
 255     [
 256         articles get keys [ >link ] map %
 257         all-words [ >link ] map %
 258         all-authors [ <vocab-author> ] map %
 259         all-tags [ <vocab-tag> ] map %
 260         all-vocabs-really %
 261     ] { } make ;
 262
 263 : serialize-index ( index file -- )
 264     binary [
 265         [ [ topic>filename ] dip ] { } assoc-map-as serialize
 266     ] with-file-writer ;
 267
 268 : generate-article-index ( -- )
 269     articles get [ [ >link ] [ article-title ] bi* ] assoc-map
 270     "articles.idx" serialize-index ;
 271
 272 : generate-word-index ( -- )
 273     all-words [ dup name>> ] { } map>assoc
 274     "words.idx" serialize-index ;
 275
 276 : generate-vocab-index ( -- )
 277     all-vocabs-really [ dup vocab-name ] { } map>assoc
 278     "vocabs.idx" serialize-index ;
 279
 280 : generate-indices ( -- )
 281     generate-article-index
 282     generate-word-index
 283     generate-vocab-index ;
 284
 285 : generate-help-files ( -- )
 286     H{
 287         { recent-searches f }
 288         { recent-words f }
 289         { recent-articles f }
 290         { recent-vocabs f }
 291     } [
 292         all-topics [ '[ _ generate-help-file ] try ] each
 293     ] with-variables ;
 294
 295 : generate-help ( -- )
 296     "docs" cache-file
 297     [ make-directories ]
 298     [
 299         [
 300             generate-indices
 301             generate-help-files
 302         ] with-directory
 303     ] bi ;
 304
 305 MEMO: load-index ( name -- index )
 306     binary file-contents bytes>object ;
 307
 308 : offline-apropos ( string index -- results )
 309     load-index completions ;
 310
 311 : article-apropos ( string -- results )
 312     "articles.idx" offline-apropos ;
 313
 314 : vocab-apropos ( string -- results )
 315     "vocabs.idx" offline-apropos ;
 316
 317 : generate-qualified-index ( index -- )
 318     H{ } clone [
 319         '[
 320             over "," split1 nip ".html" ?tail drop
 321             [ swap ":" glue 2array ] [ _ push-at ] bi
 322         ] assoc-each
 323     ] keep [ swap ] { } assoc-map-as
 324     "qualified.idx" binary [ serialize ] with-file-writer ;
 325
 326 : qualified-index ( str index -- str index' )
 327     over ":" split1 [
 328         "qualified.idx"
 329         dup file-exists? [ pick generate-qualified-index ] unless
 330         load-index completions keys concat
 331     ] [ drop f ] if [ append ] unless-empty ;
 332
 333 : word-apropos ( string -- results )
 334     "words.idx" load-index qualified-index completions ;