basis/help/html/html.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators.short-circuit
   4 debugger formatting fry help help.home help.topics help.vocabs
   5 html html.streams io.directories io.encodings.binary
   6 io.encodings.utf8 io.files io.files.temp io.pathnames kernel
   7 locals make math math.parser memoize namespaces regexp sequences
   8 sequences.deep serialize sorting splitting tools.completion
   9 vocabs vocabs.hierarchy words xml.data xml.syntax xml.traversal
  10 xml.writer ;
  11 FROM: io.encodings.ascii => ascii ;
  12 FROM: ascii => ascii? ;
  13 IN: help.html
  14
  15 : escape-char ( ch -- )
  16     dup ascii? [
  17         dup H{
  18             { CHAR: \" "__quo__" }
  19             { CHAR: * "__star__" }
  20             { CHAR: : "__colon__" }
  21             { CHAR: < "__lt__" }
  22             { CHAR: > "__gt__" }
  23             { CHAR: ? "__que__" }
  24             { CHAR: \\ "__back__" }
  25             { CHAR: | "__pipe__" }
  26             { CHAR: / "__slash__" }
  27             { CHAR: , "__comma__" }
  28             { CHAR: @ "__at__" }
  29             { CHAR: # "__hash__" }
  30             { CHAR: % "__percent__" }
  31         } at [ % ] [ , ] ?if
  32     ] [ number>string "__" "__" surround % ] if ;
  33
  34 : escape-filename ( string -- filename )
  35     [ [ escape-char ] each ] "" make ;
  36
  37 GENERIC: topic>filename* ( topic -- name prefix )
  38
  39 M: word topic>filename*
  40     dup vocabulary>> [
  41         [ name>> ] [ vocabulary>> ] bi 2array "word"
  42     ] [ drop f f ] if ;
  43
  44 M: link topic>filename* name>> dup [ "article" ] [ topic>filename* ] if ;
  45 M: word-link topic>filename* name>> topic>filename* ;
  46 M: vocab-spec topic>filename* vocab-name "vocab" ;
  47 M: vocab-tag topic>filename* name>> "tag" ;
  48 M: vocab-author topic>filename* name>> "author" ;
  49 M: f topic>filename* drop \ f topic>filename* ;
  50
  51 : topic>filename ( topic -- filename )
  52     topic>filename* [
  53         [
  54             % "-" %
  55             dup array?
  56             [ [ escape-filename ] map "," join ]
  57             [ escape-filename ]
  58             if % ".html" %
  59         ] "" make
  60     ] [ drop f ] if* ;
  61
  62 M: topic url-of topic>filename ;
  63
  64 M: pathname url-of
  65     string>> "resource:" ?head [
  66         "https://github.com/factor/factor/blob/master/"
  67         prepend
  68     ] [ drop f ] if ;
  69
  70 : help-stylesheet ( stylesheet -- xml )
  71     "vocab:help/html/stylesheet.css" ascii file-contents
  72     swap "\n" glue [XML <style><-></style> XML] ;
  73
  74 : help-meta ( -- xml )
  75     [XML <meta
  76             name="viewport"
  77             content="width=device-width, initial-scale=1"
  78         /> XML] ;
  79
  80 : help-navbar ( -- xml )
  81     "conventions" >link topic>filename
  82     [XML
  83         <div class="navbar">
  84         <a href="/">Handbook</a>
  85         <a href=<->>Glossary</a>
  86         <form method="get" action="/search" style="float: right;">
  87             <input placeholder="Search" name="search" type="text"/>
  88             <input type="submit" value="Go"/>
  89             <a href="//factorcode.org">factorcode.org</a>
  90         </form>
  91         </div>
  92      XML] ;
  93
  94 : bijective-base26 ( n -- name )
  95     [ dup 0 > ] [ 1 - 26 /mod CHAR: a + ] "" produce-as nip reverse! ;
  96
  97 : css-class ( style classes -- name )
  98     dup '[ drop _ assoc-size 1 + bijective-base26 ] cache ;
  99
 100 : css-style ( style -- style' )
 101     R/ font-size: \d+pt;/ [
 102         "font-size: " ?head drop "pt;" ?tail drop
 103         string>number 2 -
 104         "font-size: %dpt;" sprintf
 105     ] re-replace-with
 106
 107     R/ padding: \d+px;/ [
 108         "padding: " ?head drop "px;" ?tail drop
 109         string>number dup even? [ 2 * 1 + ] [ 2 * ] if
 110         number>string "padding: " "px;" surround
 111     ] re-replace-with
 112
 113     R/ width: \d+px;/ [
 114        drop ""
 115     ] re-replace-with
 116
 117     R/ font-family: monospace;/ [
 118         " white-space: pre-wrap; line-height: 125%;" append
 119     ] re-replace-with ;
 120
 121 : css-classes ( classes -- stylesheet )
 122     [
 123         [ css-style " { " "}" surround ] [ "." prepend ] bi* prepend
 124     ] { } assoc>map "\n" join ;
 125
 126 :: css-styles-to-classes ( body -- stylesheet body )
 127     H{ } clone :> classes
 128     body [
 129         dup xml-chunk? [
 130             seq>> [
 131                 dup {
 132                     [ tag? ]
 133                     [ "style" attr ]
 134                     [ "class" attr not ]
 135                 } 1&& [
 136                     [ clone [ V{ } like ] change-alist ] change-attrs
 137                     "style" over delete-at* drop classes css-class
 138                     "class" rot set-at
 139                 ] [ drop ] if
 140             ] deep-each
 141         ] [ drop ] if
 142     ] each classes sort-values css-classes body ;
 143
 144 : retina-image ( path -- path' )
 145     "@2x" over subseq? [ "." split1-last "@2x." glue ] unless ;
 146
 147 : ?copy-file ( from to -- )
 148     dup exists? [ 2drop ] [ copy-file ] if ;
 149
 150 : cache-images ( body -- body' )
 151     dup [
 152         dup xml-chunk? [
 153             seq>> [
 154                 T{ name { main "img" } } over tag-named? [
 155                     dup "src" attr
 156                     retina-image dup file-name
 157                     [ ?copy-file ] keep
 158                     "src" set-attr
 159                 ] [ drop ] if
 160             ] deep-each
 161         ] [ drop ] if
 162     ] each ;
 163
 164 : help>html ( topic -- xml )
 165     [ article-title " - Factor Documentation" append ]
 166     [
 167         [ print-topic ] with-html-writer
 168         css-styles-to-classes cache-images
 169         [ help-stylesheet help-meta prepend help-navbar ] dip
 170         [XML <div id="container"><-><div class="page"><-></div></div> XML]
 171     ] bi simple-page ;
 172
 173 : generate-help-file ( topic -- )
 174     dup topic>filename utf8 [ help>html write-xml ] with-file-writer ;
 175
 176 : all-vocabs-really ( -- seq )
 177     all-disk-vocabs-recursive filter-vocabs
 178     [ vocab-name "scratchpad" = ] reject ;
 179
 180 : all-topics ( -- topics )
 181     [
 182         articles get keys [ >link ] map %
 183         all-words [ >link ] map %
 184         all-authors [ <vocab-author> ] map %
 185         all-tags [ <vocab-tag> ] map %
 186         all-vocabs-really %
 187     ] { } make ;
 188
 189 : serialize-index ( index file -- )
 190     binary [
 191         [ [ topic>filename ] dip ] { } assoc-map-as serialize
 192     ] with-file-writer ;
 193
 194 : generate-article-index ( -- )
 195     articles get [ [ >link ] [ article-title ] bi* ] assoc-map
 196     "articles.idx" serialize-index ;
 197
 198 : generate-word-index ( -- )
 199     all-words [ dup name>> ] { } map>assoc
 200     "words.idx" serialize-index ;
 201
 202 : generate-vocab-index ( -- )
 203     all-vocabs-really [ dup vocab-name ] { } map>assoc
 204     "vocabs.idx" serialize-index ;
 205
 206 : generate-indices ( -- )
 207     generate-article-index
 208     generate-word-index
 209     generate-vocab-index ;
 210
 211 : generate-help-files ( -- )
 212     H{
 213         { recent-searches f }
 214         { recent-words f }
 215         { recent-articles f }
 216         { recent-vocabs f }
 217     } [
 218         all-topics [ '[ _ generate-help-file ] try ] each
 219     ] with-variables ;
 220
 221 : generate-help ( -- )
 222     "docs" cache-file
 223     [ make-directories ]
 224     [
 225         [
 226             generate-indices
 227             generate-help-files
 228         ] with-directory
 229     ] bi ;
 230
 231 MEMO: load-index ( name -- index )
 232     binary file-contents bytes>object ;
 233
 234 : offline-apropos ( string index -- results )
 235     load-index completions ;
 236
 237 : article-apropos ( string -- results )
 238     "articles.idx" offline-apropos ;
 239
 240 : word-apropos ( string -- results )
 241     "words.idx" offline-apropos ;
 242
 243 : vocab-apropos ( string -- results )
 244     "vocabs.idx" offline-apropos ;