basis/help/html/html.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs colors
   4 combinators.short-circuit debugger formatting help help.home
   5 help.topics help.vocabs html html.streams io.directories
   6 io.encodings.ascii io.encodings.binary io.encodings.utf8
   7 io.files io.files.temp io.pathnames kernel make math math.parser
   8 namespaces regexp sequences sequences.deep serialize sets
   9 sorting splitting strings system tools.completion vocabs
  10 vocabs.hierarchy words xml.data xml.syntax xml.traversal
  11 xml.writer ;
  12 FROM: io.encodings.ascii => ascii ;
  13 FROM: ascii => ascii? ;
  14 IN: help.html
  15
  16 : escape-char ( ch -- )
  17     dup ascii? [
  18         dup H{
  19             { CHAR: \" "__quo__" }
  20             { CHAR: * "__star__" }
  21             { CHAR: : "__colon__" }
  22             { CHAR: < "__lt__" }
  23             { CHAR: > "__gt__" }
  24             { CHAR: ? "__que__" }
  25             { CHAR: \\ "__back__" }
  26             { CHAR: | "__pipe__" }
  27             { CHAR: / "__slash__" }
  28             { CHAR: , "__comma__" }
  29             { CHAR: @ "__at__" }
  30             { CHAR: # "__hash__" }
  31             { CHAR: % "__percent__" }
  32         } at [ % ] [ , ] ?if
  33     ] [ number>string "__" "__" surround % ] if ;
  34
  35 : escape-filename ( string -- filename )
  36     [ [ escape-char ] each ] "" make ;
  37
  38 GENERIC: topic>filename* ( topic -- name prefix )
  39
  40 M: word topic>filename*
  41     dup vocabulary>> [
  42         [ name>> ] [ vocabulary>> ] bi 2array "word"
  43     ] [ drop f f ] if ;
  44
  45 M: link topic>filename* name>> dup [ "article" ] [ topic>filename* ] if ;
  46 M: word-link topic>filename* name>> topic>filename* ;
  47 M: vocab-spec topic>filename* vocab-name "vocab" ;
  48 M: vocab-tag topic>filename* name>> "tag" ;
  49 M: vocab-author topic>filename* name>> "author" ;
  50 M: f topic>filename* drop \ f topic>filename* ;
  51
  52 : topic>filename ( topic -- filename )
  53     topic>filename* [
  54         [
  55             % "-" %
  56             dup array?
  57             [ [ escape-filename ] map "," join ]
  58             [ escape-filename ]
  59             if % ".html" %
  60         ] "" make
  61     ] [ drop f ] if* ;
  62
  63 M: topic url-of topic>filename ;
  64
  65 M: pathname url-of
  66     string>> "resource:" ?head [
  67         "https://github.com/factor/factor/blob/master/"
  68         prepend
  69     ] [ drop f ] if ;
  70
  71 : help-stylesheet ( stylesheet -- xml )
  72     "vocab:help/html/stylesheet.css" ascii file-contents
  73     swap "\n" glue [XML <style><-></style> XML] ;
  74
  75 : help-meta ( -- xml )
  76     [XML <meta
  77             name="viewport"
  78             content="width=device-width, initial-scale=1"
  79             charset="utf-8"
  80         /> XML] ;
  81
  82 : help-navbar ( -- xml )
  83     "conventions" >link topic>filename
  84     [XML
  85         <div class="navbar">
  86             <div class="navrow">
  87                 <a href="https://factorcode.org">
  88                 <img src="favicon.ico" width="24" height="24" />
  89                 </a>
  90                 <a href="/">Handbook</a>
  91                 <a href=<->>Glossary</a>
  92                 <form method="get" action="/search" style="float: right;">
  93                     <input placeholder="Search" name="search" type="text"/>
  94                     <input type="submit" value="Go"/>
  95                 </form>
  96             </div>
  97         </div>
  98      XML] ;
  99
 100 : help-footer ( -- xml )
 101     version-info "\n" split1 drop
 102     [XML
 103         <div class="footer">
 104         <p>
 105         This documentation was generated offline from a
 106         <code>load-all</code> image.  If you want, you can also
 107         browse the documentation from within the <a
 108         href="article-ui-tools.html">UI developer tools</a>. See
 109         the <a href="https://factorcode.org">Factor website</a>
 110         for more information.
 111         </p>
 112         <p><-></p>
 113         </div>
 114     XML] ;
 115
 116 : bijective-base26 ( n -- name )
 117     [ dup 0 > ] [ 1 - 26 /mod CHAR: a + ] "" produce-as nip reverse! ;
 118
 119 : css-class ( style classes -- name )
 120     dup '[ drop _ assoc-size 1 + bijective-base26 ] cache ;
 121
 122 : fix-css-style ( style -- style' )
 123     R/ font-size: \d+pt;/ [
 124         "font-size: " ?head drop "pt;" ?tail drop
 125         string>number
 126         "font-size: %dpt;" sprintf
 127     ] re-replace-with
 128
 129     R/ padding: \d+px;/ [
 130         "padding: " ?head drop "px;" ?tail drop
 131         string>number dup even? [ 2 * 1 + ] [ 2 * ] if
 132         number>string "padding: " "px;" surround
 133     ] re-replace-with
 134
 135     R/ width: \d+px;/ [
 136        drop ""
 137     ] re-replace-with
 138
 139     R/ background-color: #f3f2ea;/ [
 140         drop "background-color: #f5f5f5;"
 141     ] re-replace-with
 142
 143     R/ font-family: monospace;/ [
 144         " border: 1px solid #ccc; border-radius: 5px; white-space: pre-wrap; line-height: 125%; margin: 15px; width: calc(100% - 30px);" append
 145     ] re-replace-with ;
 146
 147 : fix-help-header ( classes -- classes )
 148     dup [
 149         [ ".a" head? ] [ "#f4efd9;" swap subseq? ] bi and
 150     ] find [
 151         "padding: 10px;" "padding: 0px;" replace
 152         "background-color: #f4efd9;" "background-color: white;" replace
 153         "}" ?tail drop
 154         " border-bottom: 1px dashed #ccc; width: 100%; padding-top: 15px; padding-bottom: 10px; }"
 155         append swap pick set-nth {
 156             ".a a { color: black; font-size: 24pt; line-height: 100%; }"
 157             ".a * a { color: #2a5db0; font-size: 12pt; }"
 158             ".a td { border: none; }"
 159             ".a tr:hover { background-color: white; }"
 160         } prepend
 161     ] [ drop ] if* ;
 162
 163 : dark-mode-css ( classes -- classes' )
 164     { "/* Dark mode */" "@media (prefers-color-scheme:dark) {" }
 165     swap [
 166         R/ {[^}]+}/ [
 167             "{" ?head drop "}" ?tail drop ";" split
 168             [ [ blank? ] trim ] map harvest [ ";" append ] map
 169             [ R/ (#[0-9a-fA-F]+|white|black);/ re-contains? ] filter
 170             [
 171                 R/ (#[0-9a-fA-F]+|white|black);/ [
 172                     >string H{
 173                         { "#000000;" "#bdc1c6;" }
 174                         { "#2a5db0;" "#8ab4f8;" }
 175                         { "#333333;" "#cccccc;" }
 176                         { "#373e48;" "#ffffff;" }
 177                         { "#8b4500;" "orange;" }
 178                         { "#e3e2db;" "#666666;" }
 179                         { "white;" "#202124;" }
 180                         { "black;" "white;" }
 181                         { "#ccc;" "#666;" }
 182                     } ?at [
 183                         but-last parse-color inverse-color color>hex ";" append
 184                     ] unless
 185                 ] re-replace-with
 186             ] map " " join "{ " " }" surround
 187         ] re-replace-with "    " prepend
 188         "{  }" over subseq? [ drop f ] when
 189     ] map harvest append "}" suffix ;
 190
 191 : mobile-css ( classes -- classes' )
 192     { "/* Mobile */" "@media screen and (max-width: 600px) {" }
 193     swap [
 194         R/ {[^}]+}/ [
 195             "{" ?head drop "}" ?tail drop ";" split
 196             [ [ blank? ] trim ] map harvest [ ";" append ] map
 197             { "margin: 15px;" "width: calc(100% - 30px);" } intersect
 198             { "margin: 15px;" } { "margin: 15px 0px;" } replace
 199             { "width: calc(100% - 30px);" } { "width: 100%;" } replace
 200             " " join "{ " " }" surround
 201         ] re-replace-with "    " prepend
 202         "{  }" over subseq? [ drop f ] when
 203     ] map B harvest append "}" suffix ;
 204
 205 : css-classes ( classes -- stylesheet )
 206     [
 207         [ fix-css-style " { " "}" surround ] [ "." prepend ] bi* prepend
 208     ] { } assoc>map fix-help-header dup
 209     B [ dark-mode-css ] [ mobile-css ] bi 3append join-lines ;
 210
 211 :: css-styles-to-classes ( body -- stylesheet body )
 212     H{ } clone :> classes
 213     body [
 214         dup xml-chunk? [
 215             seq>> [
 216                 dup {
 217                     [ tag? ]
 218                     [ "style" attr ]
 219                     [ "class" attr not ]
 220                 } 1&& [
 221                     [ clone [ V{ } like ] change-alist ] change-attrs
 222                     "style" over delete-at* drop classes css-class
 223                     "class" rot set-at
 224                 ] [ drop ] if
 225             ] deep-each
 226         ] [ drop ] if
 227     ] each classes sort-values css-classes body ;
 228
 229 : retina-image ( path -- path' )
 230     "@2x" over subseq? [ "." split1-last "@2x." glue ] unless ;
 231
 232 : ?copy-file ( from to -- )
 233     dup file-exists? [ 2drop ] [ copy-file ] if ;
 234
 235 : cache-images ( body -- body' )
 236     dup [
 237         dup xml-chunk? [
 238             seq>> [
 239                 T{ name { main "img" } } over tag-named? [
 240                     dup "src" attr
 241                     retina-image dup file-name
 242                     [ ?copy-file ] keep
 243                     "src" set-attr
 244                 ] [ drop ] if
 245             ] deep-each
 246         ] [ drop ] if
 247     ] each ;
 248
 249 : help>html ( topic -- xml )
 250     [ article-title " - Factor Documentation" append ]
 251     [
 252         [ print-topic ] with-html-writer
 253         css-styles-to-classes cache-images
 254         "resource:extra/websites/factorcode/favicon.ico" dup file-name ?copy-file
 255         [ help-stylesheet help-meta prepend help-navbar ] dip help-footer
 256         [XML <-><div class="page"><-><-></div> XML]
 257     ] bi simple-page ;
 258
 259 : generate-help-file ( topic -- )
 260     dup topic>filename utf8 [ help>html write-xml ] with-file-writer ;
 261
 262 : all-vocabs-really ( -- seq )
 263     all-disk-vocabs-recursive filter-vocabs
 264     [ vocab-name "scratchpad" = ] reject ;
 265
 266 : all-topics ( -- topics )
 267     [
 268         articles get keys [ >link ] map %
 269         all-words [ >link ] map %
 270         all-authors [ <vocab-author> ] map %
 271         all-tags [ <vocab-tag> ] map %
 272         all-vocabs-really %
 273     ] { } make ;
 274
 275 : serialize-index ( index file -- )
 276     binary [
 277         [ [ topic>filename ] dip ] { } assoc-map-as serialize
 278     ] with-file-writer ;
 279
 280 : generate-article-index ( -- )
 281     articles get [ [ >link ] [ article-title ] bi* ] assoc-map
 282     "articles.idx" serialize-index ;
 283
 284 : generate-word-index ( -- )
 285     all-words [ dup name>> ] { } map>assoc
 286     "words.idx" serialize-index ;
 287
 288 : generate-vocab-index ( -- )
 289     all-vocabs-really [ dup vocab-name ] { } map>assoc
 290     "vocabs.idx" serialize-index ;
 291
 292 : generate-indices ( -- )
 293     generate-article-index
 294     generate-word-index
 295     generate-vocab-index ;
 296
 297 : generate-help-files ( -- )
 298     H{
 299         { recent-searches f }
 300         { recent-words f }
 301         { recent-articles f }
 302         { recent-vocabs f }
 303     } [
 304         all-topics [ '[ _ generate-help-file ] try ] each
 305     ] with-variables ;
 306
 307 : generate-help ( -- )
 308     "docs" cache-file
 309     [ make-directories ]
 310     [
 311         [
 312             generate-indices
 313             generate-help-files
 314         ] with-directory
 315     ] bi ;
 316
 317 MEMO: load-index ( name -- index )
 318     binary file-contents bytes>object ;
 319
 320 : offline-apropos ( string index -- results )
 321     load-index completions ;
 322
 323 : article-apropos ( string -- results )
 324     "articles.idx" offline-apropos ;
 325
 326 : vocab-apropos ( string -- results )
 327     "vocabs.idx" offline-apropos ;
 328
 329 : generate-qualified-index ( index -- )
 330     H{ } clone [
 331         '[
 332             over "," split1 nip ".html" ?tail drop
 333             [ swap ":" glue 2array ] [ _ push-at ] bi
 334         ] assoc-each
 335     ] keep [ swap ] { } assoc-map-as
 336     "qualified.idx" binary [ serialize ] with-file-writer ;
 337
 338 : qualified-index ( str index -- str index' )
 339     over ":" split1 [
 340         "qualified.idx"
 341         dup file-exists? [ pick generate-qualified-index ] unless
 342         load-index completions keys concat
 343     ] [ drop f ] if [ append ] unless-empty ;
 344
 345 : word-apropos ( string -- results )
 346     "words.idx" load-index qualified-index completions ;