basis/help/html/html.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators.short-circuit
   4 debugger formatting fry help help.home help.topics help.vocabs
   5 html html.streams io.directories io.encodings.binary
   6 io.encodings.utf8 io.files io.files.temp io.pathnames kernel
   7 locals make math math.parser memoize namespaces regexp sequences
   8 sequences.deep serialize sorting splitting tools.completion
   9 vocabs vocabs.hierarchy words xml.data xml.syntax xml.traversal
  10 xml.writer ;
  11 FROM: io.encodings.ascii => ascii ;
  12 FROM: ascii => ascii? ;
  13 IN: help.html
  14
  15 : escape-char ( ch -- )
  16     dup ascii? [
  17         dup H{
  18             { CHAR: \" "__quo__" }
  19             { CHAR: * "__star__" }
  20             { CHAR: : "__colon__" }
  21             { CHAR: < "__lt__" }
  22             { CHAR: > "__gt__" }
  23             { CHAR: ? "__que__" }
  24             { CHAR: \\ "__back__" }
  25             { CHAR: | "__pipe__" }
  26             { CHAR: / "__slash__" }
  27             { CHAR: , "__comma__" }
  28             { CHAR: @ "__at__" }
  29             { CHAR: # "__hash__" }
  30             { CHAR: % "__percent__" }
  31         } at [ % ] [ , ] ?if
  32     ] [ number>string "__" "__" surround % ] if ;
  33
  34 : escape-filename ( string -- filename )
  35     [ [ escape-char ] each ] "" make ;
  36
  37 GENERIC: topic>filename* ( topic -- name prefix )
  38
  39 M: word topic>filename*
  40     dup vocabulary>> [
  41         [ name>> ] [ vocabulary>> ] bi 2array "word"
  42     ] [ drop f f ] if ;
  43
  44 M: link topic>filename* name>> dup [ "article" ] [ topic>filename* ] if ;
  45 M: word-link topic>filename* name>> topic>filename* ;
  46 M: vocab-spec topic>filename* vocab-name "vocab" ;
  47 M: vocab-tag topic>filename* name>> "tag" ;
  48 M: vocab-author topic>filename* name>> "author" ;
  49 M: f topic>filename* drop \ f topic>filename* ;
  50
  51 : topic>filename ( topic -- filename )
  52     topic>filename* [
  53         [
  54             % "-" %
  55             dup array?
  56             [ [ escape-filename ] map "," join ]
  57             [ escape-filename ]
  58             if % ".html" %
  59         ] "" make
  60     ] [ drop f ] if* ;
  61
  62 M: topic url-of topic>filename ;
  63
  64 M: pathname url-of
  65     string>> "resource:" ?head [
  66         "https://github.com/factor/factor/blob/master/"
  67         prepend
  68     ] [ drop f ] if ;
  69
  70 : help-stylesheet ( stylesheet -- xml )
  71     "vocab:help/html/stylesheet.css" ascii file-contents
  72     swap "\n" glue [XML <style><-></style> XML] ;
  73
  74 : help-meta ( -- xml )
  75     [XML <meta
  76             name="viewport"
  77             content="width=device-width, initial-scale=1"
  78         /> XML] ;
  79
  80 : help-navbar ( -- xml )
  81     "conventions" >link topic>filename
  82     [XML
  83         <div class="navbar">
  84         <a href="/">Handbook</a>
  85         <a href=<->>Glossary</a>
  86         <form method="get" action="/search" style="display:inline;">
  87             <input placeholder="Search" name="search" type="text"/>
  88             <input type="submit" value="Go"/>
  89         </form>
  90         <div style="float: right;">
  91             <a href="//factorcode.org"><b>factorcode.org</b></a>
  92         </div>
  93         </div>
  94      XML] ;
  95
  96 : bijective-base26 ( n -- name )
  97     [ dup 0 > ] [ 1 - 26 /mod CHAR: a + ] "" produce-as nip reverse! ;
  98
  99 : css-class ( style classes -- name )
 100     dup '[ drop _ assoc-size 1 + bijective-base26 ] cache ;
 101
 102 : css-style ( style -- style' )
 103     R/ font-size: \d+pt;/ [
 104         "font-size: " ?head drop "pt;" ?tail drop
 105         string>number 2 -
 106         "font-size: %dpt;" sprintf
 107     ] re-replace-with
 108
 109     R/ padding: \d+px;/ [
 110         "padding: " ?head drop "px;" ?tail drop
 111         string>number dup even? [ 2 * 1 + ] [ 2 * ] if
 112         number>string "padding: " "px;" surround
 113     ] re-replace-with
 114
 115     R/ width: \d+px;/ [
 116        drop ""
 117     ] re-replace-with
 118
 119     R/ font-family: monospace;/ [
 120         " white-space: pre-wrap; line-height: 125%;" append
 121     ] re-replace-with ;
 122
 123 : css-classes ( classes -- stylesheet )
 124     [
 125         [ css-style " { " "}" surround ] [ "." prepend ] bi* prepend
 126     ] { } assoc>map "\n" join ;
 127
 128 :: css-styles-to-classes ( body -- stylesheet body )
 129     H{ } clone :> classes
 130     body [
 131         dup xml-chunk? [
 132             seq>> [
 133                 dup {
 134                     [ tag? ]
 135                     [ "style" attr ]
 136                     [ "class" attr not ]
 137                 } 1&& [
 138                     [ clone [ V{ } like ] change-alist ] change-attrs
 139                     "style" over delete-at* drop classes css-class
 140                     "class" rot set-at
 141                 ] [ drop ] if
 142             ] deep-each
 143         ] [ drop ] if
 144     ] each classes sort-values css-classes body ;
 145
 146 : img@2x ( body -- body' )
 147     dup [
 148         dup xml-chunk? [
 149             seq>> [
 150                 T{ name { main "img" } } over tag-named? [
 151                     dup "src" attr
 152
 153                     ! use @2x retina images
 154                     dup "@2x.png" tail? [
 155                         "." split1-last "@2x." glue
 156                     ] unless
 157
 158                     ! src mapping for webapps.help
 159                     "vocab:definitions/icons/" ?head
 160                     [ "/icons/" prepend ] when
 161
 162                     "src" set-attr
 163                 ] [ drop ] if
 164             ] deep-each
 165         ] [ drop ] if
 166     ] each ;
 167
 168 : help>html ( topic -- xml )
 169     [ article-title " - Factor Documentation" append ]
 170     [
 171         [ print-topic ] with-html-writer css-styles-to-classes img@2x
 172         [ help-stylesheet help-meta prepend help-navbar ] dip
 173         [XML <div id="container"><-><div class="page"><-></div></div> XML]
 174     ] bi simple-page ;
 175
 176 : generate-help-file ( topic -- )
 177     dup topic>filename utf8 [ help>html write-xml ] with-file-writer ;
 178
 179 : all-vocabs-really ( -- seq )
 180     all-disk-vocabs-recursive filter-vocabs
 181     [ vocab-name "scratchpad" = ] reject ;
 182
 183 : all-topics ( -- topics )
 184     [
 185         articles get keys [ >link ] map %
 186         all-words [ >link ] map %
 187         all-authors [ <vocab-author> ] map %
 188         all-tags [ <vocab-tag> ] map %
 189         all-vocabs-really %
 190     ] { } make ;
 191
 192 : serialize-index ( index file -- )
 193     binary [
 194         [ [ topic>filename ] dip ] { } assoc-map-as serialize
 195     ] with-file-writer ;
 196
 197 : generate-article-index ( -- )
 198     articles get [ [ >link ] [ article-title ] bi* ] assoc-map
 199     "articles.idx" serialize-index ;
 200
 201 : generate-word-index ( -- )
 202     all-words [ dup name>> ] { } map>assoc
 203     "words.idx" serialize-index ;
 204
 205 : generate-vocab-index ( -- )
 206     all-vocabs-really [ dup vocab-name ] { } map>assoc
 207     "vocabs.idx" serialize-index ;
 208
 209 : generate-indices ( -- )
 210     generate-article-index
 211     generate-word-index
 212     generate-vocab-index ;
 213
 214 : generate-help-files ( -- )
 215     H{
 216         { recent-searches f }
 217         { recent-words f }
 218         { recent-articles f }
 219         { recent-vocabs f }
 220     } [
 221         all-topics [ '[ _ generate-help-file ] try ] each
 222     ] with-variables ;
 223
 224 : generate-help ( -- )
 225     "docs" cache-file
 226     [ make-directories ]
 227     [
 228         [
 229             generate-indices
 230             generate-help-files
 231         ] with-directory
 232     ] bi ;
 233
 234 MEMO: load-index ( name -- index )
 235     binary file-contents bytes>object ;
 236
 237 : offline-apropos ( string index -- results )
 238     load-index completions ;
 239
 240 : article-apropos ( string -- results )
 241     "articles.idx" offline-apropos ;
 242
 243 : word-apropos ( string -- results )
 244     "words.idx" offline-apropos ;
 245
 246 : vocab-apropos ( string -- results )
 247     "vocabs.idx" offline-apropos ;