basis/help/html/html.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators.short-circuit
   4 debugger formatting fry help help.home help.topics help.vocabs
   5 html html.streams io.directories io.encodings.binary
   6 io.encodings.utf8 io.files io.files.temp io.pathnames kernel
   7 locals make math math.parser memoize namespaces regexp sequences
   8 sequences.deep serialize sorting splitting tools.completion
   9 vocabs vocabs.hierarchy words xml.data xml.syntax xml.traversal
  10 xml.writer ;
  11 FROM: io.encodings.ascii => ascii ;
  12 FROM: ascii => ascii? ;
  13 IN: help.html
  14
  15 : escape-char ( ch -- )
  16     dup ascii? [
  17         dup H{
  18             { CHAR: \" "__quo__" }
  19             { CHAR: * "__star__" }
  20             { CHAR: : "__colon__" }
  21             { CHAR: < "__lt__" }
  22             { CHAR: > "__gt__" }
  23             { CHAR: ? "__que__" }
  24             { CHAR: \\ "__back__" }
  25             { CHAR: | "__pipe__" }
  26             { CHAR: / "__slash__" }
  27             { CHAR: , "__comma__" }
  28             { CHAR: @ "__at__" }
  29             { CHAR: # "__hash__" }
  30             { CHAR: % "__percent__" }
  31         } at [ % ] [ , ] ?if
  32     ] [ number>string "__" "__" surround % ] if ;
  33
  34 : escape-filename ( string -- filename )
  35     [ [ escape-char ] each ] "" make ;
  36
  37 GENERIC: topic>filename* ( topic -- name prefix )
  38
  39 M: word topic>filename*
  40     dup vocabulary>> [
  41         [ name>> ] [ vocabulary>> ] bi 2array "word"
  42     ] [ drop f f ] if ;
  43
  44 M: link topic>filename* name>> dup [ "article" ] [ topic>filename* ] if ;
  45 M: word-link topic>filename* name>> topic>filename* ;
  46 M: vocab-spec topic>filename* vocab-name "vocab" ;
  47 M: vocab-tag topic>filename* name>> "tag" ;
  48 M: vocab-author topic>filename* name>> "author" ;
  49 M: f topic>filename* drop \ f topic>filename* ;
  50
  51 : topic>filename ( topic -- filename )
  52     topic>filename* [
  53         [
  54             % "-" %
  55             dup array?
  56             [ [ escape-filename ] map "," join ]
  57             [ escape-filename ]
  58             if % ".html" %
  59         ] "" make
  60     ] [ drop f ] if* ;
  61
  62 M: topic url-of topic>filename ;
  63
  64 M: pathname url-of
  65     string>> "resource:" ?head [
  66         "https://github.com/factor/factor/blob/master/"
  67         prepend
  68     ] [ drop f ] if ;
  69
  70 : help-stylesheet ( stylesheet -- xml )
  71     "vocab:help/html/stylesheet.css" ascii file-contents
  72     swap "\n" glue [XML <style><-></style> XML] ;
  73
  74 : help-meta ( -- xml )
  75     [XML <meta
  76             name="viewport"
  77             content="width=device-width, initial-scale=1"
  78             charset="utf-8"
  79         /> XML] ;
  80
  81 : help-navbar ( -- xml )
  82     "conventions" >link topic>filename
  83     [XML
  84         <div class="navbar">
  85         <a href="/">Handbook</a>
  86         <a href=<->>Glossary</a>
  87         <form method="get" action="/search" style="float: right;">
  88             <input placeholder="Search" name="search" type="text"/>
  89             <input type="submit" value="Go"/>
  90             <a href="//factorcode.org">factorcode.org</a>
  91         </form>
  92         </div>
  93      XML] ;
  94
  95 : bijective-base26 ( n -- name )
  96     [ dup 0 > ] [ 1 - 26 /mod CHAR: a + ] "" produce-as nip reverse! ;
  97
  98 : css-class ( style classes -- name )
  99     dup '[ drop _ assoc-size 1 + bijective-base26 ] cache ;
 100
 101 : fix-css-style ( style -- style' )
 102     R/ font-size: \d+pt;/ [
 103         "font-size: " ?head drop "pt;" ?tail drop
 104         string>number 2 -
 105         "font-size: %dpt;" sprintf
 106     ] re-replace-with
 107
 108     R/ padding: \d+px;/ [
 109         "padding: " ?head drop "px;" ?tail drop
 110         string>number dup even? [ 2 * 1 + ] [ 2 * ] if
 111         number>string "padding: " "px;" surround
 112     ] re-replace-with
 113
 114     R/ width: \d+px;/ [
 115        drop ""
 116     ] re-replace-with
 117
 118     R/ font-family: monospace;/ [
 119         " white-space: pre-wrap; line-height: 125%;" append
 120     ] re-replace-with ;
 121
 122 : fix-help-header ( classes -- classes )
 123     dup [
 124         [ ".a" head? ] [ "#f3f2ea;" swap subseq? ] bi and
 125     ] find [
 126         "background-color: #f3f2ea;" "background-color: #f5eed6;" replace
 127         "padding: 10px;" "padding: 15px;" replace
 128         "}" ?tail drop
 129         " border-bottom: 1px solid #ccc; width: calc(100% + 30px); margin: -15px; }"
 130         append swap pick set-nth
 131         ".a tr:hover { background-color: #f5eed6; }" prefix
 132     ] [ drop ] if* ;
 133
 134 : css-classes ( classes -- stylesheet )
 135     [
 136         [ fix-css-style " { " "}" surround ] [ "." prepend ] bi* prepend
 137     ] { } assoc>map fix-help-header join-lines ;
 138
 139 :: css-styles-to-classes ( body -- stylesheet body )
 140     H{ } clone :> classes
 141     body [
 142         dup xml-chunk? [
 143             seq>> [
 144                 dup {
 145                     [ tag? ]
 146                     [ "style" attr ]
 147                     [ "class" attr not ]
 148                 } 1&& [
 149                     [ clone [ V{ } like ] change-alist ] change-attrs
 150                     "style" over delete-at* drop classes css-class
 151                     "class" rot set-at
 152                 ] [ drop ] if
 153             ] deep-each
 154         ] [ drop ] if
 155     ] each classes sort-values css-classes body ;
 156
 157 : retina-image ( path -- path' )
 158     "@2x" over subseq? [ "." split1-last "@2x." glue ] unless ;
 159
 160 : ?copy-file ( from to -- )
 161     dup file-exists? [ 2drop ] [ copy-file ] if ;
 162
 163 : cache-images ( body -- body' )
 164     dup [
 165         dup xml-chunk? [
 166             seq>> [
 167                 T{ name { main "img" } } over tag-named? [
 168                     dup "src" attr
 169                     retina-image dup file-name
 170                     [ ?copy-file ] keep
 171                     "src" set-attr
 172                 ] [ drop ] if
 173             ] deep-each
 174         ] [ drop ] if
 175     ] each ;
 176
 177 : help>html ( topic -- xml )
 178     [ article-title " - Factor Documentation" append ]
 179     [
 180         [ print-topic ] with-html-writer
 181         css-styles-to-classes cache-images
 182         [ help-stylesheet help-meta prepend help-navbar ] dip
 183         [XML <div id="container"><-><div class="page"><-></div></div> XML]
 184     ] bi simple-page ;
 185
 186 : generate-help-file ( topic -- )
 187     dup topic>filename utf8 [ help>html write-xml ] with-file-writer ;
 188
 189 : all-vocabs-really ( -- seq )
 190     all-disk-vocabs-recursive filter-vocabs
 191     [ vocab-name "scratchpad" = ] reject ;
 192
 193 : all-topics ( -- topics )
 194     [
 195         articles get keys [ >link ] map %
 196         all-words [ >link ] map %
 197         all-authors [ <vocab-author> ] map %
 198         all-tags [ <vocab-tag> ] map %
 199         all-vocabs-really %
 200     ] { } make ;
 201
 202 : serialize-index ( index file -- )
 203     binary [
 204         [ [ topic>filename ] dip ] { } assoc-map-as serialize
 205     ] with-file-writer ;
 206
 207 : generate-article-index ( -- )
 208     articles get [ [ >link ] [ article-title ] bi* ] assoc-map
 209     "articles.idx" serialize-index ;
 210
 211 : generate-word-index ( -- )
 212     all-words [ dup name>> ] { } map>assoc
 213     "words.idx" serialize-index ;
 214
 215 : generate-vocab-index ( -- )
 216     all-vocabs-really [ dup vocab-name ] { } map>assoc
 217     "vocabs.idx" serialize-index ;
 218
 219 : generate-indices ( -- )
 220     generate-article-index
 221     generate-word-index
 222     generate-vocab-index ;
 223
 224 : generate-help-files ( -- )
 225     H{
 226         { recent-searches f }
 227         { recent-words f }
 228         { recent-articles f }
 229         { recent-vocabs f }
 230     } [
 231         all-topics [ '[ _ generate-help-file ] try ] each
 232     ] with-variables ;
 233
 234 : generate-help ( -- )
 235     "docs" cache-file
 236     [ make-directories ]
 237     [
 238         [
 239             generate-indices
 240             generate-help-files
 241         ] with-directory
 242     ] bi ;
 243
 244 MEMO: load-index ( name -- index )
 245     binary file-contents bytes>object ;
 246
 247 : offline-apropos ( string index -- results )
 248     load-index completions ;
 249
 250 : article-apropos ( string -- results )
 251     "articles.idx" offline-apropos ;
 252
 253 : word-apropos ( string -- results )
 254     "words.idx" offline-apropos ;
 255
 256 : vocab-apropos ( string -- results )
 257     "vocabs.idx" offline-apropos ;