basis/help/lint/checks/checks.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes classes.struct
   4 classes.tuple combinators combinators.short-circuit debugger
   5 definitions effects eval formatting fry grouping help
   6 help.markup help.topics io io.streams.string kernel macros math
   7 namespaces sequences sequences.deep sets splitting strings
   8 summary tools.destructors unicode.categories vocabs
   9 vocabs.loader words words.constant words.symbol ;
  10 FROM: sets => members ;
  11 IN: help.lint.checks
  12
  13 ERROR: simple-lint-error message ;
  14
  15 M: simple-lint-error summary message>> ;
  16
  17 M: simple-lint-error error. summary print ;
  18
  19 SYMBOL: vocabs-quot
  20 SYMBOL: all-vocabs
  21 SYMBOL: vocab-articles
  22
  23 : check-example ( element -- )
  24     [
  25         '[
  26             _ rest [
  27                 but-last "\n" join
  28                 [ (eval>string) ] call( code -- output )
  29                 "\n" ?tail drop
  30             ] keep
  31             last assert=
  32         ] vocabs-quot get call( quot -- )
  33     ] leaks members length [
  34         "%d disposable(s) leaked in example" sprintf simple-lint-error
  35     ] unless-zero ;
  36
  37 : check-examples ( element -- )
  38     \ $example swap elements [ check-example ] each ;
  39
  40 : extract-values ( element -- seq )
  41     \ $values swap elements
  42     [ f ] [ first rest keys ] if-empty ;
  43
  44 : extract-value-effects ( element -- seq )
  45     \ $values swap elements [ f ] [
  46         first rest [
  47             \ $quotation swap elements [ f ] [
  48                 first second dup effect? [ effect>string ] when
  49             ] if-empty
  50         ] map
  51     ] if-empty ;
  52
  53 : effect-values ( word -- seq )
  54     stack-effect
  55     [ in>> ] [ out>> ] bi append
  56     [ dup pair? [ first ] when effect>string ] map members ;
  57
  58 : effect-effects ( word -- seq )
  59     stack-effect in>> [
  60         dup pair?
  61         [ second dup effect? [ effect>string ] [ drop f ] if ]
  62         [ drop f ] if
  63     ] map ;
  64
  65 : contains-funky-elements? ( element -- ? )
  66     {
  67         $shuffle
  68         $complex-shuffle
  69         $values-x/y
  70         $predicate
  71         $class-description
  72         $error-description
  73     } swap '[ _ elements empty? not ] any? ;
  74
  75 : don't-check-word? ( word -- ? )
  76     {
  77         [ macro? ]
  78         [ symbol? ]
  79         [ parsing-word? ]
  80         [ "declared-effect" word-prop not ]
  81         [ constant? ]
  82     } 1|| ;
  83
  84 : skip-check-values? ( word element -- ? )
  85     [ don't-check-word? ] [ contains-funky-elements? ] bi* or ;
  86
  87 : check-values ( word element -- )
  88     2dup skip-check-values? [ 2drop ] [
  89         [ effect-values ] [ extract-values ] bi* 2dup
  90         sequence= [ 2drop ] [
  91             "$values don't match stack effect; expected %u, got %u" sprintf
  92             simple-lint-error
  93         ] if
  94     ] if ;
  95
  96 : check-value-effects ( word element -- )
  97     [ effect-effects ] [ extract-value-effects ] bi*
  98     [ 2dup and [ = ] [ 2drop t ] if ] 2all? [
  99         "$quotation stack effects in $values don't match"
 100         simple-lint-error
 101     ] unless ;
 102
 103 : check-nulls ( element -- )
 104     \ $values swap elements
 105     null swap deep-member?
 106     [ "$values should not contain null" simple-lint-error ] when ;
 107
 108 : check-see-also ( element -- )
 109     \ $see-also swap elements [ rest all-unique? ] all?
 110     [ "$see-also are not unique" simple-lint-error ] unless ;
 111
 112 : vocab-exists? ( name -- ? )
 113     [ lookup-vocab ] [ all-vocabs get member? ] bi or ;
 114
 115 : check-modules ( element -- )
 116     \ $vocab-link swap elements [
 117         second
 118         vocab-exists? [
 119             "$vocab-link to non-existent vocabulary"
 120             simple-lint-error
 121         ] unless
 122     ] each ;
 123
 124 : check-rendering ( element -- )
 125     [ print-content ] with-string-writer drop ;
 126
 127 : check-strings ( str -- )
 128     [
 129         "\n\t" intersects? [
 130             "Paragraph text should not contain \\n or \\t"
 131             simple-lint-error
 132         ] when
 133     ] [
 134         "  " swap subseq? [
 135             "Paragraph text should not contain double spaces"
 136             simple-lint-error
 137         ] when
 138     ] bi ;
 139
 140 : check-whitespace ( str1 str2 -- )
 141     [ " " tail? ] [ " " head? ] bi* or
 142     [ "Missing whitespace between strings" simple-lint-error ] unless ;
 143
 144 : check-bogus-nl ( element -- )
 145     { { $nl } { { $nl } } } [ head? ] with any? [
 146         "Simple element should not begin with a paragraph break"
 147         simple-lint-error
 148     ] when ;
 149
 150 : extract-slots ( elements -- seq )
 151     [ dup pair? [ first \ $slot = ] [ drop f ] if ] deep-filter
 152     [ second ] map ;
 153
 154 : check-class-description ( word element -- )
 155     \ $class-description swap elements over class? [
 156         [
 157             dup struct-class? [ struct-slots ] [ all-slots ] if
 158             [ name>> ] map
 159         ] [ extract-slots ] bi*
 160         [ swap member? ] with reject [
 161             ", " join "Described $slot does not exist: " prepend
 162             simple-lint-error
 163         ] unless-empty
 164     ] [
 165         nip empty? not [
 166             "A word that is not a class has a $class-description"
 167             simple-lint-error
 168         ] when
 169     ] if ;
 170
 171 : check-article-title ( article -- )
 172     article-title first LETTER?
 173     [ "Article title must begin with a capital letter" simple-lint-error ] unless ;
 174
 175 : check-elements ( element -- )
 176     {
 177         [ check-bogus-nl ]
 178         [ [ string? ] filter [ check-strings ] each ]
 179         [ [ simple-element? ] filter [ check-elements ] each ]
 180         [ 2 <clumps> [ [ string? ] all? ] filter [ first2 check-whitespace ] each ]
 181     } cleave ;
 182
 183 : check-descriptions ( element -- )
 184     { $description $class-description $var-description }
 185     swap '[
 186         _ elements [
 187             rest { { } { "" } } member?
 188             [ "Empty $description" simple-lint-error ] when
 189         ] each
 190     ] each ;
 191
 192 : check-markup ( element -- )
 193     {
 194         [ check-elements ]
 195         [ check-rendering ]
 196         [ check-examples ]
 197         [ check-modules ]
 198         [ check-descriptions ]
 199     } cleave ;
 200
 201 : files>vocabs ( -- assoc )
 202     vocabs
 203     [ [ [ vocab-docs-path ] keep ] H{ } map>assoc ]
 204     [ [ [ vocab-source-path ] keep ] H{ } map>assoc ]
 205     bi assoc-union ;
 206
 207 : group-articles ( -- assoc )
 208     articles get keys
 209     files>vocabs
 210     H{ } clone [
 211         '[
 212             dup >link where dup
 213             [ first _ at _ push-at ] [ 2drop ] if
 214         ] each
 215     ] keep ;
 216
 217 : all-word-help ( words -- seq )
 218     [ word-help ] filter ;