basis/help/lint/checks/checks.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes classes.tuple combinators
   4 combinators.short-circuit debugger definitions effects eval
   5 formatting fry grouping help help.markup help.topics io
   6 io.streams.string kernel macros namespaces sequences
   7 sequences.deep sets splitting strings summary unicode.categories
   8 vocabs vocabs.loader words words.constant words.symbol ;
   9 FROM: sets => members ;
  10 IN: help.lint.checks
  11
  12 ERROR: simple-lint-error message ;
  13
  14 M: simple-lint-error summary message>> ;
  15
  16 M: simple-lint-error error. summary print ;
  17
  18 SYMBOL: vocabs-quot
  19 SYMBOL: all-vocabs
  20 SYMBOL: vocab-articles
  21
  22 : check-example ( element -- )
  23     ! [
  24         '[
  25             _ rest [
  26                 but-last "\n" join
  27                 [ (eval>string) ] call( code -- output )
  28                 "\n" ?tail drop
  29             ] keep
  30             last assert=
  31         ] vocabs-quot get call( quot -- ) ;
  32     ! ] leaks members length [
  33     !     "%d disposable(s) leaked in example" sprintf simple-lint-error
  34     ! ] unless-zero ;
  35
  36 : check-examples ( element -- )
  37     \ $example swap elements [ check-example ] each ;
  38
  39 : extract-values ( element -- seq )
  40     \ $values swap elements
  41     [ f ] [ first rest keys ] if-empty ;
  42
  43 : extract-value-effects ( element -- seq )
  44     \ $values swap elements [ f ] [
  45         first rest [
  46             \ $quotation swap elements [ f ] [
  47                 first second dup effect? [ effect>string ] when
  48             ] if-empty
  49         ] map
  50     ] if-empty ;
  51
  52 : effect-values ( word -- seq )
  53     stack-effect
  54     [ in>> ] [ out>> ] bi append
  55     [ dup pair? [ first ] when effect>string ] map members ;
  56
  57 : effect-effects ( word -- seq )
  58     stack-effect in>> [
  59         dup pair?
  60         [ second dup effect? [ effect>string ] [ drop f ] if ]
  61         [ drop f ] if
  62     ] map ;
  63
  64 : contains-funky-elements? ( element -- ? )
  65     {
  66         $shuffle
  67         $complex-shuffle
  68         $values-x/y
  69         $predicate
  70         $class-description
  71         $error-description
  72     } swap '[ _ elements empty? not ] any? ;
  73
  74 : don't-check-word? ( word -- ? )
  75     {
  76         [ macro? ]
  77         [ symbol? ]
  78         [ parsing-word? ]
  79         [ "declared-effect" word-prop not ]
  80         [ constant? ]
  81     } 1|| ;
  82
  83 : skip-check-values? ( word element -- ? )
  84     [ don't-check-word? ] [ contains-funky-elements? ] bi* or ;
  85
  86 : check-values ( word element -- )
  87     2dup skip-check-values? [ 2drop ] [
  88         [ effect-values ] [ extract-values ] bi* 2dup
  89         sequence= [ 2drop ] [
  90             "$values don't match stack effect; expected %u, got %u" sprintf
  91             simple-lint-error
  92         ] if
  93     ] if ;
  94
  95 : check-value-effects ( word element -- )
  96     [ effect-effects ]
  97     [ extract-value-effects ]
  98     bi* [ 2dup and [ = ] [ 2drop t ] if ] 2all?
  99     [ "$quotation documentation in $values don't match stack effect" simple-lint-error ]
 100     unless ;
 101
 102 : check-nulls ( element -- )
 103     \ $values swap elements
 104     null swap deep-member?
 105     [ "$values should not contain null" simple-lint-error ] when ;
 106
 107 : check-see-also ( element -- )
 108     \ $see-also swap elements [
 109         rest all-unique? t assert=
 110     ] each ;
 111
 112 : vocab-exists? ( name -- ? )
 113     [ lookup-vocab ] [ all-vocabs get member? ] bi or ;
 114
 115 : check-modules ( element -- )
 116     \ $vocab-link swap elements [
 117         second
 118         vocab-exists? [
 119             "$vocab-link to non-existent vocabulary"
 120             simple-lint-error
 121         ] unless
 122     ] each ;
 123
 124 : check-rendering ( element -- )
 125     [ print-content ] with-string-writer drop ;
 126
 127 : check-strings ( str -- )
 128     [
 129         "\n\t" intersects? [
 130             "Paragraph text should not contain \\n or \\t"
 131             simple-lint-error
 132         ] when
 133     ] [
 134         "  " swap subseq? [
 135             "Paragraph text should not contain double spaces"
 136             simple-lint-error
 137         ] when
 138     ] bi ;
 139
 140 : check-whitespace ( str1 str2 -- )
 141     [ " " tail? ] [ " " head? ] bi* or
 142     [ "Missing whitespace between strings" simple-lint-error ] unless ;
 143
 144 : check-bogus-nl ( element -- )
 145     { { $nl } { { $nl } } } [ head? ] with any? [
 146         "Simple element should not begin with a paragraph break"
 147         simple-lint-error
 148     ] when ;
 149
 150 : extract-slots ( elements -- seq )
 151     [ dup pair? [ first \ $slot = ] [ drop f ] if ] deep-filter
 152     [ second ] map ;
 153
 154 : check-class-description ( word element -- )
 155     \ $class-description swap elements over class? [
 156         [ all-slots [ name>> ] map ] [ extract-slots ] bi*
 157         [ swap member? not ] with filter [
 158             ", " join "Described $slot does not exist: " prepend
 159             simple-lint-error
 160         ] unless-empty
 161     ] [
 162         nip empty? not [
 163             "A word that is not a class has a $class-description"
 164             simple-lint-error
 165         ] when
 166     ] if ;
 167
 168 : check-article-title ( article -- )
 169     article-title first LETTER?
 170     [ "Article title must begin with a capital letter" simple-lint-error ] unless ;
 171
 172 : check-elements ( element -- )
 173     {
 174         [ check-bogus-nl ]
 175         [ [ string? ] filter [ check-strings ] each ]
 176         [ [ simple-element? ] filter [ check-elements ] each ]
 177         [ 2 <clumps> [ [ string? ] all? ] filter [ first2 check-whitespace ] each ]
 178     } cleave ;
 179
 180 : check-descriptions ( element -- )
 181     { $description $class-description $var-description }
 182     swap '[
 183         _ elements [
 184             rest { { } { "" } } member?
 185             [ "Empty $description" simple-lint-error ] when
 186         ] each
 187     ] each ;
 188
 189 : check-markup ( element -- )
 190     {
 191         [ check-elements ]
 192         [ check-rendering ]
 193         [ check-examples ]
 194         [ check-modules ]
 195         [ check-descriptions ]
 196     } cleave ;
 197
 198 : files>vocabs ( -- assoc )
 199     vocabs
 200     [ [ [ vocab-docs-path ] keep ] H{ } map>assoc ]
 201     [ [ [ vocab-source-path ] keep ] H{ } map>assoc ]
 202     bi assoc-union ;
 203
 204 : group-articles ( -- assoc )
 205     articles get keys
 206     files>vocabs
 207     H{ } clone [
 208         '[
 209             dup >link where dup
 210             [ first _ at _ push-at ] [ 2drop ] if
 211         ] each
 212     ] keep ;
 213
 214 : all-word-help ( words -- seq )
 215     [ word-help ] filter ;