basis/help/lint/lint.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs continuations fry help help.lint.checks
   4 help.topics io kernel namespaces parser sequences
   5 source-files.errors vocabs.hierarchy vocabs words classes
   6 locals tools.errors listener ;
   7 FROM: help.lint.checks => all-vocabs ;
   8 FROM: vocabs => child-vocabs ;
   9 IN: help.lint
  10
  11 SYMBOL: lint-failures
  12
  13 lint-failures [ H{ } clone ] initialize
  14
  15 TUPLE: help-lint-error < source-file-error ;
  16
  17 SYMBOL: +help-lint-failure+
  18
  19 T{ error-type
  20    { type +help-lint-failure+ }
  21    { word ":lint-failures" }
  22    { plural "help lint failures" }
  23    { icon "vocab:ui/tools/error-list/icons/help-lint-error.tiff" }
  24    { quot [ lint-failures get values ] }
  25    { forget-quot [ lint-failures get delete-at ] }
  26 } define-error-type
  27
  28 M: help-lint-error error-type drop +help-lint-failure+ ;
  29
  30 <PRIVATE
  31
  32 : <help-lint-error> ( error topic -- help-lint-error )
  33     \ help-lint-error <definition-error> ;
  34
  35 PRIVATE>
  36
  37 : help-lint-error ( error topic -- )
  38     lint-failures get pick
  39     [ [ [ <help-lint-error> ] keep ] dip set-at ] [ delete-at drop ] if
  40     notify-error-observers ;
  41
  42 <PRIVATE
  43
  44 :: check-something ( topic quot -- )
  45     [ quot call( -- ) f ] [ ] recover
  46     topic help-lint-error ; inline
  47
  48 : check-word ( word -- )
  49     [ with-file-vocabs ] vocabs-quot set
  50     dup word-help [
  51         [ >link ] keep '[
  52             _ dup word-help
  53             [ check-values ]
  54             [ check-class-description ]
  55             [ nip [ check-nulls ] [ check-see-also ] [ check-markup ] tri ] 2tri
  56         ] check-something
  57     ] [ drop ] if ;
  58
  59 : check-article ( article -- )
  60     [ with-interactive-vocabs ] vocabs-quot set
  61     >link dup '[
  62         _
  63         [ check-article-title ]
  64         [ article-content check-markup ] bi
  65     ] check-something ;
  66
  67 : check-about ( vocab -- )
  68     vocab-link boa dup
  69     '[ _ vocab-help [ article drop ] when* ] check-something ;
  70
  71 : check-vocab ( vocab -- )
  72     "Checking " write dup write "..." print
  73     [ check-about ]
  74     [ words [ check-word ] each ]
  75     [ vocab-articles get at [ check-article ] each ]
  76     tri ;
  77
  78 PRIVATE>
  79
  80 : help-lint ( prefix -- )
  81     [
  82         auto-use? off
  83         all-vocab-names all-vocabs set
  84         group-articles vocab-articles set
  85         child-vocabs
  86         [ check-vocab ] each
  87     ] with-scope ;
  88
  89 : help-lint-all ( -- ) "" help-lint ;
  90
  91 : :lint-failures ( -- ) lint-failures get values errors. ;
  92
  93 : unlinked-words ( words -- seq )
  94     all-word-help [ article-parent not ] filter ;
  95
  96 : linked-undocumented-words ( -- seq )
  97     all-words
  98     [ word-help not ] filter
  99     [ article-parent ] filter
 100     [ predicate? not ] filter ;
 101
 102 MAIN: help-lint