basis/help/syntax/syntax.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii combinators
   4 combinators.short-circuit compiler.units definitions help
   5 help.markup help.topics kernel lexer math namespaces parser
   6 sequences splitting strings vocabs.parser words ;
   7 IN: help.syntax
   8
   9 <PRIVATE
  10
  11 :: parse-help-token ( -- str/obj/f )
  12     ?scan-token dup search {
  13         { [ dup \ } eq? ] [ 2drop f ] }
  14         { [ dup parsing-word? ] [
  15             nip V{ } clone swap execute-parsing first
  16             dup wrapper? [ wrapped>> \ $link swap 2array ] when ] }
  17         [ drop ]
  18     } cond ;
  19
  20 : push-help-text ( accum sbuf obj -- accum sbuf' )
  21     [ dup empty? [ >string suffix! SBUF" " clone ] unless ]
  22     [ [ suffix! ] curry dip ] bi* ;
  23
  24 : push-help-space ( accum sbuf -- accum sbuf )
  25     {
  26         [ dup empty? not ]
  27         [ over empty? not pick ?last \ $nl eq? not and ]
  28     } 0|| [ CHAR: \s suffix! ] when ;
  29
  30 :: parse-help-text ( -- seq )
  31     V{ } clone SBUF" " clone [
  32         lexer get line>> parse-help-token [
  33             lexer get line>> swap - 1 > [
  34                 \ $nl push-help-text
  35             ] when
  36         ] dip [
  37             [
  38                 dup string? [
  39                     dup ?first ".,;:" member? [
  40                         [ push-help-space ] dip
  41                     ] unless append!
  42                 ] [
  43                     [ push-help-space ]
  44                     [ push-help-text ] bi*
  45                 ] if
  46             ] when*
  47         ] keep
  48     ] loop [ >string suffix! ] unless-empty >array ; inline
  49
  50 : parse-help-values ( -- seq )
  51     [ scan-token dup "}" = not ] [
  52         dup "{" = [
  53             parse-datum dup parsing-word?
  54             [ V{ } clone swap execute-parsing first ] when
  55         ] [
  56             ":" ?tail drop scan-object 2array
  57         ] if
  58     ] produce nip ;
  59
  60 : example-lines ( seq -- seq' )
  61     dup string? [ string-lines [ [ blank? ] trim ] map harvest ] when ;
  62
  63 : make-example ( str type -- seq )
  64     over string? [
  65         [ example-lines ] [ prefix ] bi*
  66     ] [ drop ] if ;
  67
  68 : parse-help-examples ( -- seq )
  69     \ } parse-until [ \ $example make-example ] { } map-as ;
  70
  71 : parse-help-example ( -- seq )
  72     \ } parse-until dup { [ length 1 = ] [ first string? ] } 1&&
  73     [ first example-lines ] when ;
  74
  75 : help-text? ( word -- ? )
  76     {
  77         $description $snippet $emphasis $strong $url $heading
  78         $subheading $code $syntax $class-description
  79         $error-description $var-description $contract $notes
  80         $curious $deprecated $errors $side-effects $content
  81         $slot $image
  82     } member-eq? ;
  83
  84 : help-values? ( word -- ? )
  85     { $values $inputs $outputs } member-eq? ;
  86
  87 : help-examples? ( word -- ? )
  88     { $examples } member-eq? ;
  89
  90 : help-example? ( word -- ? )
  91     { $example $unchecked-example } member-eq? ;
  92
  93 PRIVATE>
  94
  95 SYNTAX: HELP{
  96     scan-word dup \ } eq? [ drop { } ] [
  97         {
  98             { [ dup help-text? ] [ parse-help-text ] }
  99             { [ dup help-values? ] [ parse-help-values ] }
 100             { [ dup help-example? ] [ parse-help-example ] }
 101             { [ dup help-examples? ] [ parse-help-examples ] }
 102             [ \ } parse-until >array ]
 103         } cond swap prefix
 104     ] if suffix! ;
 105
 106 SYNTAX: HELP:
 107     H{ { "{" POSTPONE: HELP{ } } [
 108         scan-word bootstrap-word
 109         [ >link save-location ]
 110         [ [ parse-array-def ] dip set-word-help ]
 111         bi
 112     ] with-words ;
 113
 114 ERROR: article-expects-name-and-title got ;
 115
 116 SYNTAX: ARTICLE:
 117     location [
 118         parse-array-def
 119         dup length 2 < [ article-expects-name-and-title ] when
 120         [ first2 ] [ 2 tail ] bi <article>
 121         over add-article >link
 122     ] dip remember-definition ;
 123
 124 SYNTAX: ABOUT:
 125     current-vocab scan-object >>help changed-definition ;