basis/help/syntax/syntax.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii combinators
   4 combinators.short-circuit compiler.units definitions help
   5 help.markup help.topics kernel lexer math namespaces parser
   6 sequences splitting strings strings.parser vocabs.parser words ;
   7 IN: help.syntax
   8
   9 <PRIVATE
  10
  11 :: parse-help-token ( end -- str/obj/f )
  12     ?scan-token dup {
  13         [ "syntax" lookup-word ]
  14         [ "help.markup" lookup-word ]
  15         [ dup ?last ":{[(" member-eq? [ search ] [ drop f ] if ]
  16     } 1|| {
  17         { [ dup not ] [ drop ] }
  18         { [ dup end eq? ] [ 2drop f ] }
  19         { [ dup parsing-word? ] [
  20             nip V{ } clone swap execute-parsing first
  21             dup wrapper? [ wrapped>> \ $link swap 2array ] when ] }
  22         { [ dup ] [ nip ] }
  23     } cond ;
  24
  25 : push-help-text ( accum sbuf obj -- accum sbuf' )
  26     [ dup empty? [ >string suffix! SBUF" " clone ] unless ]
  27     [ [ suffix! ] curry dip ] bi* ;
  28
  29 : help-block? ( word -- ? )
  30     {
  31         $description $heading $subheading $syntax
  32         $class-description $error-description $var-description
  33         $contract $notes $curious $deprecated $errors
  34         $side-effects $content $warning $subsections $nl
  35         $list $table $example $unchecked-example $code
  36     } member-eq? ;
  37
  38 : push-help-space ( accum sbuf -- accum sbuf )
  39     dup empty? [
  40         over empty? not
  41         pick ?last dup array? [ ?first ] when
  42         help-block? not and
  43     ] [
  44         dup last CHAR: \s eq? not
  45     ] if [ CHAR: \s suffix! ] when ;
  46
  47 :: parse-help-text ( end -- seq )
  48     V{ } clone SBUF" " clone [
  49         lexer get line>> :> m
  50         end parse-help-token :> obj
  51         lexer get line>> :> n
  52
  53         obj string? n m - 1 > and [
  54             { [ dup empty? not ] [ over ?last string? ] } 0||
  55             [ \ $nl push-help-text ] when
  56         ] when
  57
  58         obj [
  59             [
  60                 dup string? [
  61                     dup ?first " .,;:" member? [
  62                         [ push-help-space ] dip
  63                     ] unless append!
  64                 ] [
  65                     [ push-help-space ]
  66                     [ push-help-text ] bi*
  67                 ] if
  68             ] when*
  69         ] keep
  70     ] loop [ >string suffix! ] unless-empty >array ; inline
  71
  72 : parse-help-values ( -- seq )
  73     [ scan-token dup "}" = not ] [
  74         dup "{" = [
  75             drop \ } parse-until >array
  76         ] [
  77             ":" ?tail drop scan-object 2array
  78         ] if
  79     ] produce nip ;
  80
  81 : code-lines ( str -- seq )
  82     string-lines [ [ blank? ] trim ] map harvest ;
  83
  84 : make-example ( seq -- seq )
  85     dup string? [
  86         code-lines
  87         dup { [ array? ] [ length 1 > ] } 1&& [
  88             dup length 1 - over [ unescape-string ] change-nth
  89             \ $example prefix
  90         ] when
  91     ] when ;
  92
  93 : parse-help-examples ( -- seq )
  94     \ } parse-until [ make-example ] { } map-as ;
  95
  96 : parse-help-code ( -- seq )
  97     \ } parse-until dup { [ length 1 = ] [ first string? ] } 1&&
  98     [ first code-lines ] [ >array ] if ;
  99
 100 : help-text? ( word -- ? )
 101     {
 102         $description $snippet $emphasis $strong $url $heading
 103         $subheading $syntax $class-description
 104         $error-description $var-description $contract $notes
 105         $curious $deprecated $errors $side-effects $content
 106         $slot $image $warning
 107     } member-eq? ;
 108
 109 : help-code? ( word -- ? )
 110     { $example $unchecked-example $code } member-eq? ;
 111
 112 : help-values? ( word -- ? )
 113     { $values $inputs $outputs } member-eq? ;
 114
 115 : help-examples? ( word -- ? )
 116     { $examples } member-eq? ;
 117
 118 PRIVATE>
 119
 120 SYNTAX: HELP{
 121     scan-object dup \ } eq? [ drop { } ] [
 122         {
 123             { [ dup help-text? ] [ \ } parse-help-text ] }
 124             { [ dup help-code? ] [ parse-help-code ] }
 125             { [ dup help-values? ] [ parse-help-values ] }
 126             { [ dup help-examples? ] [ parse-help-examples ] }
 127             [ \ } parse-until >array ]
 128         } cond swap prefix
 129     ] if suffix! ;
 130
 131 SYNTAX: HELP:
 132     H{ { "{" POSTPONE: HELP{ } } [
 133         scan-word bootstrap-word
 134         [ >link save-location ]
 135         [ [ parse-array-def ] dip set-word-help ]
 136         bi
 137     ] with-words ;
 138
 139 SYNTAX: ARTICLE:
 140     location [
 141         scan-object scan-object
 142         \ ; parse-help-text <article>
 143         over add-article >link
 144     ] dip remember-definition ;
 145
 146 SYNTAX: ABOUT:
 147     current-vocab scan-object >>help changed-definition ;