basis/hints/hints.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs byte-arrays byte-vectors classes
   4 combinators definitions effects fry generic generic.single
   5 generic.standard hashtables io.binary io.streams.string kernel
   6 kernel.private math math.parser namespaces parser sbufs
   7 sequences splitting splitting.private strings vectors words ;
   8 IN: hints
   9
  10 GENERIC: specializer-predicate ( spec -- quot )
  11
  12 M: class specializer-predicate "predicate" word-prop ;
  13
  14 M: object specializer-predicate '[ _ eq? ] ;
  15
  16 GENERIC: specializer-declaration ( spec -- class )
  17
  18 M: class specializer-declaration ;
  19
  20 M: object specializer-declaration class ;
  21
  22 : specializer ( word -- specializer )
  23     "specializer" word-prop ;
  24
  25 : make-specializer ( specs -- quot )
  26     dup length <reversed>
  27     [ (picker) 2array ] 2map
  28     [ drop object eq? not ] assoc-filter
  29     [ [ t ] ] [
  30         [ swap specializer-predicate append ] { } assoc>map
  31         [ ] [ swap [ f ] \ if 3array append [ ] like ] map-reduce
  32     ] if-empty ;
  33
  34 : specializer-cases ( quot specializer -- alist )
  35     dup [ array? ] all? [ 1array ] unless [
  36         [ nip make-specializer ]
  37         [ [ specializer-declaration ] map swap '[ _ declare @ ] ] 2bi
  38     ] with { } map>assoc ;
  39
  40 : specialize-quot ( quot word specializer -- quot' )
  41     [ drop nip def>> ] [ nip specializer-cases ] 3bi alist>quot ;
  42
  43 ! compiler.tree.propagation.inlining sets this to f
  44 SYMBOL: specialize-method?
  45
  46 t specialize-method? set-global
  47
  48 : method-declaration ( method -- quot )
  49     [ "method-generic" word-prop dispatch# object <array> ]
  50     [ "method-class" word-prop ]
  51     bi prefix [ declare ] curry [ ] like ;
  52
  53 : specialize-method ( quot method -- quot' )
  54     [ specialize-method? get [ method-declaration prepend ] [ drop ] if ]
  55     [ dup "method-generic" word-prop specializer ] bi
  56     [ specialize-quot ] [ drop ] if* ;
  57
  58 : standard-method? ( method -- ? )
  59     dup method-body? [
  60         "method-generic" word-prop standard-generic?
  61     ] [ drop f ] if ;
  62
  63 : specialized-def ( word -- quot )
  64     [ def>> ] keep
  65     dup generic? [ drop ] [
  66         [ dup standard-method? [ specialize-method ] [ drop ] if ]
  67         [ dup specializer [ specialize-quot ] [ drop ] if* ]
  68         bi
  69     ] if ;
  70
  71 : specialized-length ( specializer -- n )
  72     dup [ array? ] all? [ first ] when length ;
  73
  74 SYNTAX: HINTS:
  75     scan-object dup wrapper? [ wrapped>> ] when
  76     [ changed-definition ]
  77     [ subwords [ changed-definition ] each ]
  78     [ parse-definition { } like "specializer" set-word-prop ] tri ;
  79
  80 ! Default specializers
  81 { first first2 first3 first4 }
  82 [ { array } "specializer" set-word-prop ] each
  83
  84 { last pop* pop } [
  85     { vector } "specializer" set-word-prop
  86 ] each
  87
  88 \ push { { vector } { sbuf } } "specializer" set-word-prop
  89
  90 \ last { { vector } } "specializer" set-word-prop
  91
  92 \ set-last { { object vector } } "specializer" set-word-prop
  93
  94 \ push-all
  95 { { string sbuf } { array vector } { byte-array byte-vector } }
  96 "specializer" set-word-prop
  97
  98 \ append
  99 { { string string } { array array } }
 100 "specializer" set-word-prop
 101
 102 \ subseq
 103 { { fixnum fixnum string } { fixnum fixnum array } }
 104 "specializer" set-word-prop
 105
 106 \ reverse-here
 107 { { string } { array } }
 108 "specializer" set-word-prop
 109
 110 \ mismatch
 111 { string string }
 112 "specializer" set-word-prop
 113
 114 \ >string { sbuf } "specializer" set-word-prop
 115
 116 \ >array { { vector } } "specializer" set-word-prop
 117
 118 \ >vector { { array } { vector } } "specializer" set-word-prop
 119
 120 \ >sbuf { string } "specializer" set-word-prop
 121
 122 \ split, { string string } "specializer" set-word-prop
 123
 124 \ memq? { array } "specializer" set-word-prop
 125
 126 \ member? { array } "specializer" set-word-prop
 127
 128 \ assoc-stack { vector } "specializer" set-word-prop
 129
 130 \ >le { { fixnum fixnum } { bignum fixnum } } "specializer" set-word-prop
 131
 132 \ >be { { bignum fixnum } { fixnum fixnum } } "specializer" set-word-prop
 133
 134 \ base> { string fixnum } "specializer" set-word-prop
 135
 136 M\ hashtable at* { { fixnum object } { word object } } "specializer" set-word-prop
 137
 138 M\ hashtable set-at { { object fixnum object } { object word object } } "specializer" set-word-prop