basis/hints/hints.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs byte-arrays byte-vectors classes
   4 combinators definitions fry generic generic.single
   5 generic.standard hashtables io.binary io.streams.string kernel
   6 kernel.private math math.parser namespaces parser sbufs
   7 sequences splitting splitting.private strings vectors words ;
   8 IN: hints
   9
  10 GENERIC: specializer-predicate ( spec -- quot )
  11
  12 M: class specializer-predicate "predicate" word-prop ;
  13
  14 M: object specializer-predicate '[ _ eq? ] ;
  15
  16 GENERIC: specializer-declaration ( spec -- class )
  17
  18 M: class specializer-declaration ;
  19
  20 M: object specializer-declaration class ;
  21
  22 : make-specializer ( specs -- quot )
  23     dup length <reversed>
  24     [ (picker) 2array ] 2map
  25     [ drop object eq? not ] assoc-filter
  26     [ [ t ] ] [
  27         [ swap specializer-predicate append ] { } assoc>map
  28         [ ] [ swap [ f ] \ if 3array append [ ] like ] map-reduce
  29     ] if-empty ;
  30
  31 : specializer-cases ( quot word -- default alist )
  32     dup [ array? ] all? [ 1array ] unless [
  33         [ make-specializer ] keep
  34         [ specializer-declaration ] map '[ _ declare ] pick append
  35     ] { } map>assoc ;
  36
  37 : specialize-quot ( quot specializer -- quot' )
  38     specializer-cases alist>quot ;
  39
  40 ! compiler.tree.propagation.inlining sets this to f
  41 SYMBOL: specialize-method?
  42
  43 t specialize-method? set-global
  44
  45 : method-declaration ( method -- quot )
  46     [ "method-generic" word-prop dispatch# object <array> ]
  47     [ "method-class" word-prop ]
  48     bi prefix [ declare ] curry [ ] like ;
  49
  50 : specialize-method ( quot method -- quot' )
  51     [ specialize-method? get [ method-declaration prepend ] [ drop ] if ]
  52     [ "method-generic" word-prop "specializer" word-prop ] bi
  53     [ specialize-quot ] when* ;
  54
  55 : standard-method? ( method -- ? )
  56     dup method-body? [
  57         "method-generic" word-prop standard-generic?
  58     ] [ drop f ] if ;
  59
  60 : specialized-def ( word -- quot )
  61     [ def>> ] keep
  62     dup generic? [ drop ] [
  63         [ dup standard-method? [ specialize-method ] [ drop ] if ]
  64         [ "specializer" word-prop [ specialize-quot ] when* ]
  65         bi
  66     ] if ;
  67
  68 : specialized-length ( specializer -- n )
  69     dup [ array? ] all? [ first ] when length ;
  70
  71 SYNTAX: HINTS:
  72     scan-object dup wrapper? [ wrapped>> ] when
  73     [ changed-definition ]
  74     [ subwords [ changed-definition ] each ]
  75     [ parse-definition { } like "specializer" set-word-prop ] tri ;
  76
  77 ! Default specializers
  78 { first first2 first3 first4 }
  79 [ { array } "specializer" set-word-prop ] each
  80
  81 { last pop* pop } [
  82     { vector } "specializer" set-word-prop
  83 ] each
  84
  85 \ push { { vector } { sbuf } } "specializer" set-word-prop
  86
  87 \ last { { vector } } "specializer" set-word-prop
  88
  89 \ set-last { { object vector } } "specializer" set-word-prop
  90
  91 \ push-all
  92 { { string sbuf } { array vector } { byte-array byte-vector } }
  93 "specializer" set-word-prop
  94
  95 \ append
  96 { { string string } { array array } }
  97 "specializer" set-word-prop
  98
  99 \ subseq
 100 { { fixnum fixnum string } { fixnum fixnum array } }
 101 "specializer" set-word-prop
 102
 103 \ reverse-here
 104 { { string } { array } }
 105 "specializer" set-word-prop
 106
 107 \ mismatch
 108 { string string }
 109 "specializer" set-word-prop
 110
 111 \ >string { sbuf } "specializer" set-word-prop
 112
 113 \ >array { { vector } } "specializer" set-word-prop
 114
 115 \ >vector { { array } { vector } } "specializer" set-word-prop
 116
 117 \ >sbuf { string } "specializer" set-word-prop
 118
 119 \ split, { string string } "specializer" set-word-prop
 120
 121 \ memq? { array } "specializer" set-word-prop
 122
 123 \ member? { array } "specializer" set-word-prop
 124
 125 \ assoc-stack { vector } "specializer" set-word-prop
 126
 127 \ >le { { fixnum fixnum } { bignum fixnum } } "specializer" set-word-prop
 128
 129 \ >be { { bignum fixnum } { fixnum fixnum } } "specializer" set-word-prop
 130
 131 \ base> { string fixnum } "specializer" set-word-prop
 132
 133 M\ hashtable at* { { fixnum object } { word object } } "specializer" set-word-prop
 134
 135 M\ hashtable set-at { { object fixnum object } { object word object } } "specializer" set-word-prop