basis/html/streams/streams.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs combinators destructors fry html io
   4 io.backend io.pathnames io.styles kernel macros make math
   5 math.order math.parser namespaces sequences strings words
   6 splitting xml xml.syntax ;
   7 IN: html.streams
   8
   9 GENERIC: url-of ( object -- url )
  10
  11 M: object url-of drop f ;
  12
  13 TUPLE: html-writer data ;
  14 INSTANCE: html-writer output-stream
  15
  16 <PRIVATE
  17
  18 : new-html-writer ( class -- html-writer )
  19     new V{ } clone >>data ; inline
  20
  21 TUPLE: html-sub-stream < html-writer style parent ;
  22
  23 : new-html-sub-stream ( style stream class -- stream )
  24     new-html-writer
  25         swap >>parent
  26         swap >>style ; inline
  27
  28 : end-sub-stream ( substream -- string style stream )
  29     [ data>> ] [ style>> ] [ parent>> ] tri ;
  30
  31 : object-link-tag ( xml style -- xml )
  32     presented swap at [ url-of [ simple-link ] when* ] when* ;
  33
  34 : href-link-tag ( xml style -- xml )
  35     href swap at [ simple-link ] when* ;
  36
  37 : hex-color, ( color -- )
  38     [ red>> ] [ green>> ] [ blue>> ] tri
  39     [ 255 * >integer >hex 2 CHAR: 0 pad-head % ] tri@ ;
  40
  41 : fg-css, ( color -- )
  42     "color: #" % hex-color, "; " % ;
  43
  44 : bg-css, ( color -- )
  45     "background-color: #" % hex-color, "; " % ;
  46
  47 : style-css, ( flag -- )
  48     dup
  49     { italic bold-italic } member?
  50     "font-style: " % "italic" "normal" ? % "; " %
  51     { bold bold-italic } member?
  52     "font-weight: " % "bold" "normal" ? % "; " % ;
  53
  54 : size-css, ( size -- )
  55     "font-size: " % # "pt; " % ;
  56
  57 : font-css, ( font -- )
  58     "font-family: " % % "; " % ;
  59
  60 MACRO: make-css ( pairs -- str )
  61     [ '[ _ swap at [ _ execute ] when* ] ] { } assoc>map
  62     '[ [ _ cleave ] "" make ] ;
  63
  64 : span-css-style ( style -- str )
  65     {
  66         { foreground fg-css, }
  67         { background bg-css, }
  68         { font-name font-css, }
  69         { font-style style-css, }
  70         { font-size size-css, }
  71     } make-css ;
  72
  73 : span-tag ( xml style -- xml )
  74     span-css-style
  75     [ swap [XML <span style=<->><-></span> XML] ] unless-empty ; inline
  76
  77 : emit-html ( stream quot -- )
  78     dip data>> push ; inline
  79
  80 : image-path ( path -- images-path )
  81     "vocab:definitions/icons/" ?head [ "/icons/" prepend ] when ;
  82
  83 : img-tag ( xml style -- xml )
  84     image swap at [ nip image-path simple-image ] when* ;
  85
  86 : format-html-span ( string style stream -- )
  87     [
  88         {
  89             [ span-tag ]
  90             [ href-link-tag ]
  91             [ object-link-tag ]
  92             [ img-tag ]
  93         } cleave
  94     ] emit-html ;
  95
  96 TUPLE: html-span-stream < html-sub-stream ;
  97
  98 M: html-span-stream dispose
  99     end-sub-stream format-html-span ;
 100
 101 : border-css, ( border -- )
 102     "border: 1px solid #" % hex-color, "; " % ;
 103
 104 : padding-css, ( padding -- )
 105     first2 "padding: " % # "px " % # "px; " % ;
 106
 107 CONSTANT: pre-css "white-space: pre; font-family: monospace;"
 108
 109 : div-css-style ( style -- str )
 110     [
 111         {
 112             { page-color bg-css, }
 113             { border-color border-css, }
 114             { inset padding-css, }
 115         } make-css
 116     ] [ wrap-margin swap at [ pre-css append ] unless ] bi
 117     " display: inline-block;" append ;
 118
 119 : div-tag ( xml style -- xml' )
 120     div-css-style
 121     [ swap [XML <div style=<->><-></div> XML] ] unless-empty ;
 122
 123 : format-html-div ( string style stream -- )
 124     [ [ div-tag ] [ object-link-tag ] bi ] emit-html ;
 125
 126 TUPLE: html-block-stream < html-sub-stream ;
 127
 128 M: html-block-stream dispose
 129     end-sub-stream format-html-div ;
 130
 131 : border-spacing-css, ( pair -- )
 132     "padding: " % first2 max 2 /i # "px; " % ;
 133
 134 : table-style ( style -- str )
 135     {
 136         { table-border border-css, }
 137         { table-gap border-spacing-css, }
 138     } make-css
 139     " border-collapse: collapse;" append ;
 140
 141 PRIVATE>
 142
 143 ! Stream protocol
 144 M: html-writer stream-flush drop ;
 145
 146 M: html-writer stream-write1
 147     [ 1string ] emit-html ;
 148
 149 M: html-writer stream-write
 150     [ ] emit-html ;
 151
 152 M: html-writer stream-format
 153     format-html-span ;
 154
 155 M: html-writer stream-nl
 156     [ [XML <br/> XML] ] emit-html ;
 157
 158 M: html-writer make-span-stream
 159     html-span-stream new-html-sub-stream ;
 160
 161 M: html-writer make-block-stream
 162     html-block-stream new-html-sub-stream ;
 163
 164 M: html-writer make-cell-stream
 165     html-sub-stream new-html-sub-stream ;
 166
 167 M: html-writer stream-write-table
 168     [
 169         table-style swap [
 170             [ data>> [XML <td valign="top" style=<->><-></td> XML] ] with map
 171             [XML <tr><-></tr> XML]
 172         ] with map
 173         [XML <table style="display: inline-table;"><-></table> XML]
 174     ] emit-html ;
 175
 176 M: html-writer dispose drop ;
 177
 178 : <html-writer> ( -- html-writer )
 179     html-writer new-html-writer ;
 180
 181 : with-html-writer ( quot -- xml )
 182     <html-writer> [ swap with-output-stream* ] keep data>> ; inline