basis/http/http.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs base64 calendar calendar.format
   4 calendar.parser combinators fry hashtables http.parsers io io.crlf
   5 io.encodings.iana io.encodings.utf8 kernel make math math.parser
   6 mime.types present sequences sets sorting splitting urls ;
   7 IN: http
   8
   9 CONSTANT: max-redirects 10
  10
  11 : (read-header) ( -- alist )
  12     [ read-?crlf dup f like ] [ parse-header-line ] produce nip ;
  13
  14 : collect-headers ( assoc -- assoc' )
  15     H{ } clone [ '[ _ push-at ] assoc-each ] keep ;
  16
  17 : process-header ( alist -- assoc )
  18     f swap [ [ swap or dup ] dip swap ] assoc-map nip
  19     collect-headers [ "; " join ] assoc-map
  20     >hashtable ;
  21
  22 : read-header ( -- assoc )
  23     (read-header) process-header ;
  24
  25 : header-value>string ( value -- string )
  26     {
  27         { [ dup timestamp? ] [ timestamp>http-string ] }
  28         { [ dup array? ] [ [ header-value>string ] map "; " join ] }
  29         [ present ]
  30     } cond ;
  31
  32 : check-header-string ( str -- str )
  33     ! http://en.wikipedia.org/wiki/HTTP_Header_Injection
  34     dup "\r\n" intersects?
  35     [ "Header injection attack" throw ] when ;
  36
  37 : write-header ( assoc -- )
  38     sort-keys [
  39         [ check-header-string write ": " write ]
  40         [ header-value>string check-header-string write crlf ] bi*
  41     ] assoc-each crlf ;
  42
  43 TUPLE: cookie name value version comment path domain expires max-age http-only secure ;
  44
  45 : <cookie> ( value name -- cookie )
  46     cookie new
  47         swap >>name
  48         swap >>value ;
  49
  50 : parse-set-cookie ( string -- seq )
  51     [
  52         f swap
  53         (parse-set-cookie)
  54         [
  55             over >lower [ swapd ] dip {
  56                 { "version" [ >>version ] }
  57                 { "comment" [ >>comment ] }
  58                 { "expires" [ [ cookie-string>timestamp >>expires ] unless-empty ] }
  59                 { "max-age" [ string>number seconds >>max-age ] }
  60                 { "domain" [ >>domain ] }
  61                 { "path" [ >>path ] }
  62                 { "httponly" [ drop t >>http-only ] }
  63                 { "secure" [ drop t >>secure ] }
  64                 [ drop rot <cookie> dup , ]
  65             } case
  66             nip
  67         ] assoc-each
  68         drop
  69     ] { } make ;
  70
  71 : parse-cookie ( string -- seq )
  72     [
  73         f swap
  74         (parse-cookie)
  75         [
  76             swap {
  77                 { "$version" [ >>version ] }
  78                 { "$domain" [ >>domain ] }
  79                 { "$path" [ >>path ] }
  80                 [ <cookie> dup , nip ]
  81             } case
  82         ] assoc-each
  83         drop
  84     ] { } make ;
  85
  86 : check-cookie-string ( string -- string' )
  87     dup "=;'\"\r\n" intersects?
  88     [ "Bad cookie name or value" throw ] when ;
  89
  90 : unparse-cookie-value ( key value -- )
  91     {
  92         { f [ drop ] }
  93         { t [ check-cookie-string , ] }
  94         [
  95             {
  96                 { [ dup timestamp? ] [ timestamp>cookie-string ] }
  97                 { [ dup duration? ] [ duration>seconds number>string ] }
  98                 { [ dup real? ] [ number>string ] }
  99                 [ ]
 100             } cond
 101             [ check-cookie-string ] bi@ "=" glue ,
 102         ]
 103     } case ;
 104
 105 : check-cookie-value ( string -- string )
 106     [ "Cookie value must not be f" throw ] unless* ;
 107
 108 : (unparse-cookie) ( cookie -- strings )
 109     [
 110         dup name>> check-cookie-string
 111         over value>> check-cookie-value unparse-cookie-value
 112         "$path" over path>> unparse-cookie-value
 113         "$domain" over domain>> unparse-cookie-value
 114         drop
 115     ] { } make ;
 116
 117 : unparse-cookie ( cookies -- string )
 118     [ (unparse-cookie) ] map concat "; " join ;
 119
 120 : unparse-set-cookie ( cookie -- string )
 121     [
 122         dup name>> check-cookie-string
 123         over value>> check-cookie-value unparse-cookie-value
 124         "path" over path>> unparse-cookie-value
 125         "domain" over domain>> unparse-cookie-value
 126         "expires" over expires>> unparse-cookie-value
 127         "max-age" over max-age>> unparse-cookie-value
 128         "httponly" over http-only>> unparse-cookie-value
 129         "secure" over secure>> unparse-cookie-value
 130         drop
 131     ] { } make "; " join ;
 132
 133 TUPLE: request
 134     method
 135     url
 136     proxy-url
 137     version
 138     header
 139     post-data
 140     cookies
 141     redirects ;
 142
 143 : set-header ( request/response value key -- request/response )
 144     pick header>> set-at ;
 145
 146 : basic-auth ( username password -- str )
 147     ":" glue >base64 "Basic " "" prepend-as ;
 148
 149 : set-basic-auth ( request username password -- request )
 150     basic-auth "Authorization" set-header ;
 151
 152 : set-proxy-basic-auth ( request username password -- request )
 153     basic-auth "Proxy-Authorization" set-header ;
 154
 155 : <request> ( -- request )
 156     request new
 157         "1.1" >>version
 158         <url>
 159             H{ } clone >>query
 160         >>url
 161         <url> >>proxy-url
 162         H{ } clone >>header
 163         V{ } clone >>cookies
 164         "close" "connection" set-header
 165         "Factor http.client" "user-agent" set-header
 166         max-redirects >>redirects ;
 167
 168 : header ( request/response key -- value )
 169     swap header>> at ;
 170
 171
 172 TUPLE: response
 173     version
 174     code
 175     message
 176     header
 177     cookies
 178     content-type
 179     content-charset
 180     content-encoding
 181     body ;
 182
 183 : <response> ( -- response )
 184     response new
 185         "1.1" >>version
 186         H{ } clone >>header
 187         "close" "connection" set-header
 188         now timestamp>http-string "date" set-header
 189         "Factor http.server" "server" set-header
 190         utf8 >>content-encoding
 191         V{ } clone >>cookies ;
 192
 193 M: response clone
 194     call-next-method
 195         [ clone ] change-header
 196         [ clone ] change-cookies ;
 197
 198 : get-cookie ( request/response name -- cookie/f )
 199     [ cookies>> ] dip '[ [ _ ] dip name>> = ] find nip ;
 200
 201 : delete-cookie ( request/response name -- )
 202     over cookies>> [ get-cookie ] dip remove! drop ;
 203
 204 : put-cookie ( request/response cookie -- request/response )
 205     [ name>> dupd get-cookie [ dupd delete-cookie ] when* ] keep
 206     over cookies>> push ;
 207
 208 TUPLE: raw-response
 209     version
 210     code
 211     message
 212     body ;
 213
 214 : <raw-response> ( -- response )
 215     raw-response new
 216         "1.1" >>version ;
 217
 218 TUPLE: post-data data params content-type content-encoding ;
 219
 220 : <post-data> ( content-type -- post-data )
 221     post-data new
 222         swap >>content-type ;
 223
 224 : parse-content-type-attributes ( string -- attributes )
 225     " " split harvest [
 226         "=" split1
 227         "\"" ?head drop "\"" ?tail drop
 228     ] { } map>assoc ;
 229
 230 : parse-content-type ( content-type -- type encoding )
 231     ";" split1
 232     parse-content-type-attributes "charset" of
 233     [ dup mime-type-encoding encoding>name ] unless* ;