basis/http/http.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel combinators math namespaces make assocs
   4 sequences splitting sorting sets strings vectors hashtables
   5 quotations arrays byte-arrays math.parser calendar
   6 calendar.format present urls fry io io.encodings
   7 io.encodings.iana io.encodings.binary io.encodings.utf8 io.crlf
   8 ascii io.encodings.8-bit.latin1 http.parsers base64 mime.types ;
   9 IN: http
  10
  11 CONSTANT: max-redirects 10
  12
  13 : (read-header) ( -- alist )
  14     [ read-?crlf dup f like ] [ parse-header-line ] produce nip ;
  15
  16 : collect-headers ( assoc -- assoc' )
  17     H{ } clone [ '[ _ push-at ] assoc-each ] keep ;
  18
  19 : process-header ( alist -- assoc )
  20     f swap [ [ swap or dup ] dip swap ] assoc-map nip
  21     collect-headers [ "; " join ] assoc-map
  22     >hashtable ;
  23
  24 : read-header ( -- assoc )
  25     (read-header) process-header ;
  26
  27 : header-value>string ( value -- string )
  28     {
  29         { [ dup timestamp? ] [ timestamp>http-string ] }
  30         { [ dup array? ] [ [ header-value>string ] map "; " join ] }
  31         [ present ]
  32     } cond ;
  33
  34 : check-header-string ( str -- str )
  35     ! http://en.wikipedia.org/wiki/HTTP_Header_Injection
  36     dup "\r\n" intersects?
  37     [ "Header injection attack" throw ] when ;
  38
  39 : write-header ( assoc -- )
  40     sort-keys [
  41         [ check-header-string write ": " write ]
  42         [ header-value>string check-header-string write crlf ] bi*
  43     ] assoc-each crlf ;
  44
  45 TUPLE: cookie name value version comment path domain expires max-age http-only secure ;
  46
  47 : <cookie> ( value name -- cookie )
  48     cookie new
  49         swap >>name
  50         swap >>value ;
  51
  52 : parse-set-cookie ( string -- seq )
  53     [
  54         f swap
  55         (parse-set-cookie)
  56         [
  57             swap {
  58                 { "version" [ >>version ] }
  59                 { "comment" [ >>comment ] }
  60                 { "expires" [ [ cookie-string>timestamp >>expires ] unless-empty ] }
  61                 { "max-age" [ string>number seconds >>max-age ] }
  62                 { "domain" [ >>domain ] }
  63                 { "path" [ >>path ] }
  64                 { "httponly" [ drop t >>http-only ] }
  65                 { "secure" [ drop t >>secure ] }
  66                 [ <cookie> dup , nip ]
  67             } case
  68         ] assoc-each
  69         drop
  70     ] { } make ;
  71
  72 : parse-cookie ( string -- seq )
  73     [
  74         f swap
  75         (parse-cookie)
  76         [
  77             swap {
  78                 { "$version" [ >>version ] }
  79                 { "$domain" [ >>domain ] }
  80                 { "$path" [ >>path ] }
  81                 [ <cookie> dup , nip ]
  82             } case
  83         ] assoc-each
  84         drop
  85     ] { } make ;
  86
  87 : check-cookie-string ( string -- string' )
  88     dup "=;'\"\r\n" intersects?
  89     [ "Bad cookie name or value" throw ] when ;
  90
  91 : unparse-cookie-value ( key value -- )
  92     {
  93         { f [ drop ] }
  94         { t [ check-cookie-string , ] }
  95         [
  96             {
  97                 { [ dup timestamp? ] [ timestamp>cookie-string ] }
  98                 { [ dup duration? ] [ duration>seconds number>string ] }
  99                 { [ dup real? ] [ number>string ] }
 100                 [ ]
 101             } cond
 102             [ check-cookie-string ] bi@ "=" glue ,
 103         ]
 104     } case ;
 105
 106 : check-cookie-value ( string -- string )
 107     [ "Cookie value must not be f" throw ] unless* ;
 108
 109 : (unparse-cookie) ( cookie -- strings )
 110     [
 111         dup name>> check-cookie-string
 112         over value>> check-cookie-value unparse-cookie-value
 113         "$path" over path>> unparse-cookie-value
 114         "$domain" over domain>> unparse-cookie-value
 115         drop
 116     ] { } make ;
 117
 118 : unparse-cookie ( cookies -- string )
 119     [ (unparse-cookie) ] map concat "; " join ;
 120
 121 : unparse-set-cookie ( cookie -- string )
 122     [
 123         dup name>> check-cookie-string
 124         over value>> check-cookie-value unparse-cookie-value
 125         "path" over path>> unparse-cookie-value
 126         "domain" over domain>> unparse-cookie-value
 127         "expires" over expires>> unparse-cookie-value
 128         "max-age" over max-age>> unparse-cookie-value
 129         "httponly" over http-only>> unparse-cookie-value
 130         "secure" over secure>> unparse-cookie-value
 131         drop
 132     ] { } make "; " join ;
 133
 134 TUPLE: request
 135 method
 136 url
 137 version
 138 header
 139 post-data
 140 cookies
 141 redirects ;
 142
 143 : set-header ( request/response value key -- request/response )
 144     pick header>> set-at ;
 145
 146 : set-basic-auth ( request username password -- request )
 147     ":" glue >base64 "Basic " "" prepend-as "Authorization" set-header ;
 148
 149 : <request> ( -- request )
 150     request new
 151         "1.1" >>version
 152         <url>
 153             H{ } clone >>query
 154         >>url
 155         H{ } clone >>header
 156         V{ } clone >>cookies
 157         "close" "connection" set-header
 158         "Factor http.client" "user-agent" set-header
 159         max-redirects >>redirects ;
 160
 161 : header ( request/response key -- value )
 162     swap header>> at ;
 163
 164
 165 TUPLE: response
 166 version
 167 code
 168 message
 169 header
 170 cookies
 171 content-type
 172 content-charset
 173 content-encoding
 174 body ;
 175
 176 : <response> ( -- response )
 177     response new
 178         "1.1" >>version
 179         H{ } clone >>header
 180         "close" "connection" set-header
 181         now timestamp>http-string "date" set-header
 182         "Factor http.server" "server" set-header
 183         utf8 >>content-encoding
 184         V{ } clone >>cookies ;
 185
 186 M: response clone
 187     call-next-method
 188         [ clone ] change-header
 189         [ clone ] change-cookies ;
 190
 191 : get-cookie ( request/response name -- cookie/f )
 192     [ cookies>> ] dip '[ [ _ ] dip name>> = ] find nip ;
 193
 194 : delete-cookie ( request/response name -- )
 195     over cookies>> [ get-cookie ] dip remove! drop ;
 196
 197 : put-cookie ( request/response cookie -- request/response )
 198     [ name>> dupd get-cookie [ dupd delete-cookie ] when* ] keep
 199     over cookies>> push ;
 200
 201 TUPLE: raw-response
 202 version
 203 code
 204 message
 205 body ;
 206
 207 : <raw-response> ( -- response )
 208     raw-response new
 209         "1.1" >>version ;
 210
 211 TUPLE: post-data data params content-type content-encoding ;
 212
 213 : <post-data> ( content-type -- post-data )
 214     post-data new
 215         swap >>content-type ;
 216
 217 : parse-content-type-attributes ( string -- attributes )
 218     " " split harvest [
 219         "=" split1
 220         "\"" ?head drop "\"" ?tail drop
 221     ] { } map>assoc ;
 222
 223 : parse-content-type ( content-type -- type encoding )
 224     ";" split1
 225     parse-content-type-attributes "charset" of
 226     [ dup mime-type-encoding encoding>name ] unless* ;