basis/http/http.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs base64 calendar calendar.format
   4 calendar.parser combinators hashtables http.parsers io io.crlf
   5 io.encodings.iana io.encodings.utf8 kernel make math math.parser
   6 mime.types present sequences sets sorting splitting urls ;
   7 IN: http
   8
   9 CONSTANT: max-redirects 10
  10
  11 : (read-header) ( -- alist )
  12     [ read-?crlf dup f like ] [ parse-header-line ] produce nip ;
  13
  14 : collect-headers ( assoc -- assoc' )
  15     H{ } clone [ '[ _ push-at ] assoc-each ] keep ;
  16
  17 : process-header ( alist -- assoc )
  18     f swap [ [ swap or dup ] dip swap ] assoc-map nip
  19     collect-headers [ "; " join ] assoc-map
  20     >hashtable ;
  21
  22 : read-header ( -- assoc )
  23     (read-header) process-header ;
  24
  25 : header-value>string ( value -- string )
  26     {
  27         { [ dup timestamp? ] [ timestamp>http-string ] }
  28         { [ dup array? ] [ [ header-value>string ] map "; " join ] }
  29         [ present ]
  30     } cond ;
  31
  32 : check-header-string ( str -- str )
  33     ! http://en.wikipedia.org/wiki/HTTP_Header_Injection
  34     dup "\r\n" intersects?
  35     [ "Header injection attack" throw ] when ;
  36
  37 : write-header ( assoc -- )
  38     sort-keys [
  39         [ check-header-string write ": " write ]
  40         [ header-value>string check-header-string write crlf ] bi*
  41     ] assoc-each crlf ;
  42
  43 TUPLE: cookie name value version comment path domain expires max-age http-only secure ;
  44
  45 : <cookie> ( value name -- cookie )
  46     cookie new
  47         swap >>name
  48         swap >>value ;
  49
  50 : parse-set-cookie ( string -- seq )
  51     [
  52         f swap
  53         (parse-set-cookie)
  54         [
  55             swapd pick >lower {
  56                 { "version" [ >>version ] }
  57                 { "comment" [ >>comment ] }
  58                 { "expires" [ [ cookie-string>timestamp >>expires ] unless-empty ] }
  59                 { "max-age" [ string>number seconds >>max-age ] }
  60                 { "domain" [ >>domain ] }
  61                 { "path" [ >>path ] }
  62                 { "httponly" [ drop t >>http-only ] }
  63                 { "secure" [ drop t >>secure ] }
  64                 [ drop rot <cookie> dup , ]
  65             } case nip
  66         ] assoc-each
  67         drop
  68     ] { } make ;
  69
  70 : parse-cookie ( string -- seq )
  71     [
  72         f swap
  73         (parse-cookie)
  74         [
  75             swap {
  76                 { "$version" [ >>version ] }
  77                 { "$domain" [ >>domain ] }
  78                 { "$path" [ >>path ] }
  79                 [ <cookie> dup , nip ]
  80             } case
  81         ] assoc-each
  82         drop
  83     ] { } make ;
  84
  85 : check-cookie-string ( string -- string' )
  86     dup "=;'\"\r\n" intersects?
  87     [ "Bad cookie name or value" throw ] when ;
  88
  89 : unparse-cookie-value ( key value -- )
  90     {
  91         { f [ drop ] }
  92         { t [ check-cookie-string , ] }
  93         [
  94             {
  95                 { [ dup timestamp? ] [ timestamp>cookie-string ] }
  96                 { [ dup duration? ] [ duration>seconds number>string ] }
  97                 { [ dup real? ] [ number>string ] }
  98                 [ ]
  99             } cond
 100             [ check-cookie-string ] bi@ "=" glue ,
 101         ]
 102     } case ;
 103
 104 : check-cookie-value ( string -- string )
 105     [ "Cookie value must not be f" throw ] unless* ;
 106
 107 : (unparse-cookie) ( cookie -- strings )
 108     [
 109         dup name>> check-cookie-string
 110         over value>> check-cookie-value unparse-cookie-value
 111         "$path" over path>> unparse-cookie-value
 112         "$domain" over domain>> unparse-cookie-value
 113         drop
 114     ] { } make ;
 115
 116 : unparse-cookie ( cookies -- string )
 117     [ (unparse-cookie) ] map concat "; " join ;
 118
 119 : unparse-set-cookie ( cookie -- string )
 120     [
 121         dup name>> check-cookie-string
 122         over value>> check-cookie-value unparse-cookie-value
 123         "path" over path>> unparse-cookie-value
 124         "domain" over domain>> unparse-cookie-value
 125         "expires" over expires>> unparse-cookie-value
 126         "max-age" over max-age>> unparse-cookie-value
 127         "httponly" over http-only>> unparse-cookie-value
 128         "secure" over secure>> unparse-cookie-value
 129         drop
 130     ] { } make "; " join ;
 131
 132 TUPLE: request
 133     method
 134     url
 135     proxy-url
 136     version
 137     header
 138     post-data
 139     cookies
 140     redirects ;
 141
 142 : set-header ( request/response value key -- request/response )
 143     pick header>> set-at ;
 144
 145 : basic-auth ( username password -- str )
 146     ":" glue >base64 "Basic " "" prepend-as ;
 147
 148 : set-basic-auth ( request username password -- request )
 149     basic-auth "Authorization" set-header ;
 150
 151 : set-proxy-basic-auth ( request username password -- request )
 152     basic-auth "Proxy-Authorization" set-header ;
 153
 154 : <request> ( -- request )
 155     request new
 156         "1.1" >>version
 157         <url>
 158             H{ } clone >>query
 159         >>url
 160         <url> >>proxy-url
 161         H{ } clone >>header
 162         V{ } clone >>cookies
 163         "close" "Connection" set-header
 164         "Factor http.client" "User-Agent" set-header
 165         max-redirects >>redirects ;
 166
 167 : header ( request/response key -- value )
 168     swap header>> at ;
 169
 170 ! https://github.com/factor/factor/issues/2273
 171 ! https://observatory.mozilla.org/analyze/factorcode.org
 172 ! https://csp-evaluator.withgoogle.com/?csp=https://factorcode.org
 173 : add-modern-headers ( response -- response )
 174     "max-age=63072000; includeSubDomains; preload" "Strict-Transport-Security" set-header
 175     "nosniff" "X-Content-Type-Options" set-header
 176     "default-src https: 'unsafe-inline'; frame-ancestors 'none'; object-src 'none'" "Content-Security-Policy" set-header
 177     "DENY" "X-Frame-Options" set-header
 178     "1; mode=block" "X-XSS-Protection" set-header ;
 179
 180 TUPLE: response
 181     version
 182     code
 183     message
 184     header
 185     cookies
 186     content-type
 187     content-charset
 188     content-encoding
 189     body ;
 190
 191 : <response> ( -- response )
 192     response new
 193         "1.1" >>version
 194         H{ } clone >>header
 195         "close" "Connection" set-header
 196         now timestamp>http-string "Date" set-header
 197         "Factor http.server" "Server" set-header
 198         add-modern-headers
 199         utf8 >>content-encoding
 200         V{ } clone >>cookies ;
 201
 202 M: response clone
 203     call-next-method
 204         [ clone ] change-header
 205         [ clone ] change-cookies ;
 206
 207 : get-cookie ( request/response name -- cookie/f )
 208     [ cookies>> ] dip '[ [ _ ] dip name>> = ] find nip ;
 209
 210 : delete-cookie ( request/response name -- )
 211     over cookies>> [ get-cookie ] dip remove! drop ;
 212
 213 : put-cookie ( request/response cookie -- request/response )
 214     [ name>> dupd get-cookie [ dupd delete-cookie ] when* ] keep
 215     over cookies>> push ;
 216
 217 TUPLE: raw-response
 218     version
 219     code
 220     message
 221     body ;
 222
 223 : <raw-response> ( -- response )
 224     raw-response new
 225         "1.1" >>version ;
 226
 227 TUPLE: post-data data params content-type content-encoding ;
 228
 229 : <post-data> ( content-type -- post-data )
 230     post-data new
 231         swap >>content-type ;
 232
 233 : parse-content-type-attributes ( string -- attributes )
 234     split-words harvest [
 235         "=" split1
 236         "\"" ?head drop "\"" ?tail drop
 237     ] { } map>assoc ;
 238
 239 : parse-content-type ( content-type -- type encoding )
 240     ";" split1
 241     parse-content-type-attributes "charset" of
 242     [ dup mime-type-encoding encoding>name ] unless* ;