basis/http/parsers/parsers.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators.short-circuit math math.order math.parser
   4 kernel sequences sequences.deep peg peg.parsers assocs arrays
   5 hashtables strings unicode.case namespaces make ascii ;
   6 IN: http.parsers
   7
   8 : except ( quot -- parser )
   9     [ not ] compose satisfy ; inline
  10
  11 : except-these ( quots -- parser )
  12     [ 1|| ] curry except ; inline
  13
  14 : ctl? ( ch -- ? )
  15     { [ 0 31 between? ] [ 127 = ] } 1|| ;
  16
  17 : tspecial? ( ch -- ? )
  18     "()<>@,;:\\\"/[]?={} \t" member? ;
  19
  20 : 'token' ( -- parser )
  21     { [ ctl? ] [ tspecial? ] } except-these repeat1 ;
  22
  23 : case-insensitive ( parser -- parser' )
  24     [ flatten >string >lower ] action ;
  25
  26 : case-sensitive ( parser -- parser' )
  27     [ flatten >string ] action ;
  28
  29 : 'space' ( -- parser )
  30     [ " \t" member? ] satisfy repeat0 hide ;
  31
  32 : one-of ( strings -- parser )
  33     [ token ] map choice ;
  34
  35 : 'http-method' ( -- parser )
  36     { "OPTIONS" "GET" "HEAD" "POST" "PUT" "DELETE" "TRACE" "CONNECT" } one-of ;
  37
  38 : 'url' ( -- parser )
  39     [ " \t\r\n" member? ] except repeat1 case-sensitive ;
  40
  41 : 'http-version' ( -- parser )
  42     [
  43         "HTTP" token hide ,
  44         'space' ,
  45         "/" token hide ,
  46         'space' ,
  47         "1" token ,
  48         "." token ,
  49         { "0" "1" } one-of ,
  50     ] seq* [ concat >string ] action ;
  51
  52 PEG: parse-request-line ( string -- triple )
  53     #! Triple is { method url version }
  54     [
  55         'space' ,
  56         'http-method' ,
  57         'space' ,
  58         'url' ,
  59         'space' ,
  60         'http-version' ,
  61         'space' ,
  62     ] seq* just ;
  63
  64 : 'text' ( -- parser )
  65     [ ctl? ] except ;
  66
  67 : 'response-code' ( -- parser )
  68     [ digit? ] satisfy 3 exactly-n [ string>number ] action ;
  69
  70 : 'response-message' ( -- parser )
  71     'text' repeat0 case-sensitive ;
  72
  73 PEG: parse-response-line ( string -- triple )
  74     #! Triple is { version code message }
  75     [
  76         'space' ,
  77         'http-version' ,
  78         'space' ,
  79         'response-code' ,
  80         'space' ,
  81         'response-message' ,
  82     ] seq* just ;
  83
  84 : 'crlf' ( -- parser )
  85     "\r\n" token ;
  86
  87 : 'lws' ( -- parser )
  88     [ " \t" member? ] satisfy repeat1 ;
  89
  90 : 'qdtext' ( -- parser )
  91     { [ CHAR: " = ] [ ctl? ] } except-these ;
  92
  93 : 'quoted-char' ( -- parser )
  94     "\\" token hide any-char 2seq ;
  95
  96 : 'quoted-string' ( -- parser )
  97     'quoted-char' 'qdtext' 2choice repeat0 "\"" "\"" surrounded-by ;
  98
  99 : 'ctext' ( -- parser )
 100     { [ ctl? ] [ "()" member? ] } except-these ;
 101
 102 : 'comment' ( -- parser )
 103     'ctext' 'comment' 2choice repeat0 "(" ")" surrounded-by ;
 104
 105 : 'field-name' ( -- parser )
 106     'token' case-insensitive ;
 107
 108 : 'field-content' ( -- parser )
 109     'quoted-string' case-sensitive
 110     'text' repeat0 case-sensitive
 111     2choice ;
 112
 113 PEG: parse-header-line ( string -- pair )
 114     #! Pair is either { name value } or { f value }. If f, its a
 115     #! continuation of the previous header line.
 116     [
 117         'field-name' ,
 118         'space' ,
 119         ":" token hide ,
 120         'space' ,
 121         'field-content' ,
 122     ] seq*
 123     [
 124         'lws' [ drop f ] action ,
 125         'field-content' ,
 126     ] seq*
 127     2choice ;
 128
 129 : 'word' ( -- parser )
 130     'token' 'quoted-string' 2choice ;
 131
 132 : 'value' ( -- parser )
 133     'quoted-string'
 134     [ ";" member? ] except repeat0
 135     2choice case-sensitive ;
 136
 137 : 'attr' ( -- parser )
 138     'token' case-insensitive ;
 139
 140 : 'av-pair' ( -- parser )
 141     [
 142         'space' ,
 143         'attr' ,
 144         'space' ,
 145             [ "=" token , 'space' , 'value' , ] seq* [ peek ] action
 146             epsilon [ drop f ] action
 147         2choice ,
 148         'space' ,
 149     ] seq* ;
 150
 151 : 'av-pairs' ( -- parser )
 152     'av-pair' ";" token list-of optional ;
 153
 154 PEG: (parse-set-cookie) ( string -- alist ) 'av-pairs' just ;
 155
 156 : 'cookie-value' ( -- parser )
 157     [
 158         'space' ,
 159         'attr' ,
 160         'space' ,
 161         "=" token hide ,
 162         'space' ,
 163         'value' ,
 164         'space' ,
 165     ] seq* ;
 166
 167 PEG: (parse-cookie) ( string -- alist )
 168     'cookie-value' [ ";," member? ] satisfy list-of optional just ;