basis/images/images.factor

   1 ! Copyright (C) 2009 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators kernel locals accessors sequences math arrays ;
   4 IN: images
   5
   6 SINGLETONS:
   7     A L LA BGR RGB BGRA RGBA ABGR ARGB RGBX XRGB BGRX XBGR
   8     INTENSITY DEPTH DEPTH-STENCIL R RG
   9     ubyte-components ushort-components uint-components
  10     half-components float-components
  11     byte-integer-components ubyte-integer-components
  12     short-integer-components ushort-integer-components
  13     int-integer-components uint-integer-components
  14     u-5-5-5-1-components u-5-6-5-components
  15     u-10-10-10-2-components
  16     u-24-components u-24-8-components
  17     float-32-u-8-components
  18     u-9-9-9-e5-components
  19     float-11-11-10-components ;
  20
  21 UNION: component-order
  22     A L LA BGR RGB BGRA RGBA ABGR ARGB RGBX XRGB BGRX XBGR
  23     INTENSITY DEPTH DEPTH-STENCIL R RG ;
  24
  25 UNION: component-type
  26     ubyte-components ushort-components uint-components
  27     half-components float-components
  28     byte-integer-components ubyte-integer-components
  29     short-integer-components ushort-integer-components
  30     int-integer-components uint-integer-components
  31     u-5-5-5-1-components u-5-6-5-components
  32     u-10-10-10-2-components
  33     u-24-components u-24-8-components
  34     float-32-u-8-components
  35     u-9-9-9-e5-components
  36     float-11-11-10-components ;
  37
  38 UNION: unnormalized-integer-components
  39     byte-integer-components ubyte-integer-components
  40     short-integer-components ushort-integer-components
  41     int-integer-components uint-integer-components ;
  42
  43 UNION: signed-unnormalized-integer-components
  44     byte-integer-components
  45     short-integer-components
  46     int-integer-components ;
  47
  48 UNION: unsigned-unnormalized-integer-components
  49     ubyte-integer-components
  50     ushort-integer-components
  51     uint-integer-components ;
  52
  53 UNION: packed-components
  54     u-5-5-5-1-components u-5-6-5-components
  55     u-10-10-10-2-components
  56     u-24-components u-24-8-components
  57     float-32-u-8-components
  58     u-9-9-9-e5-components
  59     float-11-11-10-components ;
  60
  61 UNION: alpha-channel BGRA RGBA ABGR ARGB LA A INTENSITY ;
  62
  63 UNION: alpha-channel-precedes-colors ABGR ARGB XBGR XRGB ;
  64
  65 TUPLE: image
  66     dim component-order component-type
  67     upside-down? premultiplied-alpha?
  68     bitmap ;
  69
  70 : <image> ( -- image ) image new ; inline
  71
  72 : has-alpha? ( image -- ? ) component-order>> alpha-channel? ;
  73
  74 : bytes-per-component ( component-type -- n )
  75     {
  76         { ubyte-components [ 1 ] }
  77         { ushort-components [ 2 ] }
  78         { uint-components [ 4 ] }
  79         { half-components [ 2 ] }
  80         { float-components [ 4 ] }
  81         { byte-integer-components [ 1 ] }
  82         { ubyte-integer-components [ 1 ] }
  83         { short-integer-components [ 2 ] }
  84         { ushort-integer-components [ 2 ] }
  85         { int-integer-components [ 4 ] }
  86         { uint-integer-components [ 4 ] }
  87     } case ;
  88
  89 : bytes-per-packed-pixel ( component-type -- n )
  90     {
  91         { u-5-5-5-1-components [ 2 ] }
  92         { u-5-6-5-components [ 2 ] }
  93         { u-10-10-10-2-components [ 4 ] }
  94         { u-24-components [ 4 ] }
  95         { u-24-8-components [ 4 ] }
  96         { u-9-9-9-e5-components [ 4 ] }
  97         { float-11-11-10-components [ 4 ] }
  98         { float-32-u-8-components [ 8 ] }
  99     } case ;
 100
 101 : component-count ( component-order -- n )
 102     {
 103         { A [ 1 ] }
 104         { L [ 1 ] }
 105         { LA [ 2 ] }
 106         { BGR [ 3 ] }
 107         { RGB [ 3 ] }
 108         { BGRA [ 4 ] }
 109         { RGBA [ 4 ] }
 110         { ABGR [ 4 ] }
 111         { ARGB [ 4 ] }
 112         { RGBX [ 4 ] }
 113         { XRGB [ 4 ] }
 114         { BGRX [ 4 ] }
 115         { XBGR [ 4 ] }
 116         { INTENSITY [ 1 ] }
 117         { DEPTH [ 1 ] }
 118         { DEPTH-STENCIL [ 1 ] }
 119         { R [ 1 ] }
 120         { RG [ 2 ] }
 121     } case ;
 122
 123 : (bytes-per-pixel) ( component-order component-type -- n )
 124     dup packed-components?
 125     [ nip bytes-per-packed-pixel ] [
 126         [ component-count ] [ bytes-per-component ] bi* *
 127     ] if ;
 128
 129 : bytes-per-pixel ( image -- n )
 130     [ component-order>> ] [ component-type>> ] bi (bytes-per-pixel) ;
 131
 132 <PRIVATE
 133
 134 :: pixel@ ( x y w image -- start end bitmap )
 135     image dim>> first y * x + :> start
 136     start w [ image bytes-per-pixel * ] bi@ :> ( start' w' )
 137     start'  start' w' +  image bitmap>> ; inline
 138
 139 : set-subseq ( new-value from to victim -- )
 140     <slice> 0 swap copy ; inline
 141
 142 PRIVATE>
 143
 144 : pixel-row-at ( x y w image -- pixels )
 145     pixel@ subseq ; inline
 146
 147 : pixel-row-slice-at ( x y w image -- pixels )
 148     pixel@ <slice> ; inline
 149
 150 : set-pixel-row-at ( pixel x y w image -- )
 151     pixel@ set-subseq ; inline
 152
 153 : pixel-at ( x y image -- pixel )
 154     [ 1 ] dip pixel-row-at ; inline
 155
 156 : pixel-slice-at ( x y image -- pixels )
 157     [ 1 ] dip pixel-row-slice-at ; inline
 158
 159 : set-pixel-at ( pixel x y image -- )
 160     [ 1 ] dip set-pixel-row-at ; inline
 161