basis/interval-sets/interval-sets.factor

   1 ! Copyright (C) 2009 Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types arrays assocs binary-search
   4 combinators fry grouping kernel locals make math math.order
   5 sequences sequences.private sorting specialized-arrays ;
   6 SPECIALIZED-ARRAY: uint
   7 IN: interval-sets
   8 ! Sets of positive integers
   9
  10 TUPLE: interval-set { array uint-array read-only } ;
  11
  12 <PRIVATE
  13
  14 ERROR: not-an-interval-set obj ;
  15
  16 : check-interval-set ( map -- map )
  17     dup interval-set? [ not-an-interval-set ] unless ; inline
  18
  19 PRIVATE>
  20
  21 : in? ( key set -- ? )
  22     check-interval-set array>>
  23     over dupd [ >=< ] curry search drop [
  24         dup even? [ dup 1 + ] [ [ 1 - ] keep ] if rot
  25         [ nth-unsafe ] curry bi@ 1 - between?
  26     ] [ 2drop f ] if* ;
  27
  28 <PRIVATE
  29
  30 : spec>pairs ( sequence -- intervals )
  31     [ dup number? [ dup 2array ] when ] map ;
  32
  33 ALIAS: start first-unsafe
  34 ALIAS: end second-unsafe
  35
  36 : disjoint? ( node1 node2 -- ? )
  37     [ end ] [ start ] bi* < ;
  38
  39 : (delete-redundancies) ( seq -- )
  40     dup length {
  41         { 0 [ drop ] }
  42         { 1 [ % ] }
  43         [
  44             drop dup first2 <
  45             [ unclip-slice , ]
  46             [ 2 tail-slice ] if
  47             (delete-redundancies)
  48         ]
  49     } case ;
  50
  51 : delete-redundancies ( seq -- seq' )
  52     ! If the next element is >= current one, leave out both
  53     [ (delete-redundancies) ] uint-array{ } make ;
  54
  55 : make-intervals ( seq -- interval-set )
  56     uint-array{ } like
  57     delete-redundancies
  58     interval-set boa ;
  59
  60 : >intervals ( seq -- seq' )
  61     [ 1 + ] assoc-map concat ;
  62
  63 PRIVATE>
  64
  65 : <interval-set> ( specification -- interval-set )
  66     spec>pairs sort-keys
  67     >intervals make-intervals ;
  68
  69 <PRIVATE
  70
  71 :: or-step ( set1 set2 -- set1' set2' )
  72     set1 first ,
  73     set1 second set2 first <=
  74     [ set1 0 ] [ set2 2 ] if
  75     [ second , ] [ set2 swap tail-slice ] bi*
  76     set1 2 tail-slice ;
  77
  78 : combine-or ( set1 set2 -- )
  79     {
  80         { [ over empty? ] [ % drop ] }
  81         { [ dup empty? ] [ drop % ] }
  82         [
  83             2dup [ first ] bi@ <=
  84             [ swap ] unless
  85             or-step combine-or
  86         ]
  87     } cond ;
  88
  89 PRIVATE>
  90
  91 : <interval-or> ( set1 set2 -- set )
  92     [ array>> ] bi@
  93     [ combine-or ] uint-array{ } make
  94     make-intervals ;
  95
  96 <PRIVATE
  97
  98 : prefix-0 ( seq -- 0seq )
  99     0 over ?nth zero? [ rest ] [ 0 prefix ] if ;
 100
 101 : interval-max ( interval-set1 interval-set2 -- n )
 102     [ array>> [ 0 ] [ last ] if-empty ] bi@ max ;
 103
 104 PRIVATE>
 105
 106 : <interval-not> ( set maximum -- set' )
 107     [ array>> prefix-0 ] dip suffix make-intervals ;
 108
 109 : <interval-and> ( set1 set2 -- set )
 110     2dup interval-max
 111     [ '[ _ <interval-not> ] bi@ <interval-or> ] keep
 112     <interval-not> ;