basis/io/backend/unix/multiplexers/select/select.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types kernel bit-arrays sequences assocs math
   4 namespaces accessors math.order locals fry io.ports
   5 io.backend.unix io.backend.unix.multiplexers unix unix.ffi
   6 unix.time ;
   7 IN: io.backend.unix.multiplexers.select
   8
   9 TUPLE: select-mx < mx read-fdset write-fdset ;
  10
  11 ! Factor's bit-arrays are an array of bytes, OS X expects
  12 ! FD_SET to be an array of cells, so we have to account for
  13 ! byte order differences on big endian platforms
  14 : munge ( i -- i' )
  15     little-endian? [ BIN: 11000 bitxor ] unless ; inline
  16
  17 : <select-mx> ( -- mx )
  18     select-mx new-mx
  19         FD_SETSIZE 8 * <bit-array> >>read-fdset
  20         FD_SETSIZE 8 * <bit-array> >>write-fdset ;
  21
  22 : clear-nth ( n seq -- ? )
  23     [ nth ] [ [ f ] 2dip set-nth ] 2bi ;
  24
  25 :: check-fd ( fd fdset mx quot -- )
  26     fd munge fdset clear-nth [ fd mx quot call ] when ; inline
  27
  28 : check-fdset ( fds fdset mx quot -- )
  29     [ check-fd ] 3curry each ; inline
  30
  31 : init-fdset ( fds fdset -- )
  32     '[ t swap munge _ set-nth ] each ;
  33
  34 : read-fdset/tasks ( mx -- seq fdset )
  35     [ reads>> keys ] [ read-fdset>> ] bi ;
  36
  37 : write-fdset/tasks ( mx -- seq fdset )
  38     [ writes>> keys ] [ write-fdset>> ] bi ;
  39
  40 : max-fd ( assoc -- n )
  41     dup assoc-empty? [ drop 0 ] [ keys supremum ] if ;
  42
  43 : num-fds ( mx -- n )
  44     [ reads>> max-fd ] [ writes>> max-fd ] bi max 1 + ;
  45
  46 : init-fdsets ( mx -- nfds read write except )
  47     [ num-fds ]
  48     [ read-fdset/tasks [ init-fdset ] keep ]
  49     [ write-fdset/tasks [ init-fdset ] keep ] tri
  50     f ;
  51
  52 M:: select-mx wait-for-events ( nanos mx -- )
  53     mx
  54     [ init-fdsets nanos dup [ 1000 /i make-timeval ] when select multiplexer-error drop ]
  55     [ [ read-fdset/tasks ] keep [ input-available ] check-fdset ]
  56     [ [ write-fdset/tasks ] keep [ output-available ] check-fdset ]
  57     tri ;