basis/io/backend/windows/nt/nt.factor

   1 USING: alien alien.c-types arrays assocs combinators continuations
   2 destructors io io.backend io.ports io.timeouts io.backend.windows
   3 io.files.windows io.files.windows.nt io.files io.pathnames io.buffers
   4 io.streams.c io.streams.null libc kernel math namespaces sequences
   5 threads windows windows.errors windows.kernel32 strings splitting
   6 ascii system accessors locals classes.struct combinators.short-circuit ;
   7 IN: io.backend.windows.nt
   8
   9 ! Global variable with assoc mapping overlapped to threads
  10 SYMBOL: pending-overlapped
  11
  12 TUPLE: io-callback port thread ;
  13
  14 C: <io-callback> io-callback
  15
  16 : (make-overlapped) ( -- overlapped-ext )
  17     OVERLAPPED malloc-struct &free ;
  18
  19 : make-overlapped ( port -- overlapped-ext )
  20     [ (make-overlapped) ] dip
  21     handle>> ptr>> [ >>offset ] when* ;
  22
  23 M: winnt FileArgs-overlapped ( port -- overlapped )
  24     make-overlapped ;
  25
  26 : <completion-port> ( handle existing -- handle )
  27      f 1 CreateIoCompletionPort dup win32-error=0/f ;
  28
  29 SYMBOL: master-completion-port
  30
  31 : <master-completion-port> ( -- handle )
  32     INVALID_HANDLE_VALUE f <completion-port> ;
  33
  34 M: winnt add-completion ( win32-handle -- )
  35     handle>> master-completion-port get-global <completion-port> drop ;
  36
  37 : eof? ( error -- ? )
  38     { [ ERROR_HANDLE_EOF = ] [ ERROR_BROKEN_PIPE = ] } 1|| ;
  39
  40 : twiddle-thumbs ( overlapped port -- bytes-transferred )
  41     [
  42         drop
  43         [ self ] dip >c-ptr pending-overlapped get-global set-at
  44         "I/O" suspend {
  45             { [ dup integer? ] [ ] }
  46             { [ dup array? ] [
  47                 first dup eof?
  48                 [ drop 0 ] [ n>win32-error-string throw ] if
  49             ] }
  50         } cond
  51     ] with-timeout ;
  52
  53 :: wait-for-overlapped ( nanos -- bytes-transferred overlapped error? )
  54     nanos [ 1,000,000 /i ] [ INFINITE ] if* :> timeout
  55     master-completion-port get-global
  56     { int void* pointer: OVERLAPPED }
  57     [ timeout GetQueuedCompletionStatus zero? ] [ ] with-out-parameters
  58     :> ( error? bytes key overlapped )
  59     bytes overlapped error? ;
  60
  61 : resume-callback ( result overlapped -- )
  62     >c-ptr pending-overlapped get-global delete-at* drop resume-with ;
  63
  64 : handle-overlapped ( nanos -- ? )
  65     wait-for-overlapped [
  66         [
  67             [ drop GetLastError 1array ] dip resume-callback t
  68         ] [ drop f ] if*
  69     ] [ resume-callback t ] if ;
  70
  71 M: win32-handle cancel-operation
  72     [ check-disposed ] [ handle>> CancelIo drop ] bi ;
  73
  74 M: winnt io-multiplex ( nanos -- )
  75     handle-overlapped [ 0 io-multiplex ] when ;
  76
  77 M: winnt init-io ( -- )
  78     <master-completion-port> master-completion-port set-global
  79     H{ } clone pending-overlapped set-global ;
  80
  81 ERROR: invalid-file-size n ;
  82
  83 : handle>file-size ( handle -- n )
  84     0 <ulonglong> [ GetFileSizeEx win32-error=0/f ] keep *ulonglong ;
  85
  86 ERROR: seek-before-start n ;
  87
  88 : set-seek-ptr ( n handle -- )
  89     [ dup 0 < [ seek-before-start ] when ] dip ptr<< ;
  90
  91 M: winnt tell-handle ( handle -- n ) ptr>> ;
  92
  93 M: winnt seek-handle ( n seek-type handle -- )
  94     swap {
  95         { seek-absolute [ set-seek-ptr ] }
  96         { seek-relative [ [ ptr>> + ] keep set-seek-ptr ] }
  97         { seek-end [ [ handle>> handle>file-size + ] keep set-seek-ptr ] }
  98         [ bad-seek-type ]
  99     } case ;
 100
 101 : file-error? ( n -- eof? )
 102     zero? [
 103         GetLastError {
 104             { [ dup expected-io-error? ] [ drop f ] }
 105             { [ dup eof? ] [ drop t ] }
 106             [ n>win32-error-string throw ]
 107         } cond
 108     ] [ f ] if ;
 109
 110 : wait-for-file ( FileArgs n port -- n )
 111     swap file-error?
 112     [ 2drop 0 ] [ [ lpOverlapped>> ] dip twiddle-thumbs ] if ;
 113
 114 : update-file-ptr ( n port -- )
 115     handle>> dup ptr>> [ rot + >>ptr drop ] [ 2drop ] if* ;
 116
 117 : finish-write ( n port -- )
 118     [ update-file-ptr ] [ buffer>> buffer-consume ] 2bi ;
 119
 120 M: winnt (wait-to-write)
 121     [
 122         [ make-FileArgs dup setup-write WriteFile ]
 123         [ wait-for-file ]
 124         [ finish-write ]
 125         tri
 126     ] with-destructors ;
 127
 128 : finish-read ( n port -- )
 129     [ update-file-ptr ] [ buffer>> n>buffer ] 2bi ;
 130
 131 M: winnt (wait-to-read) ( port -- )
 132     [
 133         [ make-FileArgs dup setup-read ReadFile ]
 134         [ wait-for-file ]
 135         [ finish-read ]
 136         tri
 137     ] with-destructors ;
 138
 139 : console-app? ( -- ? ) GetConsoleWindow >boolean ;
 140
 141 M: winnt init-stdio
 142     console-app?
 143     [ init-c-stdio ]
 144     [ null-reader null-writer null-writer set-stdio ] if ;
 145
 146 winnt set-io-backend